media-libs/libv4l && media-tv/v4l-utils : it seems gentoo forgot to update these (last commit : Sat, 13 Jan 2018 11:27)

4 files changed, 124 insertions, 0 deletions

diff --git a/media-libs/libv4l/Manifest b/media-libs/libv4l/Manifest
new file mode 100644
index 00000000..8b168bf1
--- /dev/null
+++ b/media-libs/libv4l/Manifest
@@ -0,0 +1 @@
+DIST v4l-utils-1.16.3.tar.bz2 1894961 BLAKE2B 71c674abbb3415e592354998e1baa3eedbb4be21757bef80b463ea987e9fc231789e6b333b37d0d9916cb30729e04951dc9f1755ab00a82502fdc415b00cb9a2 SHA512 404672d18d94861c6957ea3a15a6a48f238d3859940810952a5a8cc33b57f1a360d1a19af28405c01b073c0ece90c5995a71dbe6544b30bdb8eace7daeb4bc0b
diff --git a/media-libs/libv4l/libv4l-1.16.3-r1337.ebuild b/media-libs/libv4l/libv4l-1.16.3-r1337.ebuild
new file mode 100644
index 00000000..5bfea504
--- /dev/null
+++ b/media-libs/libv4l/libv4l-1.16.3-r1337.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit eutils libtool linux-info multilib-minimal
+
+MY_P="v4l-utils-${PV}"
+
+DESCRIPTION="Separate libraries ebuild from upstream v4l-utils package"
+HOMEPAGE="https://git.linuxtv.org/v4l-utils.git"
+SRC_URI="https://linuxtv.org/downloads/v4l-utils/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/0"
+KEYWORDS="~amd64"
+IUSE="jpeg"
+
+# The libraries only link to -ljpeg, therefore multilib depend only for virtual/jpeg.
+RDEPEND="jpeg? ( >=virtual/jpeg-0-r2:0=[${MULTILIB_USEDEP}] )
+	virtual/libudev
+	!media-tv/v4l2-ctl
+	!<media-tv/ivtv-utils-1.4.0-r2"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/os-headers
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	CONFIG_CHECK="~SHMEM"
+	linux-info_pkg_setup
+}
+
+src_prepare() {
+	default
+	elibtoolize
+}
+
+multilib_src_configure() {
+	# Hard disable the flags that apply only to the utils.
+	ECONF_SOURCE=${S} \
+	econf \
+		--disable-static \
+		--disable-qv4l2 \
+		--disable-v4l-utils \
+		$(use_with jpeg)
+}
+
+multilib_src_compile() {
+	emake -C lib
+}
+
+multilib_src_install() {
+	emake -j1 -C lib DESTDIR="${D}" install
+}
+
+multilib_src_install_all() {
+	dodoc ChangeLog README.lib* TODO
+	prune_libtool_files --all
+}
diff --git a/media-tv/v4l-utils/Manifest b/media-tv/v4l-utils/Manifest
new file mode 100644
index 00000000..8b168bf1
--- /dev/null
+++ b/media-tv/v4l-utils/Manifest
@@ -0,0 +1 @@
+DIST v4l-utils-1.16.3.tar.bz2 1894961 BLAKE2B 71c674abbb3415e592354998e1baa3eedbb4be21757bef80b463ea987e9fc231789e6b333b37d0d9916cb30729e04951dc9f1755ab00a82502fdc415b00cb9a2 SHA512 404672d18d94861c6957ea3a15a6a48f238d3859940810952a5a8cc33b57f1a360d1a19af28405c01b073c0ece90c5995a71dbe6544b30bdb8eace7daeb4bc0b
diff --git a/media-tv/v4l-utils/v4l-utils-1.16.3-r1337.ebuild b/media-tv/v4l-utils/v4l-utils-1.16.3-r1337.ebuild
new file mode 100644
index 00000000..4638e131
--- /dev/null
+++ b/media-tv/v4l-utils/v4l-utils-1.16.3-r1337.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit flag-o-matic udev xdg-utils
+
+DESCRIPTION="Separate utilities ebuild from upstream v4l-utils package"
+HOMEPAGE="http://git.linuxtv.org/v4l-utils.git"
+SRC_URI="http://linuxtv.org/downloads/v4l-utils/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="qt5"
+
+RDEPEND=">=media-libs/libv4l-${PV}
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtopengl:5
+		virtual/opengl
+		media-libs/alsa-lib
+	)
+	virtual/libudev
+	!media-tv/v4l2-ctl
+	!<media-tv/ivtv-utils-1.4.0-r2"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.14.1-sysmacros.patch ) #580910
+
+src_configure() {
+	if use qt5; then
+		append-cxxflags -std=c++11
+		local qt5_paths=( \
+			MOC="$(pkg-config --variable=host_bins Qt5Core)/moc" \
+			UIC="$(pkg-config --variable=host_bins Qt5Core)/uic" \
+			RCC="$(pkg-config --variable=host_bins Qt5Core)/rcc" \
+		)
+	fi
+	# Hard disable the flags that apply only to the libs.
+	econf \
+		--disable-static \
+		$(use_enable qt5 qv4l2) \
+		--with-udevdir="$(get_udevdir)" \
+		--without-jpeg \
+		"${qt5_paths[@]}"
+}
+
+src_install() {
+	emake -C utils DESTDIR="${D}" install
+	emake -C contrib DESTDIR="${D}" install
+
+	dodoc README
+	newdoc utils/libv4l2util/TODO TODO.libv4l2util
+	newdoc utils/libmedia_dev/README README.libmedia_dev
+	newdoc utils/dvb/README README.dvb
+	newdoc utils/v4l2-compliance/fixme.txt fixme.txt.v4l2-compliance
+}