app-text/calibre : drop our ebuild, use gentoo one

6 files changed, 0 insertions, 406 deletions

diff --git a/app-text/calibre/Manifest b/app-text/calibre/Manifest
deleted file mode 100644
index 55ca24d5..00000000
--- a/app-text/calibre/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST calibre-3.26.1.tar.xz 39109660 BLAKE2B 0e98c273b8a5dfafea7a7027de3f83ad25ab835edadedf78b7e9bc356bcac8937d915944f2ab6503b414c49b4e792e090e7bd2433a4e86373bf115720ed78b0a SHA512 893e36b101defaca29281b4bd072aafc1c4cb20a9cd3ee06a0b68fbe6b39cab34952799939ac4f54c77148c87861c5ab4ddff84f5ec8c2274ae7fa6424259ff5
diff --git a/app-text/calibre/calibre-3.26.1-r1.ebuild b/app-text/calibre/calibre-3.26.1-r1.ebuild
deleted file mode 100644
index 192680d0..00000000
--- a/app-text/calibre/calibre-3.26.1-r1.ebuild
+++ /dev/null
@@ -1,290 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_COMPAT=( python2_7 )
-PYTHON_REQ_USE="sqlite,ssl"
-
-inherit eutils bash-completion-r1 gnome2-utils multilib toolchain-funcs python-single-r1 xdg-utils
-
-DESCRIPTION="Ebook management application"
-HOMEPAGE="https://calibre-ebook.com/"
-SRC_URI="https://download.calibre-ebook.com/${PV}/${P}.tar.xz"
-
-LICENSE="
-	GPL-3+
-	GPL-3
-	GPL-2+
-	GPL-2
-	GPL-1+
-	LGPL-3+
-	LGPL-2.1+
-	LGPL-2.1
-	BSD
-	MIT
-	Old-MIT
-	Apache-2.0
-	public-domain
-	|| ( Artistic GPL-1+ )
-	CC-BY-3.0
-	OFL-1.1
-	PSF-2
-	unRAR
-"
-KEYWORDS="~amd64 ~arm ~x86"
-SLOT="0"
-IUSE="ios +udisks"
-
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-COMMON_DEPEND="${PYTHON_DEPS}
-	>=app-text/podofo-0.8.2:=
-	>=app-text/poppler-0.26.5[qt5]
-	>=dev-libs/chmlib-0.40:=
-	dev-libs/glib:2=
-	>=dev-libs/icu-57.1:=
-	dev-libs/libinput:=
-	>=dev-python/apsw-3.13.0[${PYTHON_USEDEP}]
-	>=dev-python/beautifulsoup-3.0.5:python-2[${PYTHON_USEDEP}]
-	dev-python/chardet[${PYTHON_USEDEP}]
-	>=dev-python/cssselect-0.7.1[${PYTHON_USEDEP}]
-	>=dev-python/cssutils-1.0.1[${PYTHON_USEDEP}]
-	>=dev-python/dbus-python-1.2.4[${PYTHON_USEDEP}]
-	>=dev-libs/dbus-glib-0.106
-	>=sys-apps/dbus-1.10.8
-	dev-python/html5-parser[${PYTHON_USEDEP}]
-	>=dev-python/lxml-3.2.1[${PYTHON_USEDEP}]
-	>=dev-python/mechanize-0.2.5[${PYTHON_USEDEP}]
-	dev-python/msgpack[${PYTHON_USEDEP}]
-	dev-python/netifaces[${PYTHON_USEDEP}]
-	dev-python/pillow[${PYTHON_USEDEP}]
-	dev-python/psutil[${PYTHON_USEDEP}]
-	>=dev-python/pygments-2.1.3[${PYTHON_USEDEP}]
-	>=dev-python/python-dateutil-2.5.3[${PYTHON_USEDEP}]
-	>=dev-python/PyQt5-5.8[gui,svg,webkit,widgets,network,printsupport,${PYTHON_USEDEP}]
-	dev-python/regex[${PYTHON_USEDEP}]
-	dev-qt/qtcore:5=
-	dev-qt/qtdbus:5=
-	dev-qt/qtgui:5=
-	dev-qt/qtwidgets:5=
-	dev-util/desktop-file-utils
-	dev-util/gtk-update-icon-cache
-	media-fonts/liberation-fonts
-	media-libs/fontconfig:=
-	>=media-libs/freetype-2:=
-	>=media-libs/libmtp-1.1.11:=
-	>=media-libs/libwmf-0.2.8
-	>=media-gfx/optipng-0.7.6
-	sys-libs/zlib:=
-	virtual/libusb:1=
-	virtual/python-dnspython[${PYTHON_USEDEP}]
-	x11-libs/libxkbcommon:=
-	x11-libs/libX11:=
-	x11-libs/libXext:=
-	x11-libs/libXrender:=
-	x11-misc/shared-mime-info
-	>=x11-misc/xdg-utils-1.0.2-r2
-	ios? (
-		>=app-pda/usbmuxd-1.0.8
-		>=app-pda/libimobiledevice-1.2.0
-	)
-	udisks? ( virtual/libudev )"
-RDEPEND="${COMMON_DEPEND}
-	udisks? ( || ( sys-fs/udisks:2 sys-fs/udisks:0 ) )"
-DEPEND="${COMMON_DEPEND}
-	>=dev-python/setuptools-23.1.0[${PYTHON_USEDEP}]
-	>=virtual/podofo-build-0.9.4
-	virtual/pkgconfig"
-
-pkg_pretend() {
-	if [[ ${MERGE_TYPE} != binary && $(gcc-major-version) -lt 6 ]]; then
-		eerror "Calibre cannot be built with this version of gcc."
-		eerror "You need at least gcc-6.0"
-		die "Your C compiler is too old for this package."
-	fi
-}
-
-src_prepare() {
-	# no_updates: do not annoy user with "new version is availible all the time
-	# disable_plugins: walking sec-hole, wait for upstream to use GHNS interface
-	eapply \
-		"${FILESDIR}/${PN}-2.9.0-no_updates_dialog.patch" \
-		"${FILESDIR}/${PN}-disable_plugins.patch"
-
-	eapply_user
-
-	# Fix outdated version constant.
-	#sed -e "s#\\(^numeric_version =\\).*#\\1 (${PV//./, })#" \
-	#	-i src/calibre/constants.py || \
-	#	die "sed failed to patch constants.py"
-
-	# Avoid sandbox violation in /usr/share/gnome/apps when linux.py
-	# calls xdg-* (bug #258938).
-	sed -e "s|'xdg-desktop-menu', 'install'|\\0, '--mode', 'user'|" \
-		-e "s|check_call(\\['xdg-desktop-menu', 'forceupdate'\\])|#\\0|" \
-		-e "s|\\(CurrentDir(tdir)\\), \\\\\$|\\1:|" \
-		-e "s|, PreserveMIMEDefaults():|:|" \
-		-e "s|'xdg-icon-resource', 'install'|\\0, '--mode', 'user'|" \
-		-e "s|cmd\[2\]|cmd[4]|" \
-		-e "s|cc(\\['xdg-desktop-menu', 'forceupdate'\\])|#\\0|" \
-		-e "s|'xdg-mime', 'install'|\\0, '--mode', 'user'|" \
-		-i src/calibre/linux.py || die "sed failed to patch linux.py"
-
-	# Disable unnecessary privilege dropping for bug #287067.
-	sed -e "s:if os.geteuid() == 0:if False and os.geteuid() == 0:" \
-		-i setup/install.py || die "sed failed to patch install.py"
-
-	sed -e "/^                self.check_call(\\[QMAKE\\] + qmc + \\[proname\\])$/a\
-\\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ self.check_call(['sed', \
-'-e', 's|^CFLAGS .*|\\\\\\\\0 ${CFLAGS}|', \
-'-e', 's|^CXXFLAGS .*|\\\\\\\\0 ${CXXFLAGS}|', \
-'-e', 's|^LFLAGS .*|\\\\\\\\0 ${LDFLAGS}|', \
-'-i', 'Makefile'])" \
-		-i setup/build.py || die "sed failed to patch build.py"
-
-	# use system beautifulsoup, instead of bundled
-	rm -f "${S}"/src/calibre/ebooks/BeautifulSoup.py \
-		|| die "could not remove bundled beautifulsoup"
-	find "${S}" -type f -name \*.py -exec \
-		sed -e 's/calibre.ebooks.BeautifulSoup/BeautifulSoup/' -i {} + \
-		|| die "could not sed bundled beautifulsoup out of the source tree"
-
-	# avoid failure of xdg tools to recognize vendor prefix
-	sed -e "s|xdg-icon-resource install|xdg-icon-resource install --novendor|" \
-		-e "s|'xdg-mime', 'install'|'xdg-mime', 'install', '--novendor'|" \
-		-e "s|'xdg-desktop-menu', 'install'|'xdg-desktop-menu', 'install', '--novendor'|" \
-		-i "${S}"/src/calibre/linux.py || die 'sed failed'
-
-	# don't create/install uninstaller
-	sed '/self\.create_uninstaller()/d' -i src/calibre/linux.py || die
-}
-
-src_install() {
-	# Bypass kbuildsycoca and update-mime-database in order to
-	# avoid sandbox violations if xdg-mime tries to call them.
-	cat - > "${T}/kbuildsycoca" <<-EOF
-	#!${BASH}
-	echo $0 : $@
-	exit 0
-	EOF
-
-	cp "${T}"/{kbuildsycoca,update-mime-database} || die
-	chmod +x "${T}"/{kbuildsycoca,update-mime-database} || die
-
-	export QMAKE="${EPREFIX}/usr/$(get_libdir)/qt5/bin/qmake"
-
-	# Unset DISPLAY in order to prevent xdg-mime from triggering a sandbox
-	# violation with kbuildsycoca as in bug #287067, comment #13.
-	export -n DISPLAY
-
-	# Bug #352625 - Some LANGUAGE values can trigger the following ValueError:
-	#   File "/usr/lib/python2.6/locale.py", line 486, in getdefaultlocale
-	#    return _parse_localename(localename)
-	#  File "/usr/lib/python2.6/locale.py", line 418, in _parse_localename
-	#    raise ValueError, 'unknown locale: %s' % localename
-	#ValueError: unknown locale: 46
-	export -n LANGUAGE
-
-	# Bug #295672 - Avoid sandbox violation in ~/.config by forcing
-	# variables to point to our fake temporary $HOME.
-	export HOME="${T}/fake_homedir"
-	export XDG_CONFIG_HOME="${HOME}/.config"
-	export XDG_DATA_HOME="${HOME}/.local/share"
-	export CALIBRE_CONFIG_DIRECTORY="${XDG_CONFIG_HOME}/calibre"
-	mkdir -p "${XDG_DATA_HOME}" "${CALIBRE_CONFIG_DIRECTORY}" || die
-
-	tc-export CC CXX
-	# Bug #334243 - respect LDFLAGS when building extensions
-	export OVERRIDE_CFLAGS="$CFLAGS" OVERRIDE_LDFLAGS="$LDFLAGS"
-	local libdir=$(get_libdir)
-	[[ -n $libdir ]] || die "get_libdir returned an empty string"
-
-	# Bug #472690 - Avoid sandbox violations
-	addpredict /dev/dri/
-	
-	#dodir "/usr/$(get_libdir)/python2.7/site-packages" # for init_calibre.py
-	#dodir $(python_get_sitedir)
-	PATH=${T}:${PATH} PYTHONPATH=${S}/src${PYTHONPATH:+:}${PYTHONPATH} \
-	"${PYTHON}" setup.py install \
-		--root="${D}" \
-		--prefix="${EPREFIX}/usr" \
-		--libdir="${EPREFIX}/usr/${libdir}" \
-		--staging-root="${ED}usr" \
-		--staging-libdir="${ED}usr/${libdir}" || die
-
-	# The menu entries end up here due to '--mode user' being added to
-	# xdg-* options in src_prepare.
-	dodir /usr/share/mime/packages
-	chmod -fR a+rX,u+w,g-w,o-w "${HOME}"/.local
-	mv "${HOME}"/.local/share/mime/packages/* "${ED}"usr/share/mime/packages/ ||
-		die "failed to register mime types"
-	dodir /usr/share/icons
-	mv "${HOME}"/.local/share/icons/* "${ED}"usr/share/icons/ ||
-		die "failed to install icon files"
-
-	domenu "${HOME}"/.local/share/applications/*.desktop ||
-		die "failed to install .desktop menu files"
-
-	find "${ED}"usr/share -type d -empty -delete
-
-	cd "${ED}"/usr/share/calibre/fonts/liberation || die
-	local x
-	for x in * ; do
-		[[ -f ${EPREFIX}usr/share/fonts/liberation-fonts/${x} ]] || continue
-		ln -sf "../../../fonts/liberation-fonts/${x}" "${x}" || die
-	done
-
-	einfo "Converting python shebangs"
-	python_fix_shebang "${ED}"
-
-	einfo "Compiling python modules"
-	python_optimize "${ED}"usr/lib/calibre
-
-	newinitd "${FILESDIR}"/calibre-server-3.init calibre-server
-	newconfd "${FILESDIR}"/calibre-server-3.conf calibre-server
-
-	bashcomp_alias calibre \
-		lrfviewer \
-		calibre-debug \
-		ebook-meta \
-		calibre-server \
-		ebook-viewer \
-		ebook-polish \
-		fetch-ebook-metadata \
-		lrf2lrs \
-		ebook-convert \
-		ebook-edit \
-		calibre-smtp \
-		ebook-device
-
-}
-
-pkg_preinst() {
-	gnome2_icon_savelist
-	# Indentify stray directories from upstream's "Binary install"
-	# method (see bug 622728).
-	CALIBRE_LIB_DIR=/usr/$(get_libdir)/calibre
-	CALIBRE_LIB_CONTENT=$(for x in "${ED%/}${CALIBRE_LIB_DIR}"/*; do
-		printf -- "${x##*/} "; done) || die "Failed to list ${ED%/}${CALIBRE_LIB_DIR}"
-}
-
-pkg_postinst() {
-	[[ -n ${CALIBRE_LIB_DIR} ]] || die "CALIBRE_LIB_DIR is unset"
-	local x
-	for x in "${EROOT%/}${CALIBRE_LIB_DIR}"/*; do
-		if [[ " ${CALIBRE_LIB_CONTENT} " != *" ${x##*/} "* ]]; then
-			elog "Purging '${x}'"
-			rm -rf "${x}"
-		fi
-	done
-	xdg_desktop_database_update
-	xdg_mimeinfo_database_update
-	gnome2_icon_cache_update
-}
-
-pkg_postrm() {
-	xdg_desktop_database_update
-	xdg_mimeinfo_database_update
-	gnome2_icon_cache_update
-}
diff --git a/app-text/calibre/files/calibre-2.9.0-no_updates_dialog.patch b/app-text/calibre/files/calibre-2.9.0-no_updates_dialog.patch
deleted file mode 100644
index 4d37c3b6..00000000
--- a/app-text/calibre/files/calibre-2.9.0-no_updates_dialog.patch
+++ /dev/null
@@ -1,27 +0,0 @@
-diff -burN calibre-2.9.0.orig/src/calibre/gui2/main.py calibre-2.9.0/src/calibre/gui2/main.py
---- calibre-2.9.0.orig/src/calibre/gui2/main.py	2014-11-09 20:09:54.081231882 +0800
-+++ calibre-2.9.0/src/calibre/gui2/main.py	2014-11-09 20:15:48.193033844 +0800
-@@ -37,8 +37,9 @@
-                       help=_('Start minimized to system tray.'))
-     parser.add_option('-v', '--verbose', default=0, action='count',
-                       help=_('Ignored, do not use. Present only for legacy reasons'))
--    parser.add_option('--no-update-check', default=False, action='store_true',
--            help=_('Do not check for updates'))
-+    parser.add_option('--update-check', dest='no_update_check', default=True,
-+            action='store_false',
-+            help=_('Check for updates'))
-     parser.add_option('--ignore-plugins', default=False, action='store_true',
-             help=_('Ignore custom plugins, useful if you installed a plugin'
-                 ' that is preventing calibre from starting'))
-diff -burN calibre-2.9.0.orig/src/calibre/gui2/update.py calibre-2.9.0/src/calibre/gui2/update.py
---- calibre-2.9.0.orig/src/calibre/gui2/update.py	2014-11-09 20:09:54.082231864 +0800
-+++ calibre-2.9.0/src/calibre/gui2/update.py	2014-11-09 20:17:49.954767115 +0800
-@@ -154,6 +154,8 @@
-             self.update_checker.signal.update_found.connect(self.update_found,
-                     type=Qt.QueuedConnection)
-             self.update_checker.start()
-+        else:
-+            self.update_checker = None
- 
-     def recalc_update_label(self, number_of_plugin_updates):
-         self.update_found(self.last_newest_calibre_version, number_of_plugin_updates)
diff --git a/app-text/calibre/files/calibre-disable_plugins.patch b/app-text/calibre/files/calibre-disable_plugins.patch
deleted file mode 100644
index 9ef1dd04..00000000
--- a/app-text/calibre/files/calibre-disable_plugins.patch
+++ /dev/null
@@ -1,17 +0,0 @@
-Description: Disable plugin dialog. It uses a totally non-authenticated and non-trusted way of installing arbitrary code.
-Author: Martin Pitt <mpitt@debian.org>
-Bug-Debian: http://bugs.debian.org/640026
-
-Index: calibre-0.8.29+dfsg/src/calibre/gui2/actions/preferences.py
-===================================================================
---- calibre-0.8.29+dfsg.orig/src/calibre/gui2/actions/preferences.py	2011-12-16 05:49:14.000000000 +0100
-+++ calibre-0.8.29+dfsg/src/calibre/gui2/actions/preferences.py	2011-12-20 19:29:04.798468930 +0100
-@@ -28,8 +28,6 @@
-             pm.addAction(QIcon(I('config.png')), _('Preferences'), self.do_config)
-         cm('welcome wizard', _('Run welcome wizard'),
-                 icon='wizard.png', triggered=self.gui.run_wizard)
--        cm('plugin updater', _('Get plugins to enhance calibre'),
--                icon='plugins/plugin_updater.png', triggered=self.get_plugins)
-         if not DEBUG:
-             pm.addSeparator()
-             cm('restart', _('Restart in debug mode'), icon='debug.png',
diff --git a/app-text/calibre/files/calibre-server-3.conf b/app-text/calibre/files/calibre-server-3.conf
deleted file mode 100644
index bb456e85..00000000
--- a/app-text/calibre/files/calibre-server-3.conf
+++ /dev/null
@@ -1,13 +0,0 @@
-# /etc/conf.d/calibre-server
-# Change this to the user you want to run calibre-server as.
-# You may specify a group too, after a colon
-# NOTE:  This must be set and not to root!
-CALIBRE_USER=
-
-# Set the path of the library to serve.
-# Defaults to the default location for CALIBRE_USER.
-#CALIBRE_LIBRARY='<user home directory>/Calibre Library'
-
-# Extra options to pass to calibre-server.
-# See the calibre-server man page for more options.
-#CALIBRE_SERVER_OPTS="--userdb /srv/calibre/users.sqlite --enable-auth --worker-count 10 --port 8080"
diff --git a/app-text/calibre/files/calibre-server-3.init b/app-text/calibre/files/calibre-server-3.init
deleted file mode 100644
index 049d3e42..00000000
--- a/app-text/calibre/files/calibre-server-3.init
+++ /dev/null
@@ -1,58 +0,0 @@
-#!/sbin/openrc-run
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License, v2 or later
-
-depend() {
-	need net
-	need localmount
-	after bootmisc
-}
-
-checkconfig() {
-	if [ "${CALIBRE_USER}" = "" -o "${CALIBRE_USER}" = "root" ] ; then
-		eerror "Please edit /etc/conf.d/calibre-server"
-		eerror "You have to specify a user to run calibre-server as, as we will not run it as root!"
-		eerror "Modify CALIBRE_USER to your needs (you can also add a group, after a colon)"
-		return 1
-	fi
-	if ! getent passwd "${CALIBRE_USER%:*}" >/dev/null ; then
-		eerror "Please edit /etc/conf.d/calibre-server"
-		eerror "Your user has to exist!"
-		return 1
-	fi
-	if [ "${CALIBRE_USER%:*}" != "${CALIBRE_USER}" ] ; then
-		if ! getent group "${CALIBRE_USER#*:}" >/dev/null ; then
-			eerror "Please edit /etc/conf.d/calibre-server"
-			eerror "Your group has to exist too!"
-			return 1
-		fi
-	fi
-	if [ "${CALIBRE_LIBRARY}" = "" ] ; then
-		CALIBRE_USER_HOME=$(getent passwd "${CALIBRE_USER%:*}" | cut -d ':' -f 6)
-		CALIBRE_LIBRARY="${CALIBRE_USER_HOME}/Calibre Library"
-	fi
-	if [ ! -d "${CALIBRE_LIBRARY}" ] ; then
-		eerror "Please edit /etc/conf.d/calibre-server"
-		eerror "The Calibre library, '${CALIBRE_LIBRARY},' does not exist."
-		eerror "Please modify CALIBRE_LIBRARY to point to a valid library."
-		return 1
-	fi
-	return 0
-}
-
-start() {
-	checkconfig || return $?
-	local pidfile=/var/run/calibre-server.pid
-	ebegin "Starting calibre-server"
-	start-stop-daemon --user "${CALIBRE_USER}" \
-		--pidfile "${pidfile}" --make-pidfile --background --exec /usr/bin/calibre-server \
-		-- ${CALIBRE_OPTS} "${CALIBRE_LIBRARY}"
-	eend $?
-}
-
-stop() {
-	ebegin "Stopping calibre-server"
-	start-stop-daemon --stop --user "${CALIBRE_USER}" \
-		--pidfile /var/run/calibre-server.pid
-	eend $?
-}