From de90a3a66f5c3ec22c253d7ee3b6b6e1b5b0d158 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 22 Sep 2018 09:12:28 +0100
Subject: app-accessibility/onboard : initial ebuild

---
 app-accessibility/onboard/onboard-1.4.1.ebuild | 76 ++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 app-accessibility/onboard/onboard-1.4.1.ebuild

(limited to 'app-accessibility/onboard/onboard-1.4.1.ebuild')

diff --git a/app-accessibility/onboard/onboard-1.4.1.ebuild b/app-accessibility/onboard/onboard-1.4.1.ebuild
new file mode 100644
index 00000000..d86de7d6
--- /dev/null
+++ b/app-accessibility/onboard/onboard-1.4.1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit distutils-r1 gnome2-utils versionator
+
+DESCRIPTION="Onscreen keyboard for everybody who can't use a hardware keyboard"
+HOMEPAGE="https://launchpad.net/onboard"
+SRC_URI="https://launchpad.net/${PN}/$(get_version_component_range 1-2)/${PV}/+download/${P}.tar.gz"
+
+# po/* are licensed under BSD 3-clause
+LICENSE="GPL-3+ BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+COMMON_DEPEND="app-text/hunspell:=
+	dev-libs/dbus-glib
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-python/python-distutils-extra[${PYTHON_USEDEP}]
+	gnome-base/dconf
+	gnome-base/librsvg
+	media-libs/libcanberra
+	sys-apps/dbus
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3[introspection]
+	x11-libs/libX11
+	x11-libs/libXi
+	x11-libs/libXtst
+	x11-libs/libwnck:3
+	x11-libs/pango"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool"
+RDEPEND="${COMMON_DEPEND}
+	app-accessibility/at-spi2-core
+	app-text/iso-codes
+	gnome-extra/mousetweaks
+	x11-libs/libxkbfile"
+
+RESTRICT="mirror"
+
+# These are using a functionality of distutils-r1.eclass
+DOCS=( AUTHORS CHANGELOG HACKING NEWS README onboard-defaults.conf.example
+	onboard-default-settings.gschema.override.example )
+PATCHES=( "${FILESDIR}/${P}-remove-duplicated-docs.patch" )
+
+src_prepare() {
+	distutils-r1_src_prepare
+	eapply_user
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	# Delete duplicated docs installed by original dustutils
+	rm "${D}"/usr/share/doc/onboard/*
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3