lxqt-base/lxqt-{meta,session} : revision bump

1 files changed, 77 insertions, 0 deletions

diff --git a/lxqt-base/lxqt-session/lxqt-session-1.1.1-r1.ebuild b/lxqt-base/lxqt-session/lxqt-session-1.1.1-r1.ebuild
new file mode 100644
index 00000000..33038ea8
--- /dev/null
+++ b/lxqt-base/lxqt-session/lxqt-session-1.1.1-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="LXQt Session Manager"
+HOMEPAGE="https://lxqt-project.org/"
+
+MY_PV="$(ver_cut 1-2)"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="amd64 ~arm arm64 ~loong ~ppc64 ~riscv x86"
+fi
+
+IUSE="gtk +udev"
+
+LICENSE="LGPL-2.1 LGPL-2.1+"
+SLOT="0"
+
+BDEPEND="
+	>=dev-qt/linguist-tools-5.15:5
+	>=dev-util/lxqt-build-tools-0.11.0
+"
+DEPEND="
+	>=app-misc/qtxdg-tools-3.9.1
+	>=dev-libs/libqtxdg-3.9.1
+	>=dev-qt/qtcore-5.15:5
+	>=dev-qt/qtdbus-5.15:5
+	>=dev-qt/qtgui-5.15:5
+	>=dev-qt/qtwidgets-5.15:5
+	>=dev-qt/qtx11extras-5.15:5
+	kde-frameworks/kwindowsystem:5[X]
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	sys-process/procps:=
+	x11-libs/libX11
+	x11-misc/xdg-user-dirs
+	udev? ( virtual/libudev:= )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	if use gtk; then
+		eapply ${FILESDIR}/platform-plugin.patch
+		cmake_src_prepare
+	else
+		cmake_src_prepare
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_LIBUDEV=$(usex udev)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman lxqt-config-session/man/*.1 lxqt-session/man/*.1
+
+	newenvd - 91lxqt-config-dir <<- _EOF_
+		XDG_CONFIG_DIRS='${EPREFIX}/usr/share'
+	_EOF_
+
+	dodir "/etc/xdg/lxqt"
+	insinto "/etc/xdg/lxqt"
+	doins "${FILESDIR}/session.conf"
+
+	dodir "/etc/X11/Sessions"
+	dosym  "/usr/bin/startlxqt" "/etc/X11/Sessions/lxqt"
+}