From 36ac65103bf5503e5bad1ecc7e8cb9e7643f6840 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 13 Sep 2019 17:49:31 +0100
Subject: Revert "gentoo resync : 13.09.2019"

This reverts commit a1392efe64137262023d92492396ca9156d22396.
---
 xfce-base/xfwm4/xfwm4-4.13.3.ebuild | 70 +++++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 xfce-base/xfwm4/xfwm4-4.13.3.ebuild

(limited to 'xfce-base/xfwm4/xfwm4-4.13.3.ebuild')

diff --git a/xfce-base/xfwm4/xfwm4-4.13.3.ebuild b/xfce-base/xfwm4/xfwm4-4.13.3.ebuild
new file mode 100644
index 000000000000..b4ae00f6bcec
--- /dev/null
+++ b/xfce-base/xfwm4/xfwm4-4.13.3.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils
+
+DESCRIPTION="Window manager for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="opengl startup-notification +xcomposite +xpresent"
+
+RDEPEND="dev-libs/dbus-glib:=
+	>=dev-libs/glib-2.20:=
+	>=x11-libs/gtk+-3.20:3=
+	x11-libs/libX11:=
+	x11-libs/libXext:=
+	x11-libs/libXinerama:=
+	x11-libs/libXrandr:=
+	x11-libs/libXrender:=
+	x11-libs/pango:=
+	>=x11-libs/libwnck-3.14:3=
+	>=xfce-base/libxfce4util-4.10:=
+	>=xfce-base/libxfce4ui-4.12:=
+	>=xfce-base/xfconf-4.13:=
+	opengl? ( media-libs/libepoxy:=[X(+)] )
+	startup-notification? ( x11-libs/startup-notification:= )
+	xpresent? ( x11-libs/libXpresent )
+	xcomposite? (
+		x11-libs/libXcomposite:=
+		x11-libs/libXdamage:=
+		x11-libs/libXfixes:=
+		)"
+# libICE/libSM: not really used anywhere but checked by configure
+#   https://bugzilla.xfce.org/show_bug.cgi?id=11914
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	x11-libs/libICE
+	x11-libs/libSM
+	xfce-base/exo
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog COMPOSITOR NEWS README TODO )
+
+src_configure() {
+	local myconf=(
+		$(use_enable opengl epoxy)
+		$(use_enable startup-notification)
+		--enable-xsync
+		--enable-render
+		--enable-randr
+		$(use_enable xpresent)
+		$(use_enable xcomposite compositor)
+	)
+
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
-- 
cgit v1.2.3