x11-misc/sddm : revision bump (do not source files in home)

1 files changed, 105 insertions, 0 deletions

diff --git a/x11-misc/sddm/sddm-0.14.0-r5.ebuild b/x11-misc/sddm/sddm-0.14.0-r5.ebuild
new file mode 100644
index 00000000..5f0adc98
--- /dev/null
+++ b/x11-misc/sddm/sddm-0.14.0-r5.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils user
+
+DESCRIPTION="Simple Desktop Display Manager"
+HOMEPAGE="https://github.com/sddm/sddm"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.xz"
+KEYWORDS="amd64 ~arm x86"
+
+LICENSE="GPL-2+ MIT CC-BY-3.0 CC-BY-SA-3.0 public-domain"
+SLOT="0"
+IUSE="+branding consolekit elogind +pam systemd"
+
+REQUIRED_USE="elogind? ( !systemd !consolekit )
+	systemd? ( !elogind !consolekit )
+	consolekit? ( !elogind !systemd )
+"
+
+RDEPEND=">=dev-qt/qtcore-5.6:5
+	>=dev-qt/qtdbus-5.6:5
+	>=dev-qt/qtgui-5.6:5
+	>=dev-qt/qtdeclarative-5.6:5
+	>=dev-qt/qtnetwork-5.6:5
+	>=x11-base/xorg-server-1.15.1
+	x11-libs/libxcb[xkb(-)]
+	branding? ( x11-themes/redcore-theme-sddm )
+	consolekit? ( >=sys-auth/consolekit-0.9.4 )
+	elogind? ( sys-auth/elogind )
+	pam? ( sys-libs/pam )
+	systemd? ( sys-apps/systemd:= )
+	!systemd? ( || ( sys-power/upower sys-power/upower-pm-utils ) )"
+
+DEPEND="${RDEPEND}
+	dev-python/docutils
+	>=dev-qt/linguist-tools-5.6:5
+	>=dev-qt/qttest-5.6:5
+	kde-frameworks/extra-cmake-modules
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.13.0-pam_kwallet.patch"
+	"${FILESDIR}/${PN}-0.12.0-respect-user-flags.patch"
+	"${FILESDIR}/${P}-avatars.patch"
+	"${FILESDIR}/${PN}-enable-elogind.patch"
+	"${FILESDIR}/${PN}-dont-source-files-in-home.patch"
+)
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary  && $(tc-getCC) == *gcc* ]]; then
+		if [[ $(gcc-major-version) -lt 4 || $(gcc-major-version) == 4 && $(gcc-minor-version) -lt 7 ]] ; then
+			die 'The active compiler needs to be gcc 4.7 (or newer)'
+		fi
+	fi
+}
+
+src_prepare() {
+	if use consolekit; then
+		eapply "${FILESDIR}/${P}-consolekit.patch"
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_PAM=$(usex pam)
+		-DNO_SYSTEMD=$(usex '!systemd')
+		-DUSE_ELOGIND=$(usex 'elogind')
+		-DBUILD_MAN_PAGES=ON
+		-DDBUS_CONFIG_FILENAME="org.freedesktop.sddm.conf"
+		)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	# overwrite autogenerated sddm.conf 
+	if use consolekit; then
+		cp -avx ${FILESDIR}/sddm-redcore-consolekit.conf ${ED}etc/sddm.conf
+	elif use elogind; then
+		cp -avx ${FILESDIR}/sddm-redcore-elogind.conf ${ED}etc/sddm.conf
+	fi
+}
+
+pkg_postinst() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 /var/lib/${PN} ${PN},video
+
+	if use consolekit && use pam && [[ -e "${ROOT}"/etc/pam.d/system-login ]]; then
+		local line=$(grep "pam_ck_connector.*nox11" "${ROOT}"/etc/pam.d/system-login)
+		if [[ -z ${line} ]]; then
+			ewarn
+			ewarn "Erroneous /etc/pam.d/system-login settings detected!"
+			ewarn "Please restore 'nox11' option in the line containing pam_ck_connector:"
+			ewarn
+			ewarn "session      optional      pam_ck_connector.so nox11"
+			ewarn
+			ewarn "or 'emerge -1 sys-auth/pambase' and run etc-update."
+			ewarn
+		fi
+	fi
+}