1 files changed, 58 insertions, 0 deletions
diff --git a/kde-plasma/kde-gtk-config/kde-gtk-config-5.17.5-r10.ebuild b/kde-plasma/kde-gtk-config/kde-gtk-config-5.17.5-r10.ebuild
new file mode 100644
index 00000000..1d5d4383
--- /dev/null
+++ b/kde-plasma/kde-gtk-config/kde-gtk-config-5.17.5-r10.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="forceoptional"
+VIRTUALX_REQUIRED="test"
+KFMIN=5.64.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma systemsettings kcm to set GTK application look&feel"
+HOMEPAGE="https://cgit.kde.org/kde-gtk-config.git"
+LICENSE="GPL-3"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	dev-libs/glib:2
+	gnome-base/gsettings-desktop-schemas
+	x11-libs/gtk+:2
+	x11-libs/gtk+:3
+	x11-libs/libXcursor
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+PATCHES=( "${FILESDIR}"/redhat-or-not-go-dconf-and-flatpak-yourself-or-try-again-with-a-option-to-disable.patch )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDATA_INSTALL_DIR="${EPREFIX}/usr/share"
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	elog "If you notice missing icons in your GTK applications, you may have to install"
+	elog "the corresponding themes for GTK. A good guess would be x11-themes/oxygen-gtk"
+	elog "for example."
+}