media-sound/strawberry : adjust deps

4 files changed, 141 insertions, 0 deletions

diff --git a/media-sound/strawberry/Manifest b/media-sound/strawberry/Manifest
new file mode 100644
index 00000000..fbc878e8
--- /dev/null
+++ b/media-sound/strawberry/Manifest
@@ -0,0 +1 @@
+DIST strawberry-1.0.21.tar.xz 11240920 BLAKE2B 8864d487dc1d097de8d9e98a5a271d33f05cfb00d4a66ab26aa1cf036b40bb6f595e8f23603e47174f9ef578369d9545b961fe5c5435a2bc3db1c6559968c4a5 SHA512 0378c80b662e9795271e2290c253e6ce523a136cd56a31e4475c02552979aef82f52676e3f66101cc01d6fab0284be6b006595d6c1a01ad05359714bf2574867
diff --git a/media-sound/strawberry/strawberry-1.0.21-r10.ebuild b/media-sound/strawberry/strawberry-1.0.21-r10.ebuild
new file mode 100644
index 00000000..4daea537
--- /dev/null
+++ b/media-sound/strawberry/strawberry-1.0.21-r10.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic plocale xdg
+
+PLOCALES="ca cs de es es_AR es_ES es_MX fi fr hu id it ja ko nb nl pl pt_BR ru sv uk zh_CN"
+
+DESCRIPTION="Modern music player and library organizer based on Clementine and Qt"
+HOMEPAGE="https://www.strawberrymusicplayer.org/"
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/strawberrymusicplayer/strawberry"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/strawberrymusicplayer/strawberry/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="cdda debug +gstreamer icu ipod moodbar mtp pulseaudio +udisks vlc"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+COMMON_DEPEND="
+	dev-db/sqlite:=
+	dev-libs/glib:2
+	dev-libs/protobuf:=
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/alsa-lib
+	media-libs/libebur128
+	media-libs/taglib
+	x11-libs/libX11
+	cdda? ( dev-libs/libcdio:= )
+	gstreamer? (
+		media-libs/chromaprint:=
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	icu? ( dev-libs/icu:= )
+	ipod? ( media-libs/libgpod )
+	moodbar? ( sci-libs/fftw:3.0 )
+	mtp? ( media-libs/libmtp )
+	pulseaudio? ( media-libs/libpulse )
+	vlc? ( media-video/vlc )
+"
+# Note: sqlite driver of dev-qt/qtsql is bundled, so no sqlite use is required; check if this can be overcome someway;
+RDEPEND="${COMMON_DEPEND}
+	gstreamer? (
+		media-plugins/gst-plugins-meta:1.0
+		media-plugins/gst-plugins-soup:1.0
+		media-plugins/gst-plugins-taglib:1.0
+	)
+	mtp? ( gnome-base/gvfs[mtp] )
+	udisks? ( sys-fs/udisks:2 )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-cpp/gtest
+	dev-libs/boost
+	dev-qt/qttest:5
+"
+
+DOCS=( Changelog README.md )
+
+REQUIRED_USE="
+	cdda? ( gstreamer )
+	|| ( gstreamer vlc )
+"
+
+src_prepare() {
+	plocale_find_changes "src/translations" "" ".po"
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# spotify is not in portage
+	local mycmakeargs=(
+		-DBUILD_WERROR=OFF
+		# avoid automagically enabling of ccache (bug #611010)
+		-DCCACHE_EXECUTABLE=OFF
+		-DENABLE_GIO=ON
+		-DLINGUAS="$(plocale_get_locales)"
+		-DENABLE_AUDIOCD="$(usex cdda)"
+		-DENABLE_GSTREAMER="$(usex gstreamer)"
+		-DUSE_ICU="$(usex icu)"
+		-DENABLE_LIBGPOD="$(usex ipod)"
+		-DENABLE_LIBMTP="$(usex mtp)"
+		-DENABLE_LIBPULSE="$(usex pulseaudio)"
+		-DENABLE_MOODBAR="$(usex moodbar)"
+		-DENABLE_MUSICBRAINZ="$(usex gstreamer)"
+		-DENABLE_SONGFINGERPRINTING="$(usex gstreamer)"
+		-DENABLE_UDISKS2="$(usex udisks)"
+		-DENABLE_VLC="$(usex vlc)"
+		-DQT_VERSION_MAJOR=5
+	)
+
+	use !debug && append-cppflags -DQT_NO_DEBUG_OUTPUT
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if use gstreamer ; then
+		elog "Note that list of supported formats is controlled by media-plugins/gst-plugins-meta "
+		elog "USE flags. You may be interested in setting aac, flac, mp3, ogg or wavpack USE flags "
+		elog "depending on your preferences"
+	fi
+}
diff --git a/metadata/md5-cache/media-sound/strawberry-1.0.21-r10 b/metadata/md5-cache/media-sound/strawberry-1.0.21-r10
new file mode 100644
index 00000000..1e0e159d
--- /dev/null
+++ b/metadata/md5-cache/media-sound/strawberry-1.0.21-r10
@@ -0,0 +1,17 @@
+BDEPEND=dev-qt/linguist-tools:5 sys-devel/gettext virtual/pkgconfig >=dev-util/ninja-1.8.2 >=dev-util/cmake-3.20.5
+DEFINED_PHASES=compile configure install postinst postrm preinst prepare test
+DEPEND=dev-db/sqlite:= dev-libs/glib:2 dev-libs/protobuf:= dev-qt/qtconcurrent:5 dev-qt/qtcore:5 dev-qt/qtdbus:5 dev-qt/qtgui:5 dev-qt/qtnetwork:5[ssl] dev-qt/qtsql:5[sqlite] dev-qt/qtwidgets:5 dev-qt/qtx11extras:5 media-libs/alsa-lib media-libs/libebur128 media-libs/taglib x11-libs/libX11 cdda? ( dev-libs/libcdio:= ) gstreamer? ( media-libs/chromaprint:= media-libs/gstreamer:1.0 media-libs/gst-plugins-base:1.0 ) icu? ( dev-libs/icu:= ) ipod? ( media-libs/libgpod ) moodbar? ( sci-libs/fftw:3.0 ) mtp? ( media-libs/libmtp ) pulseaudio? ( media-libs/libpulse ) vlc? ( media-video/vlc ) dev-cpp/gtest dev-libs/boost dev-qt/qttest:5
+DESCRIPTION=Modern music player and library organizer based on Clementine and Qt
+EAPI=8
+HOMEPAGE=https://www.strawberrymusicplayer.org/
+IDEPEND=dev-util/desktop-file-utils x11-misc/shared-mime-info
+INHERIT=cmake flag-o-matic plocale xdg
+IUSE=cdda debug +gstreamer icu ipod moodbar mtp pulseaudio +udisks vlc
+KEYWORDS=~amd64 ~arm64 ~ppc64 ~x86
+LICENSE=GPL-3
+RDEPEND=dev-db/sqlite:= dev-libs/glib:2 dev-libs/protobuf:= dev-qt/qtconcurrent:5 dev-qt/qtcore:5 dev-qt/qtdbus:5 dev-qt/qtgui:5 dev-qt/qtnetwork:5[ssl] dev-qt/qtsql:5[sqlite] dev-qt/qtwidgets:5 dev-qt/qtx11extras:5 media-libs/alsa-lib media-libs/libebur128 media-libs/taglib x11-libs/libX11 cdda? ( dev-libs/libcdio:= ) gstreamer? ( media-libs/chromaprint:= media-libs/gstreamer:1.0 media-libs/gst-plugins-base:1.0 ) icu? ( dev-libs/icu:= ) ipod? ( media-libs/libgpod ) moodbar? ( sci-libs/fftw:3.0 ) mtp? ( media-libs/libmtp ) pulseaudio? ( media-libs/libpulse ) vlc? ( media-video/vlc ) gstreamer? ( media-plugins/gst-plugins-meta:1.0 media-plugins/gst-plugins-soup:1.0 media-plugins/gst-plugins-taglib:1.0 ) mtp? ( gnome-base/gvfs[mtp] ) udisks? ( sys-fs/udisks:2 )
+REQUIRED_USE=cdda? ( gstreamer ) || ( gstreamer vlc )
+SLOT=0
+SRC_URI=https://github.com/strawberrymusicplayer/strawberry/releases/download/1.0.21/strawberry-1.0.21.tar.xz
+_eclasses_=cmake	0f2e0c197fad0312f3c4765c9cf36271	flag-o-matic	baa4d385108ac87993edac956a916a36	multilib	c19072c3cd7ac5cb21de013f7e9832e0	multiprocessing	30ead54fa2e2b5f9cd4e612ffc34d0fe	ninja-utils	39e7a84b06eff4efd9f2e0c3d1668b98	plocale	950fbaec7deeba41b5bcc0572cca99b9	toolchain-funcs	fbbbc99d10168de2926e06da7169b8dc	xdg	4a14c5c24f121e7da66e5aab4a168c6e	xdg-utils	baea6080dd821f5562d715887954c9d3
+_md5_=785b717cd0b7f4861fc0679373061fdb
diff --git a/metadata/pkg_desc_index b/metadata/pkg_desc_index
index eecf7d04..bffd3a89 100644
--- a/metadata/pkg_desc_index
+++ b/metadata/pkg_desc_index
@@ -34,6 +34,7 @@ lxqt-base/lxqt-session 1.3.0-r1: LXQt Session Manager
 mail-client/mailspring 1.9.2-r1: A beautiful fast and maintained fork of Nylas Mail
 media-libs/portsmf 239-r1: The Tenacity fork of PortSMF, a Standard MIDI File library
 media-sound/cantata 2.5.0-r10: Featureful and configurable Qt client for the music player daemon (MPD)
+media-sound/strawberry 1.0.21-r10: Modern music player and library organizer based on Clementine and Qt
 media-tv/sopcast 3.2.6-r4: SopCast free P2P Internet TV binary
 media-video/guvcview 2.0.6-r10: Simple Qt5 or GTK+3 interface for capturing and viewing video from v4l2 devices
 net-dialup/rp-pppoe 4.0-r5: A user-mode PPPoE client and server suite for Linux