From 8d9b256225be88b96262bd4f827b6ce1328951d2 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@rogentos.ro>
Date: Sat, 31 Jan 2015 11:59:56 +0200
Subject: support IOS 8.1.3 devices, tested with iPhone 6 and works magic

---
 .../libimobiledevice/libimobiledevice-1.2.0.ebuild | 66 ++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 app-pda/libimobiledevice/libimobiledevice-1.2.0.ebuild

(limited to 'app-pda/libimobiledevice/libimobiledevice-1.2.0.ebuild')

diff --git a/app-pda/libimobiledevice/libimobiledevice-1.2.0.ebuild b/app-pda/libimobiledevice/libimobiledevice-1.2.0.ebuild
new file mode 100644
index 00000000..317427a4
--- /dev/null
+++ b/app-pda/libimobiledevice/libimobiledevice-1.2.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-pda/libimobiledevice/libimobiledevice-1.1.6.ebuild,v 1.6 2014/11/27 13:18:42 pacho Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} )
+AUTOTOOLS_PRUNE_LIBTOOL_FILES=all
+inherit autotools-utils multilib python-r1
+
+DESCRIPTION="Support library to communicate with Apple iPhone/iPod Touch devices"
+HOMEPAGE="http://www.libimobiledevice.org/"
+SRC_URI="http://www.libimobiledevice.org/downloads/${P}.tar.bz2"
+
+# While COPYING* doesn't mention 'or any later version', all the headers do, hence use +
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0/4" # based on SONAME of libimobiledevice.so
+KEYWORDS="amd64 ~arm ~ppc ~ppc64 x86"
+IUSE="gnutls python static-libs"
+
+RDEPEND=">=app-pda/libplist-1.11:=[python?,${PYTHON_USEDEP}]
+	>=app-pda/libusbmuxd-1.0.9:=
+	gnutls? (
+		dev-libs/libgcrypt:0
+		>=dev-libs/libtasn1-1.1
+		>=net-libs/gnutls-2.2.0
+		)
+	!gnutls? ( dev-libs/openssl:0 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/cython-0.17[${PYTHON_USEDEP}]
+		)"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DOCS=( AUTHORS NEWS README )
+
+pkg_setup() {
+	# Prevent linking to the installed copy
+	if has_version "<${CATEGORY}/${P}"; then
+		rm -f "${EROOT}"/usr/$(get_libdir)/${PN}$(get_libname)
+	fi
+}
+
+src_configure() {
+	local myeconfargs=( $(use_enable static-libs static) )
+	use gnutls && myeconfargs+=( --disable-openssl )
+	use python || myeconfargs+=( --without-cython )
+
+	python_foreach_impl autotools-utils_src_configure
+}
+
+src_compile() {
+	python_foreach_impl autotools-utils_src_compile
+}
+
+src_install() {
+	python_foreach_impl autotools-utils_src_install
+	dohtml docs/html/*
+
+	if use python; then
+		insinto /usr/include/${PN}/cython
+		doins cython/imobiledevice.pxd
+	fi
+}
-- 
cgit v1.2.3