Merge branch 'master' of github.com:Rogentos/kogaion-desktop

8 files changed, 512 insertions, 0 deletions

diff --git a/net-irc/quassel-client/Manifest b/net-irc/quassel-client/Manifest
index ca14171e..576911ef 100644
--- a/net-irc/quassel-client/Manifest
+++ b/net-irc/quassel-client/Manifest
@@ -1,2 +1,3 @@
 DIST quassel-0.10.0.tar.bz2 2873233 SHA256 68228ce23aa3a992add3d00cb1e8b4863d8ca64bea99c881edf6d16ff9ec7c23 SHA512 e194d4f9bbcecedfebd72c48d5f1e2a4185ff9d69134629b79e532af8f3fa9841e3cb99a6aae30e9bd79440c08487eeb23d6d6914690b90d1ae0952bb6168693 WHIRLPOOL bedd3de56e7625219a2970842ff0b073abbdc3488c8efece112c92f277386d5a3b63bde100a6e3daf2d5c0011e515e9fef81b888feec58d2a6571b4f898e8578
 DIST quassel-0.11.0.tar.bz2 2875387 SHA256 99a191b8bc2a410f7020b890ec57e0be49313f539da9f4843675bb108b0f4504 SHA512 51450559df2c0fee9a54b76a9342edb9a3b834f1f58edc556e0c1bf1f9366c846d95e7953e1b48c6ecf67ea4255b3574ed3ce537962eec222c5c03ab02852c1d WHIRLPOOL c2ffb7e052a5d412aec5d1b8bacc8cdb8144c20d62d699ca1d8972fd5e8fe6ce89da49251a02c22008061b344d9408b3f018b3b39623703b4d980c289cd5613a
