3 files changed, 103 insertions, 98 deletions
diff --git a/kde-plasma/kinfocenter/Manifest b/kde-plasma/kinfocenter/Manifest
index d77c2957..e8408bee 100644
--- a/kde-plasma/kinfocenter/Manifest
+++ b/kde-plasma/kinfocenter/Manifest
@@ -1 +1 @@
-DIST kinfocenter-5.17.4.tar.xz 1344288 BLAKE2B 8f57b1c3b30f26de384739bdd8e63e085704d419f3c891446f6ecada19963763be0c4c83faca23271c5c3f65bf87aebb750b23e1bde73bc59f187d411164ae20 SHA512 93013206a97ed61001f824ccabc934e6684adfba55c3f0effc64425e0e95d4fb850d614db598059e970b7ee5e70160e06c7664b9b9915db66319b3332ec9689c
+DIST kinfocenter-5.17.5.tar.xz 1343896 BLAKE2B 0db47b3ed5f937c7701b52b194be71c6ccf474d5a1ede18864f32b1e374972cbd2e15f26b99f30fe4feba6adb153d87a05c5ccc5feb2bdd36ccc4086eda6f688 SHA512 4f759cc614061e128d57dbbcaa3253fdcda3ab96f3149085c320a0fe826f93b19a35c4b642e5ae9726c0e049ea7a4f8b6490575aeefb22b57b2c4ad8c0f1cbf7
diff --git a/kde-plasma/kinfocenter/kinfocenter-5.17.4-r314.ebuild b/kde-plasma/kinfocenter/kinfocenter-5.17.4-r314.ebuild
deleted file mode 100644
index 1a02995b..00000000
--- a/kde-plasma/kinfocenter/kinfocenter-5.17.4-r314.ebuild
+++ /dev/null
@@ -1,97 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-CMAKE_MIN_VERSION=3.14.3
-KDE_HANDBOOK="forceoptional"
-inherit kde5
-
-DESCRIPTION="Utility providing information about the computer hardware"
-HOMEPAGE="https://kde.org/applications/system/kinfocenter/"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
-IUSE="gles2 ieee1394 +opengl +pci wayland"
-
-REQUIRED_USE="wayland? ( || ( gles2 opengl ) )"
-
-COMMON_DEPEND="
-	$(add_frameworks_dep kcmutils)
-	$(add_frameworks_dep kcompletion)
-	$(add_frameworks_dep kconfig)
-	$(add_frameworks_dep kconfigwidgets)
-	$(add_frameworks_dep kcoreaddons)
-	$(add_frameworks_dep kcrash)
-	$(add_frameworks_dep kdbusaddons)
-	$(add_frameworks_dep kdeclarative)
-	$(add_frameworks_dep ki18n)
-	$(add_frameworks_dep kiconthemes)
-	$(add_frameworks_dep kio)
-	$(add_frameworks_dep kpackage)
-	$(add_frameworks_dep kservice)
-	$(add_frameworks_dep kwidgetsaddons)
-	$(add_frameworks_dep kxmlgui)
-	$(add_frameworks_dep solid)
-	$(add_qt_dep qtdbus)
-	$(add_qt_dep qtdeclarative)
-	$(add_qt_dep qtgui)
-	$(add_qt_dep qtwidgets)
-	x11-libs/libX11
-	ieee1394? ( sys-libs/libraw1394 )
-	opengl? (
-		$(add_qt_dep qtgui 'gles2=')
-		media-libs/mesa[gles2?,X(+)]
-		!gles2? ( media-libs/glu )
-	)
-	pci? ( sys-apps/pciutils )
-	wayland? (
-		$(add_frameworks_dep kwayland)
-		media-libs/mesa[egl]
-	)
-"
-DEPEND="${COMMON_DEPEND}
-	$(add_frameworks_dep plasma)
-"
-RDEPEND="${COMMON_DEPEND}
-	$(add_plasma_dep kde-cli-tools)
-	$(add_qt_dep qtquickcontrols2)
-"
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake-utils_use_find_package ieee1394 RAW1394)
-		$(cmake-utils_use_find_package pci PCIUTILS)
-		$(cmake-utils_use_find_package wayland EGL)
-		$(cmake-utils_use_find_package wayland KF5Wayland)
-	)
-
-	if has_version "dev-qt/qtgui[gles2]"; then
-		mycmakeargs+=( $(cmake-utils_use_find_package gles2 OpenGLES) )
-	else
-		mycmakeargs+=( $(cmake-utils_use_find_package opengl OpenGL) )
-	fi
-
-	kde5_src_configure
-}
-
-src_install() {
-	kde5_src_install
-
-	# TODO: Make this fully obsolete by /etc/os-release
-	insinto /etc/xdg
-	doins "${FILESDIR}"/kcm-about-distrorc
-
-	insinto /usr/share/${PN}
-	doins "${FILESDIR}"/glogo-small.png
-}
-
-pkg_postinst() {
-	kde5_pkg_postinst
-
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		has_version "net-fs/nfs-utils" || \
-			elog "Installing net-fs/nfs-utils will enable the NFS information module."
-
-		has_version "net-fs/samba" || \
-			elog "Installing net-fs/samba will enable the Samba status information module."
-	fi
-}
diff --git a/kde-plasma/kinfocenter/kinfocenter-5.17.5-r10.ebuild b/kde-plasma/kinfocenter/kinfocenter-5.17.5-r10.ebuild
new file mode 100644
index 00000000..fb684b70
--- /dev/null
+++ b/kde-plasma/kinfocenter/kinfocenter-5.17.5-r10.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.64.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Utility providing information about the computer hardware"
+HOMEPAGE="https://userbase.kde.org/KInfoCenter"
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="gles2 ieee1394 +opengl +pci wayland"
+
+REQUIRED_USE="wayland? ( || ( gles2 opengl ) )"
+
+BDEPEND=">=dev-util/cmake-3.14.3"
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	x11-libs/libX11
+	ieee1394? ( sys-libs/libraw1394 )
+	opengl? (
+		>=dev-qt/qtgui-${QTMIN}:5[gles2=]
+		media-libs/mesa[gles2?,X(+)]
+		!gles2? ( media-libs/glu )
+	)
+	pci? ( sys-apps/pciutils )
+	wayland? (
+		>=kde-frameworks/kwayland-${KFMIN}:5
+		media-libs/mesa[egl]
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package ieee1394 RAW1394)
+		$(cmake_use_find_package pci PCIUTILS)
+		$(cmake_use_find_package wayland EGL)
+		$(cmake_use_find_package wayland KF5Wayland)
+	)
+
+	if has_version "dev-qt/qtgui[gles2]"; then
+		mycmakeargs+=( $(cmake_use_find_package gles2 OpenGLES) )
+	else
+		mycmakeargs+=( $(cmake_use_find_package opengl OpenGL) )
+	fi
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# TODO: Make this fully obsolete by /etc/os-release
+	insinto /etc/xdg
+	doins "${FILESDIR}"/kcm-about-distrorc
+
+	insinto /usr/share/${PN}
+	doins "${FILESDIR}"/glogo-small.png
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		has_version "net-fs/nfs-utils" || \
+			elog "Installing net-fs/nfs-utils will enable the NFS information module."
+
+		has_version "net-fs/samba" || \
+			elog "Installing net-fs/samba will enable the Samba status information module."
+	fi
+}