From bed9fb923f6cc27b39b2277bbc7832126e761b1c Mon Sep 17 00:00:00 2001
From: stratact <stratact1@gmail.com>
Date: Sun, 22 Apr 2018 14:27:33 -0700
Subject: x11-misc/pcmanfm: version bump, remove patch x11-misc/libfm: version
 bump, remove patch x11-misc/libfm-extra: new package

---
 x11-libs/libfm-extra/libfm-extra-1.3.0.ebuild | 91 +++++++++++++++++++++++++++
 1 file changed, 91 insertions(+)
 create mode 100644 x11-libs/libfm-extra/libfm-extra-1.3.0.ebuild

(limited to 'x11-libs/libfm-extra/libfm-extra-1.3.0.ebuild')

diff --git a/x11-libs/libfm-extra/libfm-extra-1.3.0.ebuild b/x11-libs/libfm-extra/libfm-extra-1.3.0.ebuild
new file mode 100644
index 00000000..b962866e
--- /dev/null
+++ b/x11-libs/libfm-extra/libfm-extra-1.3.0.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit autotools xdg-utils
+
+MY_PV=${PV/_/}
+MY_PN="libfm"
+MY_P="${MY_PN}-${MY_PV}"
+DESCRIPTION="A library for file management"
+HOMEPAGE="http://pcmanfm.sourceforge.net/"
+SRC_URI="https://github.com/lxde/libfm/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+KEYWORDS="~alpha amd64 arm ~arm64 ~mips ppc x86 ~amd64-linux ~x86-linux"
+LICENSE="GPL-2"
+SLOT="0/5.0.1" #copy ABI_VERSION because it seems upstream change it randomly
+IUSE=""
+
+RDEPEND=">=dev-libs/glib-2.18:2"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+	sys-devel/gettext
+	!!<=x11-libs/libfm-1.2.3"
+
+S="${WORKDIR}"/${MY_P}
+
+src_prepare() {
+	sed -ie '/^SUBDIR.*=/s#docs##' "${S}"/Makefile.am || die "sed failed"
+	sed -ie '/^[[:space:]]*docs/d' configure.ac || die "sed failed"
+	sed -i -e "s:-O0::" -e "/-DG_ENABLE_DEBUG/s: -g::" \
+		configure.ac || die "sed failed"
+
+	#disable unused translations. Bug #356029
+	for trans in app-chooser ask-rename exec-file file-prop preferred-apps \
+		progress;do
+		echo "data/ui/"${trans}.ui >> po/POTFILES.in
+	done
+	#Remove -Werror for automake-1.12. Bug #421101
+	sed -i "s:-Werror::" configure.ac || die
+
+	# subslot sanity check
+	local sub_slot=${SLOT#*/}
+	local libfm_major_abi=$(sed -rne '/ABI_VERSION/s:.*=::p' src/Makefile.am | tr ':' '.')
+
+	if [[ ${sub_slot} != ${libfm_major_abi} ]]; then
+		eerror "Ebuild sub-slot (${sub_slot}) does not match ABI_VERSION(${libfm_major_abi})"
+		eerror "Please update SLOT variable as follows:"
+		eerror "    SLOT=\"${SLOT%%/*}/${libfm_major_abi}\""
+		eerror
+		die "sub-slot sanity check failed"
+	fi
+
+	eautoreconf
+	rm -r autom4te.cache || die
+}
+
+src_configure() {
+	econf --sysconfdir="${EPREFIX}/etc" --disable-dependency-tracking \
+		--disable-static --with-extra-only
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -exec rm -f '{}' +
+	# Sometimes a directory is created instead of a symlink. No idea why...
+	# It is wrong anyway. We expect a libfm-1.0 directory and then a libfm
+	# symlink to it.
+	if [[ -h ${D}/usr/include/${MY_PN} || -d ${D}/usr/include/${MY_PN} ]]; then
+		rm -r "${D}"/usr/include/${MY_PN}
+	fi
+}
+
+pkg_preinst() {
+	# Resolve the symlink mess. Bug #439570
+	[[ -d "${ROOT}"/usr/include/${MY_PN} ]] && \
+		rm -rf "${ROOT}"/usr/include/${MY_PN}
+	if [[ -d "${D}"/usr/include/${MY_PN}-1.0 ]]; then
+		cd "${D}"/usr/include
+		ln -s --force ${MY_PN}-1.0 ${MY_PN}
+	fi
+}
+
+pkg_postinst() {
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_mimeinfo_database_update
+}
-- 
cgit v1.2.3