From e57e403d595a1b4239d58ffa01cfd04116e3d876 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 22 Oct 2017 10:34:22 +0100
Subject: lxqt-base/lxqt-meta : version bump

---
 lxqt-base/lxqt-panel/Manifest                 |  1 +
 lxqt-base/lxqt-panel/lxqt-panel-0.12.0.ebuild | 81 +++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)
 create mode 100644 lxqt-base/lxqt-panel/Manifest
 create mode 100644 lxqt-base/lxqt-panel/lxqt-panel-0.12.0.ebuild

(limited to 'lxqt-base/lxqt-panel')

diff --git a/lxqt-base/lxqt-panel/Manifest b/lxqt-base/lxqt-panel/Manifest
new file mode 100644
index 00000000..6e01ad36
--- /dev/null
+++ b/lxqt-base/lxqt-panel/Manifest
@@ -0,0 +1 @@
+DIST lxqt-panel-0.12.0.tar.xz 271840 SHA256 3d286ba65d7a51403bc01d3efbc01c65c88ee4cf6f062143ed00c104a7b15f11 SHA512 bf6307b5e2b1f8063a10c50c8cb187ee4bee8f57031228da256ab6e52ce6b2af4fc2e2cba304468e28000c19e8c907a3f45481dc3887ee6cfac0744c13a3eec2 WHIRLPOOL 46fb37c08fdbba38caefa18b9204de97df5c34f9ddac744813e7af8e8e4435eb291026577669198903f55c5d3ce718899e47592b628889ef6930b9ca17b2dee6
diff --git a/lxqt-base/lxqt-panel/lxqt-panel-0.12.0.ebuild b/lxqt-base/lxqt-panel/lxqt-panel-0.12.0.ebuild
new file mode 100644
index 00000000..9acd0cdd
--- /dev/null
+++ b/lxqt-base/lxqt-panel/lxqt-panel-0.12.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt desktop panel and plugins"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://github.com/lxde/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="+alsa +clock colorpicker cpuload +desktopswitch dom +kbindicator +mainmenu
+	+mount networkmonitor pulseaudio +quicklaunch sensors +showdesktop
+	statusnotifier sysstat +taskbar +tray +volume worldclock"
+REQUIRED_USE="volume? ( || ( alsa pulseaudio ) )"
+
+CDEPEND="
+	dev-libs/glib:2
+	>=dev-libs/libqtxdg-3.1.0
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	kde-frameworks/kguiaddons:5
+	kde-frameworks/kwindowsystem:5[X]
+	>=lxde-base/menu-cache-0.3.3
+	~lxqt-base/liblxqt-${PV}
+	~lxqt-base/lxqt-globalkeys-${PV}
+	x11-libs/libX11
+	cpuload? ( sys-libs/libstatgrab )
+	kbindicator? ( x11-libs/libxkbcommon )
+	mount? ( kde-frameworks/solid:5 )
+	networkmonitor? ( sys-libs/libstatgrab )
+	sensors? ( sys-apps/lm_sensors )
+	statusnotifier? ( dev-libs/libdbusmenu-qt[qt5(+)] )
+	sysstat? ( =lxqt-base/libsysstat-0.4* )
+	tray? ( x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXrender )
+	volume? ( alsa? ( media-libs/alsa-lib )
+		pulseaudio? ( media-sound/pulseaudio ) )"
+DEPEND="${CDEPEND}
+	dev-qt/linguist-tools:5"
+RDEPEND="${CDEPEND}
+	dev-qt/qtsvg:5
+	>=lxde-base/lxmenu-data-0.1.2"
+
+src_configure() {
+	local mycmakeargs i y
+	mycmakeargs=( -DPULL_TRANSLATIONS=OFF )
+	for i in clock colorpicker cpuload desktopswitch dom kbindicator mainmenu mount \
+		networkmonitor quicklaunch sensors showdesktop statusnotifier \
+		sysstat taskbar tray volume worldclock; do
+		#Switch to ^^ when we switch to EAPI=6.
+		#y=${i^^}
+		y=$(tr '[:lower:]' '[:upper:]' <<< "${i}")
+		mycmakeargs+=( $(cmake-utils_use ${i} ${y}_PLUGIN) )
+	done
+
+	if use volume; then
+		mycmakeargs+=( $(cmake-utils_use alsa VOLUME_USE_ALSA)
+			$(cmake-utils_use pulseaudio VOLUME_USE_PULSEAUDIO) )
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_install(){
+	cmake-utils_src_install
+	doman panel/man/*.1
+}
-- 
cgit v1.2.3