From e237be2025e6eb302f4267576a245b7c65576ebc Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 16 Apr 2018 18:13:36 +0100
Subject: dev-qt : bump to 5.9.5

---
 dev-qt/qtsql/qtsql-5.9.5-r1000.ebuild | 53 +++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-qt/qtsql/qtsql-5.9.5-r1000.ebuild

(limited to 'dev-qt/qtsql/qtsql-5.9.5-r1000.ebuild')

diff --git a/dev-qt/qtsql/qtsql-5.9.5-r1000.ebuild b/dev-qt/qtsql/qtsql-5.9.5-r1000.ebuild
new file mode 100644
index 00000000..e976c6df
--- /dev/null
+++ b/dev-qt/qtsql/qtsql-5.9.5-r1000.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+inherit qt5-build-r10000
+
+DESCRIPTION="SQL abstraction library for the Qt5 tooolkit"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="amd64"
+fi
+
+IUSE="freetds mysql oci8 odbc postgres +sqlite"
+
+REQUIRED_USE="
+	|| ( freetds mysql oci8 odbc postgres sqlite )
+"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	freetds? ( dev-db/freetds )
+	mysql? ( virtual/libmysqlclient:= )
+	oci8? ( dev-db/oracle-instantclient-basic )
+	odbc? ( || ( dev-db/unixODBC dev-db/libiodbc ) )
+	postgres? ( dev-db/postgresql:* )
+	sqlite? ( >=dev-db/sqlite-3.8.10.2:3 )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/sql
+	src/plugins/sqldrivers
+)
+
+src_configure() {
+	local myconf=(
+		$(qt_use freetds  sql-tds    plugin)
+		$(qt_use mysql    sql-mysql  plugin)
+		$(qt_use oci8     sql-oci    plugin)
+		$(qt_use odbc     sql-odbc   plugin)
+		$(qt_use postgres sql-psql   plugin)
+		$(qt_use sqlite   sql-sqlite plugin)
+		$(usex sqlite -system-sqlite '')
+	)
+
+	use mysql && myconf+=("-I${EPREFIX}/usr/include/mysql" "-L${EPREFIX}/usr/$(get_libdir)/mysql")
+	use oci8 && myconf+=("-I${ORACLE_HOME}/include" "-L${ORACLE_HOME}/$(get_libdir)")
+	use odbc && myconf+=("-I${EPREFIX}/usr/include/iodbc")
+	use postgres && myconf+=("-I${EPREFIX}/usr/include/postgresql/pgsql")
+
+	qt5-build-r10000_src_configure
+}
-- 
cgit v1.2.3