From ed40676841e317a2aafa04c4c804bb6043864740 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@rogentos.ro>
Date: Fri, 26 Feb 2016 23:50:05 +0000
Subject: repo cleanup...drop old ebuilds, drop ebuilds already in portage tree

---
 net-irc/quassel-core/quassel-core-0.10.0.ebuild | 139 ------------------------
 1 file changed, 139 deletions(-)
 delete mode 100644 net-irc/quassel-core/quassel-core-0.10.0.ebuild

(limited to 'net-irc/quassel-core/quassel-core-0.10.0.ebuild')

diff --git a/net-irc/quassel-core/quassel-core-0.10.0.ebuild b/net-irc/quassel-core/quassel-core-0.10.0.ebuild
deleted file mode 100644
index 7f17e8e0..00000000
--- a/net-irc/quassel-core/quassel-core-0.10.0.ebuild
+++ /dev/null
@@ -1,139 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: $
-
-EAPI=5
-
-inherit cmake-utils eutils pax-utils systemd user versionator
-
-EGIT_REPO_URI="git://git.quassel-irc.org/quassel"
-[[ "${PV}" == "9999" ]] && inherit git-r3
-
-DESCRIPTION="Qt4/KDE IRC client - the \"core\" (server) component"
-HOMEPAGE="http://quassel-irc.org/"
-MY_P=${P/-core}
-MY_PN=${PN/-core}
-[[ "${PV}" == "9999" ]] || SRC_URI="http://quassel-irc.org/pub/${MY_P/_/-}.tar.bz2"
-
-LICENSE="GPL-3"
-KEYWORDS="~amd64 ~x86"
-SLOT="0"
-IUSE="crypt dbus postgres +ssl syslog"
-
-SERVER_RDEPEND="
-	dev-qt/qtscript:4
-	crypt? (
-		app-crypt/qca:2
-		app-crypt/qca-ossl
-	)
-	!postgres? ( dev-qt/qtsql:4[sqlite] dev-db/sqlite:3[threadsafe(+),-secure-delete] )
-	postgres? ( dev-qt/qtsql:4[postgres] )
-	syslog? ( virtual/logger )
-"
-
-RDEPEND="
-	dev-qt/qtcore:4[ssl?]
-	${SERVER_RDEPEND}
-	"
-DEPEND="
-	${RDEPEND}
-	!net-irc/quassel-core-bin
-	"
-
-DOCS="AUTHORS ChangeLog README"
-
-S="${WORKDIR}/${MY_P/_/-}"
-
-pkg_setup() {
-	QUASSEL_DIR=/var/lib/${MY_PN}
-	QUASSEL_USER=${MY_PN}
-	# create quassel:quassel user
-	enewgroup "${QUASSEL_USER}"
-	enewuser "${QUASSEL_USER}" -1 -1 "${QUASSEL_DIR}" "${QUASSEL_USER}"
-}
-
-src_configure() {
-	local mycmakeargs=(
-		"-DWITH_LIBINDICATE=OFF"
-		"-DWANT_CORE=ON"
-		"-DWANT_QTCLIENT=OFF"
-		"-DWANT_MONO=OFF"
-		"-DWITH_WEBKIT=OFF"
-		"-DWITH_PHONON=OFF"
-		"-DWITH_KDE=OFF"
-		$(cmake-utils_use_with dbus)
-		$(cmake-utils_use_with ssl OPENSSL)
-		$(cmake-utils_use_with syslog)
-		"-DWITH_OXYGEN=OFF"
-		$(cmake-utils_use_with crypt)
-		"-DEMBED_DATA=OFF"
-	)
-
-	# -DSTATIC=ON
-	cmake-utils_src_configure
-}
-
-src_install() {
-	cmake-utils_src_install
-
-	rm -rf "${ED}"usr/share/apps/quassel/
-	rm -f "${ED}"usr/share/pixmaps/quassel.png
-	rm -f "${ED}"usr/share/icons/hicolor/48x48/apps/quassel.png
-
-	# server stuff
-
-	# needs PAX marking wrt bug#346255
-	pax-mark m "${ED}/usr/bin/quasselcore"
-
-	# prepare folders in /var/
-	keepdir "${QUASSEL_DIR}"
-	fowners "${QUASSEL_USER}":"${QUASSEL_USER}" "${QUASSEL_DIR}"
-
-	# init scripts & systemd unit
-	newinitd "${FILESDIR}"/quasselcore.init quasselcore
-	newconfd "${FILESDIR}"/quasselcore.conf quasselcore
-	systemd_dounit "${FILESDIR}"/quasselcore.service
-
-	# logrotate
-	insinto /etc/logrotate.d
-	newins "${FILESDIR}/quassel.logrotate" quassel
-}
-
-pkg_postinst() {
-	einfo "If you want to generate SSL certificate remember to run:"
-	einfo "	emerge --config =${CATEGORY}/${PF}"
-
-	# server || monolithic
-	einfo "Quassel can use net-misc/oidentd package if installed on your system."
-	einfo "Consider installing it if you want to run quassel within identd daemon."
-
-	# temporary info mesage
-	if [[ $(get_version_component_range 2 ${REPLACING_VERSIONS}) -lt 7 ]]; then
-		echo
-		ewarn "Please note that all configuration moved from"
-		ewarn "/home/\${QUASSEL_USER}/.config/quassel-irc.org/"
-		ewarn "to: ${QUASSEL_DIR}."
-		echo
-		ewarn "For migration, stop the core, move quasselcore files (pretty much"
-		ewarn "everything apart from quasselclient.conf and settings.qss) into"
-		ewarn "new location and then start server again."
-	fi
-}
-
-pkg_config() {
-	if use ssl; then
-		# generate the pem file only when it does not already exist
-		if [ ! -f "${QUASSEL_DIR}/quasselCert.pem" ]; then
-			einfo "Generating QUASSEL SSL certificate to: \"${QUASSEL_DIR}/quasselCert.pem\""
-			openssl req -x509 -nodes -days 365 -newkey rsa:2048 \
-				-keyout "${QUASSEL_DIR}/quasselCert.pem" \
-				-out "${QUASSEL_DIR}/quasselCert.pem"
-			# permissions for the key
-			chown ${QUASSEL_USER}:${QUASSEL_USER} "${QUASSEL_DIR}/quasselCert.pem"
-			chmod 400 "${QUASSEL_DIR}/quasselCert.pem"
-		else
-			einfo "Certificate \"${QUASSEL_DIR}/quasselCert.pem\" already exists."
-			einfo "Remove it if you want to create new one."
-		fi
-	fi
-}
-- 
cgit v1.2.3