how this happened?

2 files changed, 114 insertions, 0 deletions

diff --git a/kde-plasma/kinfocenter/kinfocenter-5.23.3-r10.ebuild b/kde-plasma/kinfocenter/kinfocenter-5.23.3-r10.ebuild
new file mode 100644
index 00000000..97cdc922
--- /dev/null
+++ b/kde-plasma/kinfocenter/kinfocenter-5.23.3-r10.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.86.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+inherit ecm kde.org optfeature
+
+DESCRIPTION="Utility providing information about the computer hardware"
+HOMEPAGE="https://userbase.kde.org/KInfoCenter"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="gles2-only ieee1394 +opengl +pci usb wayland +X"
+
+REQUIRED_USE="opengl? ( X ) wayland? ( || ( opengl gles2-only ) )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5[gles2-only=]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	gles2-only? ( media-libs/mesa[gles2] )
+	ieee1394? ( sys-libs/libraw1394 )
+	opengl? (
+		media-libs/libglvnd[X?]
+		!gles2-only? ( media-libs/glu )
+	)
+	pci? ( sys-apps/pciutils )
+	usb? ( virtual/libusb:1 )
+	wayland? (
+		>=kde-frameworks/kwayland-${KFMIN}:5
+		media-libs/mesa[egl(+)]
+	)
+	X? ( x11-libs/libX11 )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	>=kde-plasma/systemsettings-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package ieee1394 RAW1394)
+		$(cmake_use_find_package pci PCIUTILS)
+		$(cmake_use_find_package usb USB1)
+		$(cmake_use_find_package wayland EGL)
+		$(cmake_use_find_package wayland KF5Wayland)
+		$(cmake_use_find_package X X11)
+	)
+
+	if has_version "dev-qt/qtgui[gles2-only]"; then
+		mycmakeargs+=( $(cmake_use_find_package gles2-only OpenGLES) )
+	else
+		mycmakeargs+=( $(cmake_use_find_package opengl OpenGL) )
+	fi
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# TODO: Make this fully obsolete by /etc/os-release
+	insinto /etc/xdg
+	doins "${FILESDIR}"/kcm-about-distrorc
+
+	insinto /usr/share/${PN}
+	doins "${FILESDIR}"/glogo-small.png
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "NFS information module" net-fs/nfs-utils
+		optfeature "Samba status information module" net-fs/samba
+		optfeature "Vulkan graphics API information module" dev-util/vulkan-tools
+		optfeature "advanced CPU information module" sys-apps/util-linux
+	fi
+	ecm_pkg_postinst
+}
diff --git a/metadata/md5-cache/kde-plasma/kinfocenter-5.23.3-r10 b/metadata/md5-cache/kde-plasma/kinfocenter-5.23.3-r10
new file mode 100644
index 00000000..3d7f9ba6
--- /dev/null
+++ b/metadata/md5-cache/kde-plasma/kinfocenter-5.23.3-r10
@@ -0,0 +1,16 @@
+BDEPEND=dev-util/ninja >=dev-util/cmake-3.20.5 handbook? ( >=kde-frameworks/kdoctools-5.86.0:5 ) >=kde-frameworks/extra-cmake-modules-5.86.0:5
+DEFINED_PHASES=compile configure install nofetch postinst postrm preinst prepare setup test unpack
+DEPEND=>=dev-qt/qtdbus-5.15.2:5 >=dev-qt/qtdeclarative-5.15.2:5 >=dev-qt/qtgui-5.15.2:5[gles2-only=] >=dev-qt/qtwidgets-5.15.2:5 >=kde-frameworks/kcmutils-5.86.0:5 >=kde-frameworks/kconfig-5.86.0:5 >=kde-frameworks/kconfigwidgets-5.86.0:5 >=kde-frameworks/kcoreaddons-5.86.0:5 >=kde-frameworks/kdeclarative-5.86.0:5 >=kde-frameworks/ki18n-5.86.0:5 >=kde-frameworks/kiconthemes-5.86.0:5 >=kde-frameworks/kio-5.86.0:5 >=kde-frameworks/kpackage-5.86.0:5 >=kde-frameworks/kservice-5.86.0:5 >=kde-frameworks/kwidgetsaddons-5.86.0:5 >=kde-frameworks/solid-5.86.0:5 gles2-only? ( media-libs/mesa[gles2] ) ieee1394? ( sys-libs/libraw1394 ) opengl? ( media-libs/libglvnd[X?] !gles2-only? ( media-libs/glu ) ) pci? ( sys-apps/pciutils ) usb? ( virtual/libusb:1 ) wayland? ( >=kde-frameworks/kwayland-5.86.0:5 media-libs/mesa[egl(+)] ) X? ( x11-libs/libX11 ) dev-qt/qtcore:5
+DESCRIPTION=Utility providing information about the computer hardware
+EAPI=8
+HOMEPAGE=https://userbase.kde.org/KInfoCenter
+INHERIT=ecm kde.org optfeature
+IUSE=gles2-only ieee1394 +opengl +pci usb wayland +X debug +handbook
+KEYWORDS=~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86
+LICENSE=GPL-2
+RDEPEND=>=dev-qt/qtdbus-5.15.2:5 >=dev-qt/qtdeclarative-5.15.2:5 >=dev-qt/qtgui-5.15.2:5[gles2-only=] >=dev-qt/qtwidgets-5.15.2:5 >=kde-frameworks/kcmutils-5.86.0:5 >=kde-frameworks/kconfig-5.86.0:5 >=kde-frameworks/kconfigwidgets-5.86.0:5 >=kde-frameworks/kcoreaddons-5.86.0:5 >=kde-frameworks/kdeclarative-5.86.0:5 >=kde-frameworks/ki18n-5.86.0:5 >=kde-frameworks/kiconthemes-5.86.0:5 >=kde-frameworks/kio-5.86.0:5 >=kde-frameworks/kpackage-5.86.0:5 >=kde-frameworks/kservice-5.86.0:5 >=kde-frameworks/kwidgetsaddons-5.86.0:5 >=kde-frameworks/solid-5.86.0:5 gles2-only? ( media-libs/mesa[gles2] ) ieee1394? ( sys-libs/libraw1394 ) opengl? ( media-libs/libglvnd[X?] !gles2-only? ( media-libs/glu ) ) pci? ( sys-apps/pciutils ) usb? ( virtual/libusb:1 ) wayland? ( >=kde-frameworks/kwayland-5.86.0:5 media-libs/mesa[egl(+)] ) X? ( x11-libs/libX11 ) >=dev-qt/qtquickcontrols2-5.15.2:5 >=kde-frameworks/kirigami-5.86.0:5 >=kde-plasma/kde-cli-tools-5.23.3:5 >=kde-plasma/systemsettings-5.23.3:5 || ( kde-frameworks/breeze-icons:* kde-frameworks/oxygen-icons:* ) >=kde-frameworks/kf-env-4 dev-qt/qtcore:5
+REQUIRED_USE=opengl? ( X ) wayland? ( || ( opengl gles2-only ) )
+SLOT=5
+SRC_URI=mirror://kde/stable/plasma/5.23.3/kinfocenter-5.23.3.tar.xz
+_eclasses_=cmake	11fee991ab428a3370e5c20fa8231fb6	ecm	9fe70cc0ef1ddfecce7548500987215d	flag-o-matic	4134b5c0fb719b9161d10bdaba9e09e5	kde.org	f95aaca4085d2d633c2b76abfd72208f	multilib	4b66d835ec72e021e359bb81eacfe988	multiprocessing	61c959fc55c15c00bbb1079d6a71370b	ninja-utils	a4dab848a4490e8e48cf0baab3e61bc2	optfeature	30ce9dec2b8943338c9b015bd32bac6a	toolchain-funcs	9ea1c67b6f8315fdc2568abb674519aa	virtualx	fa024aa649b6bd544144bf94893d402c	xdg	6024fbc93167fad782e2032933654857	xdg-utils	4f29a8b760a594a212abe9c2ba957c31
+_md5_=5419d431bd9405bb3eb3f92f9fe349bb