media-libs/openimageio : add newer ebuild than what gentoo has

1 files changed, 138 insertions, 0 deletions

diff --git a/media-libs/openimageio/openimageio-2.0.7-r314.ebuild b/media-libs/openimageio/openimageio-2.0.7-r314.ebuild
new file mode 100644
index 00000000..bbab9e89
--- /dev/null
+++ b/media-libs/openimageio/openimageio-2.0.7-r314.ebuild
@@ -0,0 +1,138 @@
+# Copyright 1999-2019 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_7 )
+
+inherit cmake-utils python-single-r1
+
+DESCRIPTION="A library for reading and writing images"
+HOMEPAGE="https://sites.google.com/site/openimageio/ https://github.com/OpenImageIO"
+SRC_URI="https://github.com/OpenImageIO/oiio/archive/Release-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+X86_CPU_FEATURES=(
+	sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4.1 sse4_2:sse4.2
+	avx:avx avx2:avx2 avx512f:avx512f f16c:f16c
+)
+CPU_FEATURES=( ${X86_CPU_FEATURES[@]/#/cpu_flags_x86_} )
+
+IUSE="colorio doc ffmpeg field3d gif jpeg2k libressl opencv opengl ptex python qt5 raw ssl +truetype ${CPU_FEATURES[@]%:*}"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RESTRICT="test" #431412
+
+RDEPEND=">=dev-libs/boost-1.69
+	dev-libs/robin-map
+	dev-libs/pugixml:=
+	>=media-libs/ilmbase-2.2.0-r1:=
+	media-libs/libpng:0=
+	>=media-libs/libwebp-0.2.1:=
+	>=media-libs/openexr-2.2.0-r2:=
+	media-libs/tiff:0=
+	sys-libs/zlib:=
+	virtual/jpeg:0
+	sci-libs/dcmtk
+	colorio? ( media-libs/opencolorio:= )
+	ffmpeg? ( media-video/ffmpeg:= )
+	field3d? ( media-libs/Field3D:= )
+	gif? ( media-libs/giflib:0= )
+	jpeg2k? ( >=media-libs/openjpeg-1.5 )
+	opencv? ( media-libs/opencv:= )
+	opengl? (
+		virtual/glu
+		virtual/opengl
+		media-libs/glew:=
+	)
+	ptex? ( media-libs/ptex:= )
+	python? (
+		${PYTHON_DEPS}
+		dev-libs/boost:=[python,${PYTHON_USEDEP}]
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		opengl? ( dev-qt/qtopengl:5 )
+	)
+	raw? ( media-libs/libraw:= )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	truetype? ( media-libs/freetype:2= )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen[latex] )"
+
+DOCS=( CHANGES.md CREDITS.md README.md src/doc/${PN}.pdf )
+
+PATCHES=(
+	"${FILESDIR}"/ivgl_h.patch
+	"${FILESDIR}"/CMakeLists.txt.patch
+	"${FILESDIR}"/externalpackages.cmake.patch
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+S="${WORKDIR}/oiio-Release-${PV}"
+
+src_configure() {
+	# Build with SIMD support
+	local cpufeature
+	local mysimd=()
+	for cpufeature in "${CPU_FEATURES[@]}"; do
+		use "${cpufeature%:*}" && mysimd+=("${cpufeature#*:}")
+	done
+
+	# If no CPU SIMDs were used, completely disable them
+	[[ -z ${mysimd} ]] && mysimd=("0")
+
+	local mycmakeargs
+
+	if use python; then
+		mycmakeargs+=(
+			-DPYLIB3_INSTALL_DIR=$(python_get_sitedir)
+		)
+	
+	fi
+
+	mycmakeargs+=(
+		-DBUILDSTATIC=OFF
+		-DLINKSTATIC=OFF
+		-DNOTHREADS=OFF
+		-DCMAKE_INSTALL_PREFIX=/usr
+		-DCMAKE_INSTALL_LIBDIR=$(get_libdir)
+		-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+		-DINSTALL_DOCS=$(usex doc)
+		-DOIIO_BUILD_TESTS=ON
+		-DOIIO_BUILD_TOOLS=ON
+		-DSTOP_ON_WARNING=OFF
+		-DUSE_CPP14=ON
+		-DUSE_EXTERNAL_PUGIXML=ON
+		-DUSE_FFMPEG=$(usex ffmpeg)
+		-DUSE_FIELD3D=$(usex field3d)
+		-DUSE_FREETYPE=$(usex truetype)
+		-DUSE_GIF=$(usex gif)
+		-DUSE_JPEGTURBO=ON
+		-DUSE_LIBRAW=$(usex raw)
+		-DUSE_NUKE=NO # Missing in Gentoo
+		-DUSE_NUKE=OFF
+		-DUSE_OCIO=$(usex colorio)
+		-DUSE_OPENCV=$(usex opencv)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_OPENJPEG=$(usex jpeg2k)
+		-DUSE_OPENSSL=$(usex ssl)
+		-DUSE_PTEX=$(usex ptex)
+		-DUSE_PYTHON=$(usex python)
+		-DUSE_PYTHON3=$(usex python)
+		-DUSE_QT=$(usex qt5)
+		-DUSE_SIMD=$(local IFS=','; echo "${mysimd[*]}")
+	)
+
+	cmake-utils_src_configure
+}