From 4551b41523452c0d743a71cca34e4dca2ca7538c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 4 Jan 2023 12:06:28 +0000
Subject: gentoo auto-resync : 04:01:2023 - 12:06:28

---
 x11-misc/xdialog/xdialog-2.3.1-r1.ebuild | 61 ++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 x11-misc/xdialog/xdialog-2.3.1-r1.ebuild

(limited to 'x11-misc/xdialog/xdialog-2.3.1-r1.ebuild')

diff --git a/x11-misc/xdialog/xdialog-2.3.1-r1.ebuild b/x11-misc/xdialog/xdialog-2.3.1-r1.ebuild
new file mode 100644
index 000000000000..b04058431d62
--- /dev/null
+++ b/x11-misc/xdialog/xdialog-2.3.1-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Drop-in replacement for cdialog using GTK"
+HOMEPAGE="http://xdialog.free.fr/"
+SRC_URI="http://${PN}.free.fr/Xdialog-${PV}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~hppa ppc x86"
+IUSE="doc examples nls"
+
+RDEPEND="
+	dev-libs/glib:2
+	>=x11-libs/gtk+-2.2:2
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+S="${WORKDIR}/${P/x/X}"
+
+DOCS=( AUTHORS BUGS ChangeLog README )
+
+PATCHES=(
+	"${FILESDIR}"/${P}-no-strip.patch
+	"${FILESDIR}"/${P}-install.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i -e 's:configure.in:configure.ac:' configure.in || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		--with-gtk2
+}
+
+src_install() {
+	default
+
+	rm -r "${ED}"/usr/share/doc || die
+	use doc && local HTML_DOCS=( doc/. )
+	einstalldocs
+
+	if use examples; then
+		docinto examples
+		dodoc samples/*
+	fi
+}
-- 
cgit v1.2.3