dev-qt/qt-creator : fixed in gentoo, drop from overlay

4 files changed, 0 insertions, 250 deletions

diff --git a/dev-qt/qt-creator/Manifest b/dev-qt/qt-creator/Manifest
deleted file mode 100644
index 8613fc7c..00000000
--- a/dev-qt/qt-creator/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST qt-creator-opensource-src-6.0.0.tar.xz 44361156 BLAKE2B 8853b69036b969233981d31236535b2bbb74e9cf9293f0100c5caf614a5e8e80c83b0a4b038ebbefa64a4fe0cb75728d5ed34f45d8ab9cd1e283dae943fbb348 SHA512 4d97b18cb5ad8388f3ea0f1cff3b4d0cb04251d2dba22770a7d9f387efbe670b9461a8d83e08a92aefb6472c36e19d0902ff42fd85fd224318b99c66d2526bbb
diff --git a/dev-qt/qt-creator/qt-creator-6.0.0-r1.ebuild b/dev-qt/qt-creator/qt-creator-6.0.0-r1.ebuild
deleted file mode 100644
index 4c0bbb64..00000000
--- a/dev-qt/qt-creator/qt-creator-6.0.0-r1.ebuild
+++ /dev/null
@@ -1,231 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-LLVM_MAX_SLOT=13
-PLOCALES="cs da de fr hr ja pl ru sl uk zh-CN zh-TW"
-
-inherit llvm qmake-utils virtualx xdg
-
-DESCRIPTION="Lightweight IDE for C++/QML development centering around Qt"
-HOMEPAGE="https://doc.qt.io/qtcreator/"
-
-if [[ ${PV} == *9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://code.qt.io/${PN}/${PN}.git"
-else
-	MY_PV=${PV/_/-}
-	MY_P=${PN}-opensource-src-${MY_PV}
-	[[ ${MY_PV} == ${PV} ]] && MY_REL=official || MY_REL=development
-	SRC_URI="https://download.qt.io/${MY_REL}_releases/${PN/-}/$(ver_cut 1-2)/${MY_PV}/${MY_P}.tar.xz"
-	S=${WORKDIR}/${MY_P}
-	KEYWORDS="~amd64 ~arm ~x86"
-fi
-
-LICENSE="GPL-3"
-SLOT="0"
-QTC_PLUGINS=(android +autotest autotools:autotoolsprojectmanager baremetal bazaar beautifier boot2qt '+clang:clangcodemodel|clangformat|clangtools'
-	clearcase +cmake:cmakeprojectmanager conan cppcheck ctfvisualizer cvs +designer docker +git glsl:glsleditor +help incredibuild
-	+lsp:languageclient mcu:mcusupport mercurial meson:mesonprojectmanager modeling:modeleditor nim perforce perfprofiler python
-	qbs:qbsprojectmanager +qmake:qmakeprojectmanager '+qml:qmldesigner|qmljseditor|qmlpreview|qmlprojectmanager|studiowelcome'
-	qmlprofiler qnx remotelinux scxml:scxmleditor serialterminal silversearcher subversion valgrind webassembly)
-IUSE="doc systemd test webengine ${QTC_PLUGINS[@]%:*}"
-RESTRICT="!test? ( test )"
-REQUIRED_USE="
-	android? ( lsp )
-	boot2qt? ( remotelinux )
-	clang? ( lsp )
-	mcu? ( baremetal cmake )
-	python? ( lsp )
-	qml? ( qmake )
-	qnx? ( remotelinux )
-"
-
-# minimum Qt version required
-QT_PV="5.15:5"
-
-BDEPEND="
-	>=dev-qt/linguist-tools-${QT_PV}
-	virtual/pkgconfig
-	doc? ( >=dev-qt/qdoc-${QT_PV} )
-"
-CDEPEND="
-	>=dev-qt/qtconcurrent-${QT_PV}
-	>=dev-qt/qtcore-${QT_PV}
-	>=dev-qt/qtdeclarative-${QT_PV}[widgets]
-	>=dev-qt/qtgui-${QT_PV}
-	>=dev-qt/qtnetwork-${QT_PV}[ssl]
-	>=dev-qt/qtprintsupport-${QT_PV}
-	>=dev-qt/qtquickcontrols-${QT_PV}
-	>=dev-qt/qtscript-${QT_PV}
-	>=dev-qt/qtsql-${QT_PV}[sqlite]
-	>=dev-qt/qtsvg-${QT_PV}
-	>=dev-qt/qtwidgets-${QT_PV}
-	>=dev-qt/qtx11extras-${QT_PV}
-	>=dev-qt/qtxml-${QT_PV}
-	>=kde-frameworks/syntax-highlighting-5.87:5
-	clang? (
-		>=dev-cpp/yaml-cpp-0.6.2:=
-		|| (
-			sys-devel/clang:13
-			sys-devel/clang:12
-			sys-devel/clang:11
-		)
-		<sys-devel/clang-$((LLVM_MAX_SLOT + 1)):=
-	)
-	designer? ( >=dev-qt/designer-${QT_PV} )
-	help? (
-		>=dev-qt/qthelp-${QT_PV}
-		webengine? ( >=dev-qt/qtwebengine-${QT_PV}[widgets] )
-	)
-	perfprofiler? ( dev-libs/elfutils )
-	serialterminal? ( >=dev-qt/qtserialport-${QT_PV} )
-	systemd? ( sys-apps/systemd:= )
-"
-DEPEND="${CDEPEND}
-	test? (
-		>=dev-qt/qtdeclarative-${QT_PV}[localstorage]
-		>=dev-qt/qtquickcontrols2-${QT_PV}
-		>=dev-qt/qttest-${QT_PV}
-		>=dev-qt/qtxmlpatterns-${QT_PV}[qml]
-	)
-"
-RDEPEND="${CDEPEND}
-	sys-devel/gdb[python]
-	cppcheck? ( dev-util/cppcheck )
-	cvs? ( dev-vcs/cvs )
-	git? ( dev-vcs/git )
-	mercurial? ( dev-vcs/mercurial )
-	qml? ( >=dev-qt/qtquicktimeline-${QT_PV} )
-	silversearcher? ( sys-apps/the_silver_searcher )
-	subversion? ( dev-vcs/subversion )
-	valgrind? ( dev-util/valgrind )
-"
-# qt translations must also be installed or qt-creator translations won't be loaded
-for x in ${PLOCALES}; do
-	IUSE+=" l10n_${x}"
-	RDEPEND+=" l10n_${x}? ( >=dev-qt/qttranslations-${QT_PV} )"
-done
-unset x
-
-llvm_check_deps() {
-	has_version -d "sys-devel/clang:${LLVM_SLOT}"
-}
-
-pkg_setup() {
-	use clang && llvm_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	# disable unwanted plugins
-	for plugin in "${QTC_PLUGINS[@]#[+-]}"; do
-		if ! use ${plugin%:*}; then
-			sed -i -re "s/(^\s+|\s*SUBDIRS\s*\+=.*)\<(${plugin#*:})\>(.*)/\1\3/" \
-				src/plugins/plugins.pro || die "failed to disable ${plugin%:*} plugin"
-		fi
-	done
-	sed -i -re '/\<(ios|updateinfo|winrt)\>/d' src/plugins/plugins.pro || die
-
-	# avoid building unused support libraries and tools
-	if ! use clang; then
-		sed -i -e '/yaml-cpp/d' src/libs/libs.pro || die
-		sed -i -e '/clangbackend/d' src/tools/tools.pro || die
-	fi
-	if ! use glsl; then
-		sed -i -e '/glsl/d' src/libs/libs.pro || die
-	fi
-	if ! use lsp; then
-		sed -i -e '/languageserverprotocol/d' src/libs/libs.pro tests/auto/auto.pro || die
-	fi
-	if ! use modeling; then
-		sed -i -e '/modelinglib/d' src/libs/libs.pro || die
-	fi
-	if ! use perfprofiler; then
-		rm -r src/tools/perfparser || die
-		if ! use ctfvisualizer && ! use qmlprofiler; then
-			sed -i -e '/tracing/d' src/libs/libs.pro tests/auto/auto.pro || die
-		fi
-	fi
-	if ! use qmake; then
-		sed -i -e '/buildoutputparser/d' src/tools/tools.pro || die
-	fi
-	if ! use qml; then
-		sed -i -e '/advanceddockingsystem\|qmleditorwidgets/d' src/libs/libs.pro || die
-		sed -i -e '/qml2puppet/d' src/tools/tools.pro || die
-		sed -i -e '/qmldesigner\|qmlprojectmanager/d' tests/auto/qml/qml.pro || die
-	fi
-	if ! use valgrind; then
-		sed -i -e '/valgrindfake/d' src/tools/tools.pro || die
-		sed -i -e '/valgrind/d' tests/auto/auto.pro || die
-	fi
-
-	# automagic dep on qtwebengine
-	if ! use webengine; then
-		sed -i -e 's/isEmpty(QT\.webenginewidgets\.name)/true/' src/plugins/help/help.pro || die
-	fi
-
-	# disable broken or unreliable tests
-	sed -i -e 's/\(manual\|tools\|unit\)//g' tests/tests.pro || die
-	sed -i -e '/dumpers\.pro/d' tests/auto/debugger/debugger.pro || die
-	sed -i -e '/CONFIG -=/s/$/ testcase/' tests/auto/extensionsystem/pluginmanager/correctplugins1/plugin?/plugin?.pro || die
-	sed -i -e '/reformatter/d' tests/auto/qml/qml.pro || die
-	sed -i -e 's/\<\(imports\|\)check\>//' tests/auto/qml/codemodel/codemodel.pro || die
-	sed -i -e '/timelineitemsrenderpass/d' tests/auto/tracing/tracing.pro || die
-	sed -i -e '/qtcprocess/d' tests/auto/utils/utils.pro || die
-
-	# do not install test binaries
-	sed -i -e '/CONFIG +=/s/$/ no_testcase_installs/' tests/auto/{qttest.pri,json/json.pro} || die
-
-	# fix path to some clang headers
-	sed -i -e "/^CLANG_INCLUDE_DIR\s*=/s:\$\${LLVM_LIBDIR}:${EPREFIX}/usr/lib:" src/shared/clang/clang_defines.pri || die
-
-	# fix translations
-	local lang languages=
-	for lang in ${PLOCALES}; do
-		use l10n_${lang} && languages+=" ${lang/-/_}"
-	done
-	sed -i -e "/^LANGUAGES\s*=/s:=.*:=${languages}:" share/qtcreator/translations/translations.pro || die
-
-	# remove bundled syntax-highlighting
-	rm -r src/libs/3rdparty/syntax-highlighting || die
-
-	# remove bundled yaml-cpp
-	rm -r src/libs/3rdparty/yaml-cpp || die
-
-	# remove bundled qbs
-	rm -r src/shared/qbs || die
-
-	# TODO: unbundle sqlite
-}
-
-src_configure() {
-	eqmake5 IDE_LIBRARY_BASENAME="$(get_libdir)" \
-		IDE_PACKAGE_MODE=1 \
-		KSYNTAXHIGHLIGHTING_LIB_DIR="${EPREFIX}/usr/$(get_libdir)" \
-		KSYNTAXHIGHLIGHTING_INCLUDE_DIR="${EPREFIX}/usr/include/KF5/KSyntaxHighlighting/KSyntaxHighlighting" \
-		$(use clang && echo LLVM_INSTALL_DIR="$(get_llvm_prefix ${LLVM_MAX_SLOT})") \
-		$(use qbs && echo QBS_INSTALL_DIR="${EPREFIX}/usr") \
-		$(use systemd && echo CONFIG+=journald) \
-		$(use test && echo BUILD_TESTS=1)
-}
-
-src_test() {
-	cd tests/auto && virtx default
-}
-
-src_install() {
-	emake INSTALL_ROOT="${ED}/usr" install
-
-	dodoc dist/{changes-*,known-issues}
-
-	# install documentation
-	if use doc; then
-		emake docs
-		# don't use ${PF} or the doc will not be found
-		insinto /usr/share/doc/qtcreator
-		doins share/doc/qtcreator/qtcreator{,-dev}.qch
-		docompress -x /usr/share/doc/qtcreator/qtcreator{,-dev}.qch
-	fi
-}
diff --git a/metadata/md5-cache/dev-qt/qt-creator-6.0.0-r1 b/metadata/md5-cache/dev-qt/qt-creator-6.0.0-r1
deleted file mode 100644
index 9d9e3655..00000000
--- a/metadata/md5-cache/dev-qt/qt-creator-6.0.0-r1
+++ /dev/null
@@ -1,17 +0,0 @@
-BDEPEND=>=dev-qt/linguist-tools-5.15:5 virtual/pkgconfig doc? ( >=dev-qt/qdoc-5.15:5 ) test? ( x11-base/xorg-server[xvfb] x11-apps/xhost )
-DEFINED_PHASES=configure install postinst postrm preinst prepare setup test
-DEPEND=>=dev-qt/qtconcurrent-5.15:5 >=dev-qt/qtcore-5.15:5 >=dev-qt/qtdeclarative-5.15:5[widgets] >=dev-qt/qtgui-5.15:5 >=dev-qt/qtnetwork-5.15:5[ssl] >=dev-qt/qtprintsupport-5.15:5 >=dev-qt/qtquickcontrols-5.15:5 >=dev-qt/qtscript-5.15:5 >=dev-qt/qtsql-5.15:5[sqlite] >=dev-qt/qtsvg-5.15:5 >=dev-qt/qtwidgets-5.15:5 >=dev-qt/qtx11extras-5.15:5 >=dev-qt/qtxml-5.15:5 >=kde-frameworks/syntax-highlighting-5.87:5 clang? ( >=dev-cpp/yaml-cpp-0.6.2:= || ( sys-devel/clang:13 sys-devel/clang:12 sys-devel/clang:11 ) <sys-devel/clang-14:= ) designer? ( >=dev-qt/designer-5.15:5 ) help? ( >=dev-qt/qthelp-5.15:5 webengine? ( >=dev-qt/qtwebengine-5.15:5[widgets] ) ) perfprofiler? ( dev-libs/elfutils ) serialterminal? ( >=dev-qt/qtserialport-5.15:5 ) systemd? ( sys-apps/systemd:= ) test? ( >=dev-qt/qtdeclarative-5.15:5[localstorage] >=dev-qt/qtquickcontrols2-5.15:5 >=dev-qt/qttest-5.15:5 >=dev-qt/qtxmlpatterns-5.15:5[qml] ) !!sys-devel/llvm:0 dev-util/desktop-file-utils x11-misc/shared-mime-info
-DESCRIPTION=Lightweight IDE for C++/QML development centering around Qt
-EAPI=7
-HOMEPAGE=https://doc.qt.io/qtcreator/
-INHERIT=llvm qmake-utils virtualx xdg
-IUSE=doc systemd test webengine android +autotest autotools baremetal bazaar beautifier boot2qt +clang clearcase +cmake conan cppcheck ctfvisualizer cvs +designer docker +git glsl +help incredibuild +lsp mcu mercurial meson modeling nim perforce perfprofiler python qbs +qmake +qml qmlprofiler qnx remotelinux scxml serialterminal silversearcher subversion valgrind webassembly l10n_cs l10n_da l10n_de l10n_fr l10n_hr l10n_ja l10n_pl l10n_ru l10n_sl l10n_uk l10n_zh-CN l10n_zh-TW test
-KEYWORDS=~amd64 ~arm ~x86
-LICENSE=GPL-3
-RDEPEND=>=dev-qt/qtconcurrent-5.15:5 >=dev-qt/qtcore-5.15:5 >=dev-qt/qtdeclarative-5.15:5[widgets] >=dev-qt/qtgui-5.15:5 >=dev-qt/qtnetwork-5.15:5[ssl] >=dev-qt/qtprintsupport-5.15:5 >=dev-qt/qtquickcontrols-5.15:5 >=dev-qt/qtscript-5.15:5 >=dev-qt/qtsql-5.15:5[sqlite] >=dev-qt/qtsvg-5.15:5 >=dev-qt/qtwidgets-5.15:5 >=dev-qt/qtx11extras-5.15:5 >=dev-qt/qtxml-5.15:5 >=kde-frameworks/syntax-highlighting-5.87:5 clang? ( >=dev-cpp/yaml-cpp-0.6.2:= || ( sys-devel/clang:13 sys-devel/clang:12 sys-devel/clang:11 ) <sys-devel/clang-14:= ) designer? ( >=dev-qt/designer-5.15:5 ) help? ( >=dev-qt/qthelp-5.15:5 webengine? ( >=dev-qt/qtwebengine-5.15:5[widgets] ) ) perfprofiler? ( dev-libs/elfutils ) serialterminal? ( >=dev-qt/qtserialport-5.15:5 ) systemd? ( sys-apps/systemd:= ) sys-devel/gdb[python] cppcheck? ( dev-util/cppcheck ) cvs? ( dev-vcs/cvs ) git? ( dev-vcs/git ) mercurial? ( dev-vcs/mercurial ) qml? ( >=dev-qt/qtquicktimeline-5.15:5 ) silversearcher? ( sys-apps/the_silver_searcher ) subversion? ( dev-vcs/subversion ) valgrind? ( dev-util/valgrind ) l10n_cs? ( >=dev-qt/qttranslations-5.15:5 ) l10n_da? ( >=dev-qt/qttranslations-5.15:5 ) l10n_de? ( >=dev-qt/qttranslations-5.15:5 ) l10n_fr? ( >=dev-qt/qttranslations-5.15:5 ) l10n_hr? ( >=dev-qt/qttranslations-5.15:5 ) l10n_ja? ( >=dev-qt/qttranslations-5.15:5 ) l10n_pl? ( >=dev-qt/qttranslations-5.15:5 ) l10n_ru? ( >=dev-qt/qttranslations-5.15:5 ) l10n_sl? ( >=dev-qt/qttranslations-5.15:5 ) l10n_uk? ( >=dev-qt/qttranslations-5.15:5 ) l10n_zh-CN? ( >=dev-qt/qttranslations-5.15:5 ) l10n_zh-TW? ( >=dev-qt/qttranslations-5.15:5 )
-REQUIRED_USE=android? ( lsp ) boot2qt? ( remotelinux ) clang? ( lsp ) mcu? ( baremetal cmake ) python? ( lsp ) qml? ( qmake ) qnx? ( remotelinux )
-RESTRICT=!test? ( test )
-SLOT=0
-SRC_URI=https://download.qt.io/official_releases/qtcreator/6.0/6.0.0/qt-creator-opensource-src-6.0.0.tar.xz
-_eclasses_=llvm	29d5332b8530fb760c2ca71ad6706858	multilib	5ca4e49abed8e3a2f7b56920eadee157	qmake-utils	59420c906278d16deaaa629f9d115707	toolchain-funcs	441f754fd75cd4fd1fa06fbc17da6144	virtualx	644887c82aefdf12001489391fca4f02	xdg	6024fbc93167fad782e2032933654857	xdg-utils	ac0e315a3688929e34ac75b139e7349a
-_md5_=802793020550eb68d539a244eac471c2
diff --git a/metadata/pkg_desc_index b/metadata/pkg_desc_index
index bd2076d3..306fd5af 100644
--- a/metadata/pkg_desc_index
+++ b/metadata/pkg_desc_index
@@ -22,7 +22,6 @@ dev-python/click 7.1.2-r100: A Python package for creating beautiful command lin
 dev-python/sh 1.12.14-r4: Python process launching
 dev-python/typer 0.2.1-r2: Build great CLIs. Easy to code. Based on Python type hints
 dev-python/wget 2.2-r2: Python library for downloading from http URLs
-dev-qt/qt-creator 6.0.0-r1: Lightweight IDE for C++/QML development centering around Qt
 dev-util/lxqt-build-tools 0.11.0-r1: LXQt Build Tools
 gui-libs/display-manager-init 1.1.1-r1: RC init files for starting display and login managers
 kde-plasma/kinfocenter 5.26.2-r5: Utility providing information about the computer hardware