1 files changed, 0 insertions, 89 deletions
diff --git a/sys-auth/elogind/elogind-234.4-r2.ebuild b/sys-auth/elogind/elogind-234.4-r2.ebuild
deleted file mode 100644
index 36239eed..00000000
--- a/sys-auth/elogind/elogind-234.4-r2.ebuild
+++ /dev/null
@@ -1,89 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit autotools linux-info pam udev xdg-utils
-
-DESCRIPTION="The systemd project's logind, extracted to a standalone package"
-HOMEPAGE="https://github.com/elogind/elogind"
-SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="CC0-1.0 LGPL-2.1+ public-domain"
-SLOT="0"
-KEYWORDS="amd64"
-IUSE="acl debug pam policykit selinux"
-
-COMMON_DEPEND="
-	sys-apps/util-linux
-	sys-libs/libcap
-	virtual/libudev:=
-	acl? ( sys-apps/acl )
-	pam? ( virtual/pam )
-	selinux? ( sys-libs/libselinux )
-"
-DEPEND="${COMMON_DEPEND}
-	app-text/docbook-xml-dtd:4.2
-	app-text/docbook-xml-dtd:4.5
-	app-text/docbook-xsl-stylesheets
-	dev-util/gperf
-	dev-util/intltool
-	sys-devel/libtool
-	virtual/pkgconfig
-"
-RDEPEND="${COMMON_DEPEND}
-	!sys-apps/systemd
-"
-PDEPEND="
-	sys-apps/dbus
-	policykit? ( sys-auth/polkit )
-"
-
-PATCHES=( "${FILESDIR}/${PN}-226.4-docs.patch" )
-
-pkg_setup() {
-	local CONFIG_CHECK="~CGROUPS ~EPOLL ~INOTIFY_USER ~SIGNALFD ~TIMERFD"
-
-	if use kernel_linux; then
-		linux-info_pkg_setup
-	fi
-}
-
-src_prepare() {
-	default
-	eautoreconf # Makefile.am patched by "${FILESDIR}/${P}-docs.patch"
-	xdg_environment_reset
-}
-
-src_configure() {
-	econf \
-		--with-pamlibdir=$(getpam_mod_dir) \
-		--with-udevrulesdir="$(get_udevdir)"/rules.d \
-		--libdir="${EPREFIX}"/usr/$(get_libdir) \
-		--with-rootlibdir="${EPREFIX}"/$(get_libdir) \
-		--with-rootprefix="${EPREFIX}/" \
-		--with-rootlibexecdir="${EPREFIX}"/$(get_libdir)/elogind \
-		--enable-smack \
-		--with-cgroup-controller=openrc \
-		--disable-lto \
-		--without-kill-user-processes \
-		$(use_enable debug debug elogind) \
-		$(use_enable acl) \
-		$(use_enable pam) \
-		$(use_enable selinux)
-}
-
-src_install() {
-	default
-	find "${D}" -name '*.la' -delete || die
-
-	newinitd "${FILESDIR}"/${PN}.init ${PN}
-
-	sed -e "s/@libdir@/$(get_libdir)/" "${FILESDIR}"/${PN}.conf.in > ${PN}.conf || die
-	newconfd ${PN}.conf ${PN}
-
-	# workaround for "RUN{builtin}: 'uaccess' unknown /lib64/udev/rules.d/73-seat-late.rules:15" warning
-	# we can safely remove the rule since it's part of systemd, and eudev doesn't support ACL's anyway
-	# this should be fixed in >=sys-fs/eudev-3.3 and >=sys-auth/elogind-235.3
-	rm -rf ${ED}lib/udev/rules.d/73-seat-late.rules
-}