From 113cc6fe7a9adc2baf67f9ef7723db6ed2b24887 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 10 Jan 2023 23:43:04 +0000
Subject: gentoo auto-resync : 10:01:2023 - 23:43:04

---
 xfce-base/xfce4-panel/xfce4-panel-4.19.0.ebuild | 83 +++++++++++++++++++++++++
 1 file changed, 83 insertions(+)
 create mode 100644 xfce-base/xfce4-panel/xfce4-panel-4.19.0.ebuild

(limited to 'xfce-base/xfce4-panel/xfce4-panel-4.19.0.ebuild')

diff --git a/xfce-base/xfce4-panel/xfce4-panel-4.19.0.ebuild b/xfce-base/xfce4-panel/xfce4-panel-4.19.0.ebuild
new file mode 100644
index 000000000000..fff8efcd9fa6
--- /dev/null
+++ b/xfce-base/xfce4-panel/xfce4-panel-4.19.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit vala xdg-utils
+
+DESCRIPTION="Panel for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfce4-panel/start
+	https://gitlab.xfce.org/xfce/xfce4-panel/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="X +dbusmenu introspection vala wayland"
+REQUIRED_USE="vala? ( introspection )"
+
+DEPEND="
+	>=dev-libs/glib-2.72.0
+	>=x11-libs/cairo-1.16.0
+	>=x11-libs/gtk+-3.24.0:3[X?,introspection?,wayland?]
+	>=xfce-base/exo-0.11.2:=
+	>=xfce-base/garcon-4.17.0:=
+	>=xfce-base/libxfce4ui-4.17.1:=
+	>=xfce-base/libxfce4util-4.17.2:=[introspection?,vala?]
+	>=xfce-base/libxfce4windowing-4.19.1:=
+	>=xfce-base/xfconf-4.13:=
+	X? (
+		x11-libs/libX11
+		x11-libs/libwnck:3
+	)
+	dbusmenu? ( >=dev-libs/libdbusmenu-16.04.0[gtk3] )
+	introspection? ( >=dev-libs/gobject-introspection-1.66:= )
+	wayland? (
+		>=dev-libs/wayland-1.15
+		>=gui-libs/gtk-layer-shell-0.7.0
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	vala? ( $(vala_depend) )
+	dev-lang/perl
+	dev-util/gdbus-codegen
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable dbusmenu dbusmenu-gtk3)
+		$(use_enable vala)
+		$(use_enable X gtk-x11)
+		$(use_enable X libwnck)
+		$(use_enable wayland wayland-client)
+		$(use_enable wayland gtk-layer-shell)
+	)
+
+	use vala && vala_setup
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
-- 
cgit v1.2.3