blob: e6e6474a2e57961e2b20553266950f7f4ef418bb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
|
# Copyright 2011-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
PYTHON_REQ_USE="xml(+)"
inherit linux-info python-any-r1
if [[ ${PV} == 9999 ]]; then
EGIT_REPO_URI="https://gitlab.com/openconnect/openconnect.git"
inherit git-r3 autotools
else
inherit verify-sig
SRC_URI="https://www.infradead.org/openconnect/download/${P}.tar.gz
verify-sig? ( https://www.infradead.org/openconnect/download/${P}.tar.gz.asc )"
KEYWORDS="amd64 arm arm64 ~loong ppc64 ~riscv x86"
fi
DESCRIPTION="Free client for Cisco AnyConnect SSL VPN software"
HOMEPAGE="https://www.infradead.org/openconnect/"
LICENSE="LGPL-2.1 GPL-2"
SLOT="0/5"
IUSE="doc +gnutls gssapi libproxy lz4 nls pskc selinux smartcard stoken test"
RESTRICT="!test? ( test )"
COMMON_DEPEND="
dev-libs/json-parser:0=
dev-libs/libxml2
sys-libs/zlib
app-crypt/p11-kit
!gnutls? (
>=dev-libs/openssl-1.0.1h:0=
dev-libs/libp11
)
gnutls? (
app-crypt/trousers
app-misc/ca-certificates
dev-libs/nettle
>=net-libs/gnutls-3.6.13:0=
dev-libs/libtasn1:0=
app-crypt/tpm2-tss:=
)
gssapi? ( virtual/krb5 )
libproxy? ( net-libs/libproxy )
lz4? ( app-arch/lz4:= )
nls? ( virtual/libintl )
pskc? ( sys-auth/oath-toolkit[pskc(+)] )
smartcard? ( sys-apps/pcsc-lite:0= )
stoken? ( app-crypt/stoken )
"
DEPEND="${COMMON_DEPEND}
test? (
net-libs/socket_wrapper
sys-libs/uid_wrapper
!gnutls? ( dev-libs/openssl:0[weak-ssl-ciphers(-)] )
)
"
RDEPEND="${COMMON_DEPEND}
sys-apps/iproute2
>=net-vpn/vpnc-scripts-20210402-r1
selinux? ( sec-policy/selinux-vpn )
"
BDEPEND="
virtual/pkgconfig
doc? ( ${PYTHON_DEPS} sys-apps/groff )
nls? ( sys-devel/gettext )
test? ( net-vpn/ocserv )
"
if [[ ${PV} != 9999 ]]; then
BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-dwmw2 )"
VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/openpgp-keys/dwmw2@kernel.org.key"
fi
CONFIG_CHECK="~TUN"
pkg_pretend() {
check_extra_config
}
pkg_setup() {
:
}
src_unpack() {
if [[ ${PV} == 9999 ]]; then
git-r3_src_unpack
else
if use verify-sig; then
verify-sig_verify_detached "${DISTDIR}/${P}".tar.gz{,.asc}
fi
unpack "${P}.tar.gz"
fi
}
src_prepare() {
default
if [[ ${PV} == 9999 ]]; then
eautoreconf
fi
}
src_configure() {
if use doc; then
python_setup
else
export ac_cv_path_PYTHON=
fi
# Used by tests if userpriv is disabled
addwrite /run/netns
local myconf=(
--disable-dsa-tests
$(use_enable nls)
--disable-static
$(use_with !gnutls openssl)
$(use_with gnutls)
$(use_with libproxy)
$(use_with lz4)
$(use_with gssapi)
$(use_with pskc libpskc)
$(use_with smartcard libpcsclite)
$(use_with stoken)
--with-vpnc-script="${EPREFIX}/etc/vpnc/vpnc-script"
--without-builtin-json
--without-java
)
econf "${myconf[@]}"
}
src_test() {
local charset
for charset in UTF-8 ISO-8859-2; do
if [[ $(LC_ALL=cs_CZ.${charset} locale charmap 2>/dev/null) != ${charset} ]]; then
# If we don't have valid cs_CZ locale data, auth-nonascii will fail.
# Force a test skip by exiting with status 77.
sed -i -e '2i exit 77' tests/auth-nonascii || die
break
fi
done
addwrite /proc
default
}
src_install() {
default
find "${ED}" -name '*.la' -delete || die
dodoc "${FILESDIR}"/README.OpenRC
newconfd "${FILESDIR}"/openconnect.confd openconnect
newinitd "${FILESDIR}"/openconnect.initd openconnect
insinto /etc/logrotate.d
newins "${FILESDIR}"/openconnect.logrotate openconnect
keepdir /var/log/openconnect
}
|