+DIST quassel-0.12.2.tar.bz2 3681838 SHA256 6bd6f79ecb88fb857bea7e89c767a3bd0f413ff01bae9298dd2e563478947897 SHA512 0c907982af0ba11af6ba5d075850149dc4d4df0c759a736dfaccdc01778958bd9b0137515c2d78a72a1b5aef6600cea47505de6ee905d83a51cf4e67d132911d WHIRLPOOL 947c47ab6a5db73fdda7d5e5fc3f618030e9c2cfd78f4f423b32332e6514b5c3b8d24423a6be8ee8bf81e2e4a973aa29578e776dba5e8f7ad947acbcb7aef497
diff --git a/net-irc/quassel-client/quassel-client-0.12.2.ebuild b/net-irc/quassel-client/quassel-client-0.12.2.ebuild
new file mode 100644
index 00000000..1941ef23
--- /dev/null
+++ b/net-irc/quassel-client/quassel-client-0.12.2.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit cmake-utils eutils
+
+EGIT_REPO_URI="git://git.quassel-irc.org/quassel"
+[[ "${PV}" == "9999" ]] && inherit git-r3
+MY_P=${P/-client}
+# MY_PN=${PN/-client}
+
+DESCRIPTION="Qt/KDE IRC client supporting a remote daemon for 24/7 connectivity (client only)"
+HOMEPAGE="http://quassel-irc.org/"
+[[ "${PV}" == "9999" ]] || SRC_URI="http://quassel-irc.org/pub/${MY_P/_/-}.tar.bz2"
+
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="ayatana crypt dbus debug kde phonon qt5 +ssl webkit"
+
+GUI_RDEPEND="
+	qt5? (
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		dbus? (
+			dev-libs/libdbusmenu-qt[qt5]
+			dev-qt/qtdbus:5
+		)
+		phonon? ( media-libs/phonon[qt5] )
+		webkit? ( dev-qt/qtwebkit:5 )
+	)
+	!qt5? (
+		dev-qt/qtgui:4
+		ayatana? ( dev-libs/libindicate-qt )
+		dbus? (
+			dev-libs/libdbusmenu-qt[qt4(+)]
+			dev-qt/qtdbus:4
+			kde? (
+				kde-base/kdelibs:4
+				ayatana? ( kde-misc/plasma-widget-message-indicator )
+			)
+		)
+		phonon? ( || ( media-libs/phonon[qt4] dev-qt/qtphonon:4 ) )
+		webkit? ( dev-qt/qtwebkit:4 )
+	)
+"
+
+RDEPEND="
+	~net-irc/quassel-common-${PV}
+	sys-libs/zlib
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtnetwork:5[ssl?]
+	)
+	!qt5? ( dev-qt/qtcore:4[ssl?] )
+	${GUI_RDEPEND}
+"
+DEPEND="${RDEPEND}
+	qt5? ( dev-qt/linguist-tools:5 )
+"
+
+S="${WORKDIR}/${MY_P/_/-}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package ayatana IndicateQt)
+		$(cmake-utils_use_find_package crypt QCA2)
+		$(cmake-utils_use_find_package dbus dbusmenu-qt)
+		$(cmake-utils_use_find_package dbus dbusmenu-qt5)
+		$(cmake-utils_use_with kde)
+		"-DWITH_OXYGEN=OFF"
+		"-DWANT_MONO=OFF"
+		$(cmake-utils_use_find_package phonon)
+		$(cmake-utils_use_find_package phonon Phonon4Qt5)
+		$(cmake-utils_use_use qt5)
+		"-DWANT_CORE=OFF"
+		$(cmake-utils_use_with webkit)
+		"-DWANT_QTCLIENT=ON"
+		"-DEMBED_DATA=OFF"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	rm -r "${ED}"usr/share/apps/ || die
+	rm -r "${ED}"usr/share/pixmaps || die
+	rm -r "${ED}"usr/share/icons || die
+
+	insinto /usr/share/applications
+	doins data/quasselclient.desktop
+}
+
+pkg_postinst() {
+	elog "To make use of quasselclient, install server, too."
+	elog "It is provided by net-irc/quassel-core and net-irc/quassel-core-bin."
+}
diff --git a/net-irc/quassel-common/Manifest b/net-irc/quassel-common/Manifest
index ca14171e..576911ef 100644
--- a/net-irc/quassel-common/Manifest
+++ b/net-irc/quassel-common/Manifest
@@ -1,2 +1,3 @@
 DIST quassel-0.10.0.tar.bz2 2873233 SHA256 68228ce23aa3a992add3d00cb1e8b4863d8ca64bea99c881edf6d16ff9ec7c23 SHA512 e194d4f9bbcecedfebd72c48d5f1e2a4185ff9d69134629b79e532af8f3fa9841e3cb99a6aae30e9bd79440c08487eeb23d6d6914690b90d1ae0952bb6168693 WHIRLPOOL bedd3de56e7625219a2970842ff0b073abbdc3488c8efece112c92f277386d5a3b63bde100a6e3daf2d5c0011e515e9fef81b888feec58d2a6571b4f898e8578
 DIST quassel-0.11.0.tar.bz2 2875387 SHA256 99a191b8bc2a410f7020b890ec57e0be49313f539da9f4843675bb108b0f4504 SHA512 51450559df2c0fee9a54b76a9342edb9a3b834f1f58edc556e0c1bf1f9366c846d95e7953e1b48c6ecf67ea4255b3574ed3ce537962eec222c5c03ab02852c1d WHIRLPOOL c2ffb7e052a5d412aec5d1b8bacc8cdb8144c20d62d699ca1d8972fd5e8fe6ce89da49251a02c22008061b344d9408b3f018b3b39623703b4d980c289cd5613a
