From 5dbf4a78e5139a28a04746e296b48878294fbe7b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 26 Aug 2018 11:55:30 +0100
Subject: sys-fs/{spl,zfs} : version bump

---
 sys-fs/spl-utils/spl-utils-0.7.9.ebuild | 60 +++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 sys-fs/spl-utils/spl-utils-0.7.9.ebuild

(limited to 'sys-fs/spl-utils/spl-utils-0.7.9.ebuild')

diff --git a/sys-fs/spl-utils/spl-utils-0.7.9.ebuild b/sys-fs/spl-utils/spl-utils-0.7.9.ebuild
new file mode 100644
index 00000000..02a1ed1b
--- /dev/null
+++ b/sys-fs/spl-utils/spl-utils-0.7.9.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+inherit flag-o-matic autotools-utils
+
+MY_PN="spl"
+MY_P="${MY_PN}-${PV}"
+
+SRC_URI="https://github.com/zfsonlinux/zfs/releases/download/zfs-${PV}/${MY_P}.tar.gz"
+
+DESCRIPTION="The Solaris Porting Layer is a Linux kernel module which provides many of the Solaris kernel APIs"
+HOMEPAGE="http://zfsonlinux.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64"
+IUSE="debug"
+
+RESTRICT="debug? ( strip ) test"
+
+S="${WORKDIR}/${MY_P}"
+
+COMMON_DEPEND="dev-lang/perl
+	virtual/awk"
+DEPEND="${COMMON_DEPEND}"
+RDEPEND="${COMMON_DEPEND}
+	!sys-devel/spl"
+
+AT_M4DIR="config"
+AUTOTOOLS_IN_SOURCE_BUILD="1"
+
+DOCS=( AUTHORS DISCLAIMER )
+
+src_prepare() {
+	# Workaround for hard coded path
+	sed -i "s|/sbin/lsmod|/bin/lsmod|" "${S}/scripts/check.sh" || \
+		die "Cannot patch check.sh"
+
+	# splat is unnecessary unless we are debugging
+	use debug || { sed -e 's/^subdir-m += splat$//' -i "${S}/module/Makefile.in" || die ; }
+
+	# Set module revision number
+	[ ${PV} != "9999" ] && \
+		{ sed -i "s/\(Release:\)\(.*\)1/\1\2${PR}-redcore/" "${S}/META" || die "Could not set Redcore release"; }
+
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	filter-ldflags -Wl,*
+
+	local myeconfargs=(
+		--bindir="${EPREFIX}/bin"
+		--sbindir="${EPREFIX}/sbin"
+		--with-config=user
+		$(use_enable debug)
+	)
+	autotools-utils_src_configure
+}
-- 
cgit v1.2.3