From 7623b8b96d81e5a06582627a3c16184aa9a407dd Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 4 Dec 2017 16:10:22 +0000
Subject: lower revisions

---
 app-crypt/libsecret/libsecret-0.18.5-r1.ebuild | 61 ++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 app-crypt/libsecret/libsecret-0.18.5-r1.ebuild

(limited to 'app-crypt/libsecret/libsecret-0.18.5-r1.ebuild')

diff --git a/app-crypt/libsecret/libsecret-0.18.5-r1.ebuild b/app-crypt/libsecret/libsecret-0.18.5-r1.ebuild
new file mode 100644
index 00000000..9466fb08
--- /dev/null
+++ b/app-crypt/libsecret/libsecret-0.18.5-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+GCONF_DEBUG="yes"
+PYTHON_COMPAT=( python2_7 )
+VALA_USE_DEPEND=vapigen
+
+inherit gnome2 python-any-r1 vala virtualx
+
+DESCRIPTION="GObject library for accessing the freedesktop.org Secret Service API"
+HOMEPAGE="https://wiki.gnome.org/Projects/Libsecret"
+
+LICENSE="LGPL-2.1+ Apache-2.0" # Apache-2.0 license is used for tests only
+SLOT="0"
+
+IUSE="+crypt +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="alpha amd64 arm ~arm64 ia64 ~mips ppc ppc64 sparc x86 ~amd64-fbsd"
+
+RDEPEND="
+	>=dev-libs/glib-2.38:2
+	crypt? ( >=dev-libs/libgcrypt-1.2.2:0= )
+	introspection? ( >=dev-libs/gobject-introspection-1.29:= )"
+DEPEND="${RDEPEND}
+	dev-libs/libxslt
+	dev-util/gdbus-codegen
+	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/intltool-0.35.0
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? (
+		dev-python/mock
+		introspection? (
+			${PYTHON_DEPS}
+			>=dev-libs/gjs-1.32
+			dev-python/pygobject:3 )
+	)
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--enable-manpages \
+		--disable-strict \
+		--disable-coverage \
+		--disable-static \
+		$(use_enable crypt gcrypt) \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}
+
+src_test() {
+	Xemake check
+}
-- 
cgit v1.2.3