1 files changed, 74 insertions, 0 deletions
diff --git a/lxqt-base/lxqt-config/lxqt-config-2.1.0-r1.ebuild b/lxqt-base/lxqt-config/lxqt-config-2.1.0-r1.ebuild
new file mode 100644
index 00000000..8b21bad4
--- /dev/null
+++ b/lxqt-base/lxqt-config/lxqt-config-2.1.0-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PV="$(ver_cut 1-2)"
+
+inherit cmake xdg-utils
+
+DESCRIPTION="LXQt system configuration control center"
+HOMEPAGE="https://lxqt-project.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+fi
+
+LICENSE="GPL-2 GPL-2+ GPL-3 LGPL-2 LGPL-2+ LGPL-2.1+ WTFPL-2"
+SLOT="0"
+IUSE="+monitor +touchpad"
+
+BDEPEND="
+	>=dev-qt/qttools-6.6:6[linguist]
+	>=dev-util/lxqt-build-tools-2.1.0
+"
+DEPEND="
+	>=dev-libs/libqtxdg-4.1.0
+	>=dev-qt/qtbase-6.6:6[gui,widgets,xml]
+	>=dev-qt/qtsvg-6.6:6
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	=lxqt-base/lxqt-menu-data-${MY_PV}*
+	sys-libs/zlib:=
+	x11-apps/setxkbmap
+	x11-libs/libxcb:=
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	monitor? ( kde-plasma/libkscreen:6= )
+	touchpad? (
+		virtual/libudev:=
+		x11-drivers/xf86-input-libinput
+		x11-libs/libXi
+	)
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=( 
+	"${FILESDIR}"/revert-2aff948ea19508317c185d87bc5f5e20fe64a30f.patch
+	"${FILESDIR}"/"${PN}"-qt5ct.patch )
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MONITOR=$(usex monitor)
+		-DWITH_TOUCHPAD=$(usex touchpad)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman man/*.1 liblxqt-config-cursor/man/*.1 lxqt-config-appearance/man/*.1
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}