From 5a165c60b9b8c4847067cb83b4be7da785d01f93 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 28 Sep 2019 08:17:07 +0100
Subject: gentoo resync : 28.09.2019

---
 .../adwaita-icon-theme-3.32.0.ebuild               | 58 ++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 x11-themes/adwaita-icon-theme/adwaita-icon-theme-3.32.0.ebuild

(limited to 'x11-themes/adwaita-icon-theme/adwaita-icon-theme-3.32.0.ebuild')

diff --git a/x11-themes/adwaita-icon-theme/adwaita-icon-theme-3.32.0.ebuild b/x11-themes/adwaita-icon-theme/adwaita-icon-theme-3.32.0.ebuild
new file mode 100644
index 000000000000..b7a2d6710fcd
--- /dev/null
+++ b/x11-themes/adwaita-icon-theme/adwaita-icon-theme-3.32.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit gnome2
+
+DESCRIPTION="GNOME default icon theme"
+HOMEPAGE="https://git.gnome.org/browse/adwaita-icon-theme/"
+
+SRC_URI="${SRC_URI}
+	branding? ( https://www.mail-archive.com/tango-artists@lists.freedesktop.org/msg00043/tango-gentoo-v1.1.tar.gz )
+"
+LICENSE="
+	|| ( LGPL-3 CC-BY-SA-3.0 )
+	branding? ( CC-BY-SA-4.0 )
+"
+SLOT="0"
+IUSE="branding"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
+
+# gtk+:3 is needed for build for the gtk-encode-symbolic-svg utility
+# librsvg is needed for gtk-encode-symbolic-svg to be able to read the source SVG via its pixbuf loader and at runtime for rendering scalable icons shipped by the theme
+COMMON_DEPEND="
+	>=x11-themes/hicolor-icon-theme-0.10
+	gnome-base/librsvg:2
+"
+RDEPEND="${COMMON_DEPEND}
+	!<x11-themes/gnome-themes-standard-3.14
+"
+DEPEND="${COMMON_DEPEND}
+	x11-libs/gtk+:3
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+# This ebuild does not install any binaries
+RESTRICT="binchecks strip"
+
+src_prepare() {
+	if use branding; then
+		for i in 16 22 24 32 48; do
+			cp "${WORKDIR}"/tango-gentoo-v1.1/${i}x${i}/gentoo.png \
+			"${S}"/Adwaita/${i}x${i}/places/start-here.png \
+			|| die "Copying gentoo logos failed"
+		done
+	fi
+
+	# Install cursors in the right place used in Gentoo
+	sed -e 's:^\(cursordir.*\)icons\(.*\):\1cursors/xorg-x11\2:' \
+		-i "${S}"/Makefile.am \
+		-i "${S}"/Makefile.in || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure GTK_UPDATE_ICON_CACHE=$(type -P true)
+}
-- 
cgit v1.2.3