From da407288bb9fc771488c3fee13fc2f8561681e66 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 15 Dec 2022 21:34:37 +0000
Subject: gentoo auto-resync : 15:12:2022 - 21:34:37

---
 xfce-base/xfwm4/xfwm4-4.18.0.ebuild | 74 +++++++++++++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)
 create mode 100644 xfce-base/xfwm4/xfwm4-4.18.0.ebuild

(limited to 'xfce-base/xfwm4/xfwm4-4.18.0.ebuild')

diff --git a/xfce-base/xfwm4/xfwm4-4.18.0.ebuild b/xfce-base/xfwm4/xfwm4-4.18.0.ebuild
new file mode 100644
index 000000000000..350c367a5f0b
--- /dev/null
+++ b/xfce-base/xfwm4/xfwm4-4.18.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="Window manager for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfwm4/start
+	https://gitlab.xfce.org/xfce/xfwm4
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="opengl startup-notification +xcomposite +xpresent"
+
+DEPEND="
+	>=x11-libs/gtk+-3.24.0:3
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXi
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXres
+	x11-libs/pango
+	>=x11-libs/libwnck-3.14:3
+	>=xfce-base/libxfce4util-4.10:=
+	>=xfce-base/libxfce4ui-4.12:=
+	>=xfce-base/xfconf-4.13:=
+	opengl? ( media-libs/libepoxy:=[X(+)] )
+	startup-notification? ( x11-libs/startup-notification )
+	xcomposite? (
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXfixes
+	)
+	xpresent? ( x11-libs/libXpresent )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-libs/glib
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable opengl epoxy)
+		$(use_enable startup-notification)
+		$(use_enable xcomposite compositor)
+		$(use_enable xpresent)
+		--enable-randr
+		--enable-render
+		--enable-xi2
+		--enable-xsync
+	)
+
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
-- 
cgit v1.2.3