From 5001a6c7b6da2956f5b17c695b1e0059dc7b8de5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 7 Jan 2018 18:44:07 +0000
Subject: gentoo resync : 07.01.2018

---
 x11-misc/tint2/tint2-16.1.ebuild | 60 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 x11-misc/tint2/tint2-16.1.ebuild

(limited to 'x11-misc/tint2/tint2-16.1.ebuild')

diff --git a/x11-misc/tint2/tint2-16.1.ebuild b/x11-misc/tint2/tint2-16.1.ebuild
new file mode 100644
index 000000000000..f7cbd25ca6f4
--- /dev/null
+++ b/x11-misc/tint2/tint2-16.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils gnome2-utils vcs-snapshot
+
+DESCRIPTION="tint2 is a lightweight panel/taskbar for Linux."
+HOMEPAGE="https://gitlab.com/o9000/tint2"
+SRC_URI="https://gitlab.com/o9000/${PN}/repository/archive.tar.gz?ref=v${PV} -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="battery svg startup-notification tint2conf"
+
+DEPEND="
+	dev-libs/glib:2
+	svg? ( gnome-base/librsvg:2 )
+	>=media-libs/imlib2-1.4.2[X,png]
+	x11-libs/cairo[X]
+	x11-libs/pango
+	tint2conf? ( x11-libs/gtk+:2 )
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXinerama
+	>=x11-libs/libXrandr-1.3
+	x11-libs/libXrender
+	startup-notification? ( x11-libs/startup-notification )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+		-DENABLE_BATTERY="$(usex battery)"
+		-DENABLE_TINT2CONF="$(usex tint2conf)"
+		-DENABLE_SN="$(usex startup-notification)"
+		-DENABLE_RSVG="$(usex svg)"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
-- 
cgit v1.2.3