From da407288bb9fc771488c3fee13fc2f8561681e66 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 15 Dec 2022 21:34:37 +0000
Subject: gentoo auto-resync : 15:12:2022 - 21:34:37

---
 xfce-base/xfconf/xfconf-4.18.0.ebuild | 78 +++++++++++++++++++++++++++++++++++
 1 file changed, 78 insertions(+)
 create mode 100644 xfce-base/xfconf/xfconf-4.18.0.ebuild

(limited to 'xfce-base/xfconf/xfconf-4.18.0.ebuild')

diff --git a/xfce-base/xfconf/xfconf-4.18.0.ebuild b/xfce-base/xfconf/xfconf-4.18.0.ebuild
new file mode 100644
index 000000000000..cbc4b3f557d9
--- /dev/null
+++ b/xfce-base/xfconf/xfconf-4.18.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit bash-completion-r1 vala
+
+DESCRIPTION="A configuration management system for Xfce"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfconf/start
+	https://gitlab.xfce.org/xfce/xfconf/
+"
+
+LICENSE="GPL-2+"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
+IUSE="debug +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+DEPEND="
+	>=dev-libs/glib-2.66.0
+	sys-apps/dbus
+	>=xfce-base/libxfce4util-4.17.3:=
+	introspection? ( >=dev-libs/gobject-introspection-1.66:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable vala)
+		$(use_enable debug checks)
+		--with-bash-completion-dir="$(get_bashcompdir)"
+	)
+
+	use vala && vala_setup
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	local service_dir=${HOME}/.local/share/dbus-1/services
+	mkdir -p "${service_dir}" || die
+	cat > "${service_dir}/org.xfce.Xfconf.service" <<-EOF || die
+		[D-BUS Service]
+		Name=org.xfce.Xfconf
+		Exec=${S}/xfconfd/xfconfd
+	EOF
+
+	(
+		# start isolated dbus session bus
+		dbus_data=$(dbus-launch --sh-syntax) || exit
+		eval "${dbus_data}"
+
+		# -j>1 often hangs
+		# https://gitlab.xfce.org/xfce/xfconf/-/issues/13
+		nonfatal emake -j1 check
+		ret=${?}
+
+		kill "${DBUS_SESSION_BUS_PID}"
+		exit "${ret}"
+	) || die
+}
+
+src_install() {
+	default
+	find "${D}" -type f -name '*.la' -delete || die
+}
-- 
cgit v1.2.3