From e1759c9e8379289f72917ce2d2d7953fe9c4a7fb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 20 Jul 2019 10:21:25 +0100
Subject: media-tv/v4l-utils : version && EAPI bump

---
 media-tv/v4l-utils/Manifest                      |  2 +-
 media-tv/v4l-utils/v4l-utils-1.16.3-r1337.ebuild | 64 ----------------------
 media-tv/v4l-utils/v4l-utils-1.16.6-r314.ebuild  | 69 ++++++++++++++++++++++++
 3 files changed, 70 insertions(+), 65 deletions(-)
 delete mode 100644 media-tv/v4l-utils/v4l-utils-1.16.3-r1337.ebuild
 create mode 100644 media-tv/v4l-utils/v4l-utils-1.16.6-r314.ebuild

(limited to 'media-tv')

diff --git a/media-tv/v4l-utils/Manifest b/media-tv/v4l-utils/Manifest
index 8b168bf1..9552a52b 100644
--- a/media-tv/v4l-utils/Manifest
+++ b/media-tv/v4l-utils/Manifest
@@ -1 +1 @@
-DIST v4l-utils-1.16.3.tar.bz2 1894961 BLAKE2B 71c674abbb3415e592354998e1baa3eedbb4be21757bef80b463ea987e9fc231789e6b333b37d0d9916cb30729e04951dc9f1755ab00a82502fdc415b00cb9a2 SHA512 404672d18d94861c6957ea3a15a6a48f238d3859940810952a5a8cc33b57f1a360d1a19af28405c01b073c0ece90c5995a71dbe6544b30bdb8eace7daeb4bc0b
+DIST v4l-utils-1.16.6.tar.bz2 1893768 BLAKE2B f31cf794f6949fa2c1f45db8bae99a10a5fbc67af356889f636ab03cfd04011a82939a10f01145c56001b91655664530cfbda7d64c523752b8bb77159a1c80ab SHA512 f011218591e32b0ca3239373d9ea4739d7cfe3a6bef5f8a996253cea9b9d836ba488132e2a1b8f6f61cd69f1bcecc20e4b5c26f9c95a2a912e17c400b9fa9b58
diff --git a/media-tv/v4l-utils/v4l-utils-1.16.3-r1337.ebuild b/media-tv/v4l-utils/v4l-utils-1.16.3-r1337.ebuild
deleted file mode 100644
index cfd682d7..00000000
--- a/media-tv/v4l-utils/v4l-utils-1.16.3-r1337.ebuild
+++ /dev/null
@@ -1,64 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit flag-o-matic udev xdg-utils
-
-DESCRIPTION="Separate utilities ebuild from upstream v4l-utils package"
-HOMEPAGE="http://git.linuxtv.org/v4l-utils.git"
-SRC_URI="http://linuxtv.org/downloads/v4l-utils/${P}.tar.bz2"
-
-LICENSE="GPL-2+ LGPL-2.1+"
-SLOT="0"
-KEYWORDS="~amd64"
-IUSE="jpeg qt5"
-
-RDEPEND="
-	jpeg? (
-		>=media-libs/libv4l-${PV}[jpeg]
-	)
-	!jpeg? ( >=media-libs/libv4l-${PV}[-jpeg] )
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtopengl:5
-		virtual/opengl
-		media-libs/alsa-lib
-	)
-	virtual/libudev
-	!media-tv/v4l2-ctl
-	!<media-tv/ivtv-utils-1.4.0-r2"
-DEPEND="${RDEPEND}
-	sys-devel/gettext
-	virtual/pkgconfig"
-
-PATCHES=( "${FILESDIR}/sdlcam-only-build-if-using-jpeg.patch" )
-
-src_configure() {
-	if use qt5; then
-		append-cxxflags -std=c++11
-		local qt5_paths=( \
-			MOC="$(pkg-config --variable=host_bins Qt5Core)/moc" \
-			UIC="$(pkg-config --variable=host_bins Qt5Core)/uic" \
-			RCC="$(pkg-config --variable=host_bins Qt5Core)/rcc" \
-		)
-	fi
-	# Hard disable the flags that apply only to the libs.
-	econf \
-		--disable-static \
-		$(use_enable qt5 qv4l2) \
-		--with-udevdir="$(get_udevdir)" \
-		$(use_with jpeg) \
-		"${qt5_paths[@]}"
-}
-
-src_install() {
-	emake -C utils DESTDIR="${D}" install
-	emake -C contrib DESTDIR="${D}" install
-
-	dodoc README
-	newdoc utils/libv4l2util/TODO TODO.libv4l2util
-	newdoc utils/libmedia_dev/README README.libmedia_dev
-	newdoc utils/dvb/README README.dvb
-	newdoc utils/v4l2-compliance/fixme.txt fixme.txt.v4l2-compliance
-}
diff --git a/media-tv/v4l-utils/v4l-utils-1.16.6-r314.ebuild b/media-tv/v4l-utils/v4l-utils-1.16.6-r314.ebuild
new file mode 100644
index 00000000..61b53693
--- /dev/null
+++ b/media-tv/v4l-utils/v4l-utils-1.16.6-r314.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit flag-o-matic udev xdg-utils
+
+DESCRIPTION="Separate utilities ebuild from upstream v4l-utils package"
+HOMEPAGE="https://git.linuxtv.org/v4l-utils.git"
+SRC_URI="https://linuxtv.org/downloads/v4l-utils/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="opengl qt5 jpeg"
+
+RDEPEND=">=media-libs/libv4l-${PV}[jpeg]
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		opengl? ( dev-qt/qtopengl:5[-gles2(-)] virtual/opengl )
+		media-libs/alsa-lib
+	)
+	virtual/libudev
+	>=virtual/jpeg-0-r2:0=
+	virtual/libelf:=
+	!media-tv/v4l2-ctl
+	!<media-tv/ivtv-utils-1.4.0-r2"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}/sdlcam-only-build-if-using-jpeg.patch" )
+
+src_configure() {
+	if use qt5; then
+		append-cxxflags -std=c++11
+		local qt5_paths=( \
+			MOC="$(pkg-config --variable=host_bins Qt5Core)/moc" \
+			UIC="$(pkg-config --variable=host_bins Qt5Core)/uic" \
+			RCC="$(pkg-config --variable=host_bins Qt5Core)/rcc" \
+		)
+		if use !opengl; then
+			sed -e 's/Qt5OpenGL/DiSaBlEd/g' -i configure || die
+		fi
+	fi
+	# Hard disable the flags that apply only to the libs.
+	econf \
+		--disable-static \
+		$(use_enable qt5 qv4l2) \
+		$(use_enable qt5 qvidcap) \
+		--with-udevdir="$(get_udevdir)" \
+		$(use_with jpeg) \
+		"${qt5_paths[@]}"
+}
+
+src_install() {
+	emake -C utils DESTDIR="${D}" install
+	emake -C contrib DESTDIR="${D}" install
+
+	dodoc README
+	newdoc utils/libv4l2util/TODO TODO.libv4l2util
+	newdoc utils/libmedia_dev/README README.libmedia_dev
+	newdoc utils/dvb/README README.dvb
+	newdoc utils/v4l2-compliance/fixme.txt fixme.txt.v4l2-compliance
+}
+
+pkg_postinst() { xdg_icon_cache_update; }
+pkg_postrm() { xdg_icon_cache_update; }
-- 
cgit v1.2.3