+DIST quassel-0.12.2.tar.bz2 3681838 SHA256 6bd6f79ecb88fb857bea7e89c767a3bd0f413ff01bae9298dd2e563478947897 SHA512 0c907982af0ba11af6ba5d075850149dc4d4df0c759a736dfaccdc01778958bd9b0137515c2d78a72a1b5aef6600cea47505de6ee905d83a51cf4e67d132911d WHIRLPOOL 947c47ab6a5db73fdda7d5e5fc3f618030e9c2cfd78f4f423b32332e6514b5c3b8d24423a6be8ee8bf81e2e4a973aa29578e776dba5e8f7ad947acbcb7aef497
diff --git a/net-irc/quassel-common/quassel-common-0.12.2.ebuild b/net-irc/quassel-common/quassel-common-0.12.2.ebuild
new file mode 100644
index 00000000..f9c85b60
--- /dev/null
+++ b/net-irc/quassel-common/quassel-common-0.12.2.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit cmake-utils eutils
+
+EGIT_REPO_URI="git://git.quassel-irc.org/quassel"
+[[ "${PV}" == "9999" ]] && inherit git-r3
+
+DESCRIPTION="Qt/KDE IRC client supporting a remote daemon for 24/7 connectivity (common files)"
+HOMEPAGE="http://quassel-irc.org/"
+MY_P=${P/-common}
+[[ "${PV}" == "9999" ]] || SRC_URI="http://quassel-irc.org/pub/${MY_P/_/-}.tar.bz2"
+
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="kde"
+
+RDEPEND="kde? (
+	|| ( kde-apps/oxygen-icons kde-base/oxygen-icons:4 ) )"
+DEPEND="${RDEPEND}
+		!<net-irc/quassel-${PV}
+		!<net-irc/quassel-client-${PV}"
+		# -core(-bin) does not depend on it
+
+S="${WORKDIR}/${MY_P/_/-}"
+
+src_configure() {
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_make po
+}
+
+src_install() {
+	# cmake-utils_src_install
+
+	local mypath
+
+	dodoc ChangeLog AUTHORS
+
+	# /usr/share/icons/hicolor
+	for mypath in icons/hicolor/*/*/quassel*.png; do
+		if [ -f "${mypath}" ]; then
+			insinto "/usr/share/${mypath%/*}"
+			doins "${mypath}" || die "doins for icon failed"
+		fi
+	done
+
+	# /usr/share/apps/quassel/icons/oxygen
+	if ! use kde; then
+		dodoc icons/README.Oxygen
+		local mydest
+		for mydest in COPYING AUTHORS CONTRIBUTING; do
+			newdoc "icons/oxygen/${mydest}" "${mydest}.Oxygen"
+		done
+
+		for mypath in icons/oxygen{,_kde}/*/*/*.{svgz,png}; do
+			if [ -f "${mypath}" ]; then
+				mydest=${mypath/oxygen_kde/oxygen}
+				insinto "/usr/share/apps/quassel/${mydest%/*}"
+				doins "${mypath}" || die "doins for Oxygen icon failed"
+			fi
+		done
+	fi
+
+	doicon icons/oxygen_kde/48x48/apps/quassel.png
+
+	# /usr/share/apps/quassel/stylesheets
+	for mypath in data/stylesheets/*.qss; do
+		if [ -f "${mypath}" ]; then
+			insinto /usr/share/apps/quassel/stylesheets
+			doins "${mypath}" || die "doins for .qss file failed"
+		fi
+	done
+
+	# /usr/share/apps/quassel/scripts
+	for mypath in data/scripts/*; do
+		if [ -f "${mypath}" ]; then
+			insinto /usr/share/apps/quassel/scripts
+			doins "${mypath/$CMAKE_BUILD_DIR}" || die "doins for script failed"
+		fi
+	done
+
+	# /usr/share/apps/quassel/translations
+	for mypath in "${CMAKE_BUILD_DIR}"/po/*.qm; do
+		insinto /usr/share/apps/quassel/translations
+		doins "${mypath}" || die "doins for .qm file failed"
+	done
+
+	insinto /usr/share/apps/quassel
+	doins data/networks.ini
+
+	use kde && doins data/quassel.notifyrc
+}
diff --git a/net-irc/quassel-core/Manifest b/net-irc/quassel-core/Manifest
index ca14171e..576911ef 100644
--- a/net-irc/quassel-core/Manifest
+++ b/net-irc/quassel-core/Manifest
@@ -1,2 +1,3 @@
 DIST quassel-0.10.0.tar.bz2 2873233 SHA256 68228ce23aa3a992add3d00cb1e8b4863d8ca64bea99c881edf6d16ff9ec7c23 SHA512 e194d4f9bbcecedfebd72c48d5f1e2a4185ff9d69134629b79e532af8f3fa9841e3cb99a6aae30e9bd79440c08487eeb23d6d6914690b90d1ae0952bb6168693 WHIRLPOOL bedd3de56e7625219a2970842ff0b073abbdc3488c8efece112c92f277386d5a3b63bde100a6e3daf2d5c0011e515e9fef81b888feec58d2a6571b4f898e8578
 DIST quassel-0.11.0.tar.bz2 2875387 SHA256 99a191b8bc2a410f7020b890ec57e0be49313f539da9f4843675bb108b0f4504 SHA512 51450559df2c0fee9a54b76a9342edb9a3b834f1f58edc556e0c1bf1f9366c846d95e7953e1b48c6ecf67ea4255b3574ed3ce537962eec222c5c03ab02852c1d WHIRLPOOL c2ffb7e052a5d412aec5d1b8bacc8cdb8144c20d62d699ca1d8972fd5e8fe6ce89da49251a02c22008061b344d9408b3f018b3b39623703b4d980c289cd5613a
+DIST quassel-0.12.2.tar.bz2 3681838 SHA256 6bd6f79ecb88fb857bea7e89c767a3bd0f413ff01bae9298dd2e563478947897 SHA512 0c907982af0ba11af6ba5d075850149dc4d4df0c759a736dfaccdc01778958bd9b0137515c2d78a72a1b5aef6600cea47505de6ee905d83a51cf4e67d132911d WHIRLPOOL 947c47ab6a5db73fdda7d5e5fc3f618030e9c2cfd78f4f423b32332e6514b5c3b8d24423a6be8ee8bf81e2e4a973aa29578e776dba5e8f7ad947acbcb7aef497
diff --git a/net-irc/quassel-core/quassel-core-0.12.2.ebuild b/net-irc/quassel-core/quassel-core-0.12.2.ebuild
new file mode 100644
index 00000000..6fa63448
--- /dev/null
+++ b/net-irc/quassel-core/quassel-core-0.12.2.ebuild
@@ -0,0 +1,155 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit cmake-utils eutils pax-utils systemd user versionator
+
+EGIT_REPO_URI="git://git.quassel-irc.org/quassel"
+[[ "${PV}" == "9999" ]] && inherit git-r3
+
+DESCRIPTION="Qt/KDE IRC client - the \"core\" (server) component"
+HOMEPAGE="http://quassel-irc.org/"
+MY_P=${P/-core}
+MY_PN=${PN/-core}
+[[ "${PV}" == "9999" ]] || SRC_URI="http://quassel-irc.org/pub/${MY_P/_/-}.tar.bz2"
+
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="crypt postgres qt5 +ssl syslog"
+
+SERVER_RDEPEND="
+	qt5? (
+		dev-qt/qtscript:5
+		postgres? ( dev-qt/qtsql:5[postgres] )
+		!postgres? ( dev-qt/qtsql:5[sqlite] dev-db/sqlite:3[threadsafe(+),-secure-delete] )
+	)
+	!qt5? (
+		dev-qt/qtscript:4
+		crypt? (
+			app-crypt/qca:2[qt4(+)]
+			|| ( app-crypt/qca-ossl:2 app-crypt/qca:2[openssl] )
+		)
+		postgres? ( dev-qt/qtsql:4[postgres] )
+		!postgres? ( dev-qt/qtsql:4[sqlite] dev-db/sqlite:3[threadsafe(+),-secure-delete] )
+	)
+	syslog? ( virtual/logger )
+"
+
+RDEPEND="
+	sys-libs/zlib
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtnetwork:5[ssl?]
+	)
+	!qt5? ( dev-qt/qtcore:4[ssl?] )
+	${SERVER_RDEPEND}
+"
+DEPEND="
+	${RDEPEND}
+	!net-irc/quassel-core-bin
+	"
+
+DOCS=( AUTHORS ChangeLog README )
+
+S="${WORKDIR}/${MY_P/_/-}"
+
+pkg_setup() {
+	QUASSEL_DIR=/var/lib/${MY_PN}
+	QUASSEL_USER=${MY_PN}
+	# create quassel:quassel user
+	enewgroup "${QUASSEL_USER}"
+	enewuser "${QUASSEL_USER}" -1 -1 "${QUASSEL_DIR}" "${QUASSEL_USER}"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		"CMAKE_DISABLE_FIND_PACKAGE_IndicateQt=ON"
+		$(cmake-utils_use_find_package crypt QCA2)
+		# $(cmake-utils_use_find_package dbus dbusmenu-qt)
+		# $(cmake-utils_use_find_package dbus dbusmenu-qt5)
+		"-DWITH_KDE=OFF"
+		"-DWITH_OXYGEN=OFF"
+		"-DWANT_MONO=OFF"
+
+		"CMAKE_DISABLE_FIND_PACKAGE_phonon=ON"
+		"CMAKE_DISABLE_FIND_PACKAGE_Phonon=ON"
+		"CMAKE_DISABLE_FIND_PACKAGE_PHONON=ON"
+
+		"CMAKE_DISABLE_FIND_PACKAGE_Phonon4Qt5=ON"
+		$(cmake-utils_use_use qt5)
+		"-DWANT_CORE=ON"
+		"-DWITH_WEBKIT=OFF"
+		"-DWANT_QTCLIENT=OFF"
+		"-DEMBED_DATA=OFF"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	rm -rf "${ED}"usr/share/apps/quassel/ || die
+	rm -f "${ED}"usr/share/pixmaps/quassel.png || die
+	rm -f "${ED}"usr/share/icons/hicolor/48x48/apps/quassel.png || die
+
+	# server stuff
+
+	# needs PAX marking wrt bug#346255
+	pax-mark m "${ED}/usr/bin/quasselcore"
+
+	# prepare folders in /var/
+	keepdir "${QUASSEL_DIR}"
+	fowners "${QUASSEL_USER}":"${QUASSEL_USER}" "${QUASSEL_DIR}"
+
+	# init scripts & systemd unit
+	newinitd "${FILESDIR}"/quasselcore.init quasselcore
+	newconfd "${FILESDIR}"/quasselcore.conf quasselcore
+	systemd_dounit "${FILESDIR}"/quasselcore.service
+
+	# logrotate
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/quassel.logrotate" quassel
+}
+
+pkg_postinst() {
+	einfo "If you want to generate SSL certificate remember to run:"
+	einfo "	emerge --config =${CATEGORY}/${PF}"
+
+	# server || monolithic
+	einfo "Quassel can use net-misc/oidentd package if installed on your system."
+	einfo "Consider installing it if you want to run quassel within identd daemon."
+
+	# temporary info mesage
+	if [[ $(get_version_component_range 2 ${REPLACING_VERSIONS}) -lt 7 ]]; then
+		echo
+		ewarn "Please note that all configuration moved from"
+		ewarn "/home/\${QUASSEL_USER}/.config/quassel-irc.org/"
+		ewarn "to: ${QUASSEL_DIR}."
+		echo
+		ewarn "For migration, stop the core, move quasselcore files (pretty much"
+		ewarn "everything apart from quasselclient.conf and settings.qss) into"
+		ewarn "new location and then start server again."
+	fi
+}
+
+pkg_config() {
+	if use ssl; then
+		# generate the pem file only when it does not already exist
+		if [ ! -f "${QUASSEL_DIR}/quasselCert.pem" ]; then
+			einfo "Generating QUASSEL SSL certificate to: \"${QUASSEL_DIR}/quasselCert.pem\""
+			openssl req -x509 -nodes -days 365 -newkey rsa:2048 \
+				-keyout "${QUASSEL_DIR}/quasselCert.pem" \
+				-out "${QUASSEL_DIR}/quasselCert.pem"
+			# permissions for the key
+			chown ${QUASSEL_USER}:${QUASSEL_USER} "${QUASSEL_DIR}/quasselCert.pem"
+			chmod 400 "${QUASSEL_DIR}/quasselCert.pem"
+		else
+			einfo "Certificate \"${QUASSEL_DIR}/quasselCert.pem\" already exists."
+			einfo "Remove it if you want to create new one."
+		fi
+	fi
+}
diff --git a/net-irc/quassel/Manifest b/net-irc/quassel/Manifest
index ca14171e..576911ef 100644
--- a/net-irc/quassel/Manifest
+++ b/net-irc/quassel/Manifest
@@ -1,2 +1,3 @@
 DIST quassel-0.10.0.tar.bz2 2873233 SHA256 68228ce23aa3a992add3d00cb1e8b4863d8ca64bea99c881edf6d16ff9ec7c23 SHA512 e194d4f9bbcecedfebd72c48d5f1e2a4185ff9d69134629b79e532af8f3fa9841e3cb99a6aae30e9bd79440c08487eeb23d6d6914690b90d1ae0952bb6168693 WHIRLPOOL bedd3de56e7625219a2970842ff0b073abbdc3488c8efece112c92f277386d5a3b63bde100a6e3daf2d5c0011e515e9fef81b888feec58d2a6571b4f898e8578
 DIST quassel-0.11.0.tar.bz2 2875387 SHA256 99a191b8bc2a410f7020b890ec57e0be49313f539da9f4843675bb108b0f4504 SHA512 51450559df2c0fee9a54b76a9342edb9a3b834f1f58edc556e0c1bf1f9366c846d95e7953e1b48c6ecf67ea4255b3574ed3ce537962eec222c5c03ab02852c1d WHIRLPOOL c2ffb7e052a5d412aec5d1b8bacc8cdb8144c20d62d699ca1d8972fd5e8fe6ce89da49251a02c22008061b344d9408b3f018b3b39623703b4d980c289cd5613a
+DIST quassel-0.12.2.tar.bz2 3681838 SHA256 6bd6f79ecb88fb857bea7e89c767a3bd0f413ff01bae9298dd2e563478947897 SHA512 0c907982af0ba11af6ba5d075850149dc4d4df0c759a736dfaccdc01778958bd9b0137515c2d78a72a1b5aef6600cea47505de6ee905d83a51cf4e67d132911d WHIRLPOOL 947c47ab6a5db73fdda7d5e5fc3f618030e9c2cfd78f4f423b32332e6514b5c3b8d24423a6be8ee8bf81e2e4a973aa29578e776dba5e8f7ad947acbcb7aef497
diff --git a/net-irc/quassel/quassel-0.12.2.ebuild b/net-irc/quassel/quassel-0.12.2.ebuild
new file mode 100644
index 00000000..49a42685
--- /dev/null
+++ b/net-irc/quassel/quassel-0.12.2.ebuild
@@ -0,0 +1,153 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit cmake-utils eutils
+
+EGIT_REPO_URI="git://git.quassel-irc.org/quassel"
+[[ "${PV}" == "9999" ]] && inherit git-r3
+
+DESCRIPTION="Qt/KDE IRC client - monolithic client only (no remote daemon)"
+HOMEPAGE="http://quassel-irc.org/"
+[[ "${PV}" == "9999" ]] || SRC_URI="http://quassel-irc.org/pub/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+# monolithic USE flag must be enabled for this package
+IUSE="ayatana crypt dbus debug kde monolithic phonon postgres qt5 +server +ssl syslog webkit X"
+
+SERVER_RDEPEND="
+	qt5? (
+		dev-qt/qtscript:5
+		postgres? ( dev-qt/qtsql:5[postgres] )
+		!postgres? ( dev-qt/qtsql:5[sqlite] dev-db/sqlite:3[threadsafe(+),-secure-delete] )
+	)
+	!qt5? (
+		dev-qt/qtscript:4
+		crypt? (
+			app-crypt/qca:2[qt4(+)]
+			|| ( app-crypt/qca-ossl:2 app-crypt/qca:2[openssl] )
+		)
+		postgres? ( dev-qt/qtsql:4[postgres] )
+		!postgres? ( dev-qt/qtsql:4[sqlite] dev-db/sqlite:3[threadsafe(+),-secure-delete] )
+	)
+	syslog? ( virtual/logger )
+"
+
+GUI_RDEPEND="
+	qt5? (
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		dbus? (
+			dev-libs/libdbusmenu-qt[qt5]
+			dev-qt/qtdbus:5
+		)
+		phonon? ( media-libs/phonon[qt5] )
+		webkit? ( dev-qt/qtwebkit:5 )
+	)
+	!qt5? (
+		dev-qt/qtgui:4
+		ayatana? ( dev-libs/libindicate-qt )
+		dbus? (
+			dev-libs/libdbusmenu-qt[qt4(+)]
+			dev-qt/qtdbus:4
+			kde? (
+				kde-base/kdelibs:4
+				ayatana? ( kde-misc/plasma-widget-message-indicator )
+			)
+		)
+		phonon? ( || ( media-libs/phonon[qt4] dev-qt/qtphonon:4 ) )
+		webkit? ( dev-qt/qtwebkit:4 )
+	)
+"
+
+RDEPEND="
+	~net-irc/quassel-common-${PV}
+	sys-libs/zlib
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtnetwork:5[ssl?]
+	)
+	!qt5? ( dev-qt/qtcore:4[ssl?] )
+	monolithic? (
+		${SERVER_RDEPEND}
+		${GUI_RDEPEND}
+	)
+	!monolithic? (
+		server? ( ${SERVER_RDEPEND} )
+		X? ( ${GUI_RDEPEND} )
+	)
+"
+DEPEND="${RDEPEND}
+	qt5? ( dev-qt/linguist-tools:5 )
+"
+
+DOCS=( AUTHORS ChangeLog README )
+
+S="${WORKDIR}/${P/_/-}"
+
+REQUIRED_USE="
+	|| ( X server monolithic )
+	ayatana? ( || ( X monolithic ) )
+	crypt? ( || ( server monolithic ) )
+	dbus? ( || ( X monolithic ) )
+	kde? ( phonon || ( X monolithic ) )
+	phonon? ( || ( X monolithic ) )
+	postgres? ( || ( server monolithic ) )
+	qt5? ( !ayatana !crypt !kde phonon )
+	syslog? ( || ( server monolithic ) )
+	webkit? ( || ( X monolithic ) )
+"
+
+pkg_setup() {
+	# sanity check for the split ebuild
+	use monolithic || die "The 'monolithic' flag must be enabled!"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package ayatana IndicateQt)
+		$(cmake-utils_use_find_package crypt QCA2)
+		$(cmake-utils_use_find_package dbus dbusmenu-qt)
+		$(cmake-utils_use_find_package dbus dbusmenu-qt5)
+		$(cmake-utils_use_with kde)
+		"-DWITH_OXYGEN=OFF"
+		"-DWANT_MONO=ON"
+		$(cmake-utils_use_find_package phonon)
+		$(cmake-utils_use_find_package phonon Phonon4Qt5)
+		$(cmake-utils_use_use qt5)
+		"-DWANT_CORE=OFF"
+		$(cmake-utils_use_with webkit)
+		"-DWANT_QTCLIENT=OFF"
+		"-DEMBED_DATA=OFF"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	rm -r "${ED}"usr/share/apps || die
+	rm -r "${ED}"usr/share/pixmaps || die
+	rm -r "${ED}"usr/share/icons || die
+	rm -r "${ED}"usr/share/applications || die
+
+	insinto /usr/share/applications
+	doins data/quassel.desktop
+}
+
+pkg_postinst() {
+	if use monolithic && use ssl ; then
+		elog "Information on how to enable SSL support for client/core connections"
+		elog "is available at http://bugs.quassel-irc.org/wiki/quassel-irc."
+	fi
+
+	if use server || use monolithic ; then
+		einfo "Quassel can use net-misc/oidentd package if installed on your system."
+		einfo "Consider installing it if you want to run quassel within identd daemon."
+	fi
+}