dev-libs/libqtxdg : version bump

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-libs/libqtxdg/libqtxdg-3.3.1.ebuild b/dev-libs/libqtxdg/libqtxdg-3.3.1.ebuild
new file mode 100644
index 00000000..6093c409
--- /dev/null
+++ b/dev-libs/libqtxdg/libqtxdg-3.3.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils virtualx
+
+DESCRIPTION="A Qt implementation of XDG standards"
+HOMEPAGE="https://lxqt.org/"
+
+SRC_URI="https://downloads.lxqt.org/downloads/${PN}/${PV}/${P}.tar.xz"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+LICENSE="LGPL-2.1+ Nokia-Qt-LGPL-Exception-1.1"
+SLOT="0"
+IUSE="test"
+
+BDEPEND="
+	>=lxqt-base/lxqt-build-tools-0.6.0
+	virtual/pkgconfig
+"
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5=
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	x11-misc/xdg-utils
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+	)
+	cmake-utils_src_configure
+}
+
+src_test() {
+	# Tests don't work with C
+	LC_ALL=en_US.utf8 virtx cmake-utils_src_test
+}