From 9cc02d27716570f90b43e6af46337132823deae7 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 25 Oct 2023 23:14:02 +0100
Subject: kde-plasma/kinfocenter : version bump

---
 .../kinfocenter/kinfocenter-5.27.9-r5.ebuild       | 80 ++++++++++++++++++++++
 1 file changed, 80 insertions(+)
 create mode 100644 kde-plasma/kinfocenter/kinfocenter-5.27.9-r5.ebuild

(limited to 'kde-plasma/kinfocenter/kinfocenter-5.27.9-r5.ebuild')

diff --git a/kde-plasma/kinfocenter/kinfocenter-5.27.9-r5.ebuild b/kde-plasma/kinfocenter/kinfocenter-5.27.9-r5.ebuild
new file mode 100644
index 00000000..3bc990a7
--- /dev/null
+++ b/kde-plasma/kinfocenter/kinfocenter-5.27.9-r5.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.106.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.9
+inherit ecm plasma.kde.org optfeature
+
+DESCRIPTION="Utility providing information about the computer hardware"
+HOMEPAGE="https://userbase.kde.org/KInfoCenter"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="gles2-only usb"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5[gles2-only=]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	gles2-only? ( media-libs/mesa[gles2] )
+	usb? ( virtual/libusb:1 )
+"
+RDEPEND="${DEPEND}
+	dev-qt/qdbus:*
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	>=kde-plasma/systemsettings-${PVCUT}:5
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:5"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package usb USB1)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# TODO: Make this fully obsolete by /etc/os-release
+	insinto /etc/xdg
+	doins "${FILESDIR}"/kcm-about-distrorc
+
+	insinto /usr/share/${PN}
+	doins "${FILESDIR}"/glogo-small.png
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "NFS information module" net-fs/nfs-utils
+		optfeature "Samba status information module" net-fs/samba
+		optfeature "Vulkan graphics API information module" dev-util/vulkan-tools
+		optfeature "advanced CPU information module" sys-apps/util-linux
+	fi
+	optfeature "Wayland information module" app-misc/wayland-utils
+	optfeature "Firmware security module" "app-text/aha sys-apps/fwupd"
+	optfeature "OpenGL information module" x11-apps/mesa-progs
+	optfeature "PCI devices information module" sys-apps/pciutils
+	optfeature "X Server information module" x11-apps/xdpyinfo
+	ecm_pkg_postinst
+}
-- 
cgit v1.2.3