From 26062b5638b6d2a6eedba7797ed6dde6f3d1f01c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 23 Aug 2022 20:45:29 +0100
Subject: gentoo auto-resync : 23:08:2022 - 20:45:29

---
 x11-misc/rofi/rofi-1.7.5.ebuild | 73 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 x11-misc/rofi/rofi-1.7.5.ebuild

(limited to 'x11-misc/rofi/rofi-1.7.5.ebuild')

diff --git a/x11-misc/rofi/rofi-1.7.5.ebuild b/x11-misc/rofi/rofi-1.7.5.ebuild
new file mode 100644
index 000000000000..4fe9af652772
--- /dev/null
+++ b/x11-misc/rofi/rofi-1.7.5.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs xdg-utils
+
+DESCRIPTION="A window switcher, run dialog and dmenu replacement"
+HOMEPAGE="https://github.com/davatorium/rofi"
+SRC_URI="https://github.com/davatorium/rofi/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+drun test +windowmode"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+"
+RDEPEND="
+	dev-libs/glib:2
+	x11-libs/cairo[X,xcb(+)]
+	x11-libs/gdk-pixbuf:2
+	x11-libs/libxcb:=
+	x11-libs/libxkbcommon[X]
+	x11-libs/pango[X]
+	x11-libs/startup-notification
+	x11-libs/xcb-util
+	x11-libs/xcb-util-cursor
+	x11-libs/xcb-util-wm
+	x11-misc/xkeyboard-config
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+	test? ( >=dev-libs/check-0.11 )
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC
+
+	local myeconfargs=(
+		$(use_enable drun)
+		$(use_enable test check)
+		$(use_enable windowmode)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+pkg_postinst() {
+	for v in ${REPLACING_VERSIONS}; do
+		if ver_test "${v}" -lt 1.7.0; then
+			elog "Rofi 1.7.0 removed the (deprecated) xresources based configuration setup."
+			elog "If you are still using old configuration setup, please convert it to new format manually."
+			elog "The new format configuration can be generated by 'rofi -dump-config > ~/.config/rofi/config.rasi'."
+			elog "For more information, please see https://github.com/davatorium/rofi/releases/tag/1.7.0"
+		fi
+	done
+
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
-- 
cgit v1.2.3