From ce6655a372b67dbf744e1301300bef7c81ab2cb8 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 13 May 2023 09:17:44 +0100
Subject: net-dialup/rp-pppoe : import from gentoo, fix build

---
 net-dialup/rp-pppoe/rp-pppoe-4.0-r5.ebuild | 62 ++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 net-dialup/rp-pppoe/rp-pppoe-4.0-r5.ebuild

(limited to 'net-dialup/rp-pppoe/rp-pppoe-4.0-r5.ebuild')

diff --git a/net-dialup/rp-pppoe/rp-pppoe-4.0-r5.ebuild b/net-dialup/rp-pppoe/rp-pppoe-4.0-r5.ebuild
new file mode 100644
index 00000000..2c8e4ac4
--- /dev/null
+++ b/net-dialup/rp-pppoe/rp-pppoe-4.0-r5.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit readme.gentoo-r1
+
+DESCRIPTION="A user-mode PPPoE client and server suite for Linux"
+HOMEPAGE="https://dianne.skoll.ca/projects/rp-pppoe/ https://salsa.debian.org/dskoll/rp-pppoe"
+if [[ $PV = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI=https://github.com/dfskoll/rp-pppoe.git
+else
+	SRC_URI="https://dianne.skoll.ca/projects/rp-pppoe/download/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+
+S="${S}/src"
+
+RDEPEND="
+	net-dialup/ppp:=
+	sys-apps/iproute2
+"
+DEPEND=">=sys-kernel/linux-headers-2.6.25
+	elibc_musl? ( net-libs/ppp-defs )
+	${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/rp-pppoe-4.0-ar_environment.patch"
+)
+
+pkg_setup() {
+	# This is needed in multiple phases
+	PPPD_VER="$(best_version net-dialup/ppp)"
+	PPPD_VER="${PPPD_VER#*/*-}" #reduce it to ${PV}-${PR}
+	PPPD_VER="${PPPD_VER%%-*}" #reduce it to ${PV}
+
+	PPPD_PLUGIN_DIR="/usr/$(get_libdir)/pppd/${PPPD_VER}"
+}
+
+src_configure() {
+	addpredict /dev/ppp
+
+	econf --enable-plugin=/usr/include/pppd
+}
+
+src_compile() {
+	emake PLUGIN_PATH=rp-pppoe.so PLUGIN_DIR="${PPPD_PLUGIN_DIR}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" docdir="/usr/share/doc/${PF}" PLUGIN_DIR="${PPPD_PLUGIN_DIR}" install
+
+	# We don't need this README file here.
+	rm "${ED}${PPPD_PLUGIN_DIR}/README" || die "Error removing ${PPPD_PLUGIN_DIR}/README from installation"
+
+	newinitd "${FILESDIR}"/pppoe-server.initd pppoe-server
+	newconfd "${FILESDIR}"/pppoe-server.confd pppoe-server
+}
-- 
cgit v1.2.3