From 21435953e16cda318a82334ddbadb3b5c36d9ea7 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 15 Jan 2020 15:51:32 +0000
Subject: gentoo resync : 15.01.2020

---
 xfce-extra/tumbler/tumbler-0.2.8.ebuild | 57 +++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 xfce-extra/tumbler/tumbler-0.2.8.ebuild

(limited to 'xfce-extra/tumbler/tumbler-0.2.8.ebuild')

diff --git a/xfce-extra/tumbler/tumbler-0.2.8.ebuild b/xfce-extra/tumbler/tumbler-0.2.8.ebuild
new file mode 100644
index 000000000000..c9883f6524b0
--- /dev/null
+++ b/xfce-extra/tumbler/tumbler-0.2.8.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="A thumbnail service for Thunar"
+HOMEPAGE="https://docs.xfce.org/xfce/thunar/start"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="curl ffmpeg gstreamer jpeg odf pdf raw"
+
+COMMON_DEPEND=">=dev-libs/glib-2.42:2
+	media-libs/freetype:2=
+	media-libs/libpng:0=
+	>=sys-apps/dbus-1.6
+	>=x11-libs/gdk-pixbuf-2.14:2
+	curl? ( >=net-misc/curl-7.25:= )
+	ffmpeg? ( >=media-video/ffmpegthumbnailer-2.0.8:= )
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		)
+	jpeg? ( virtual/jpeg:0= )
+	odf? ( >=gnome-extra/libgsf-1.14.20:= )
+	pdf? ( >=app-text/poppler-0.12.4[cairo] )
+	raw? ( >=media-libs/libopenraw-0.0.8:=[gtk] )"
+RDEPEND="${COMMON_DEPEND}
+	>=xfce-base/thunar-1.4
+	gstreamer? ( media-plugins/gst-plugins-meta:1.0 )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		$(use_enable curl cover-thumbnailer)
+		$(use_enable jpeg jpeg-thumbnailer)
+		$(use_enable ffmpeg ffmpeg-thumbnailer)
+		$(use_enable gstreamer gstreamer-thumbnailer)
+		$(use_enable odf odf-thumbnailer)
+		$(use_enable pdf poppler-thumbnailer)
+		$(use_enable raw raw-thumbnailer)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3