From 7218e1b46bceac05841e90472501742d905fb3fc Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 12 Mar 2021 21:55:15 +0000
Subject: gentoo resync : 12.03.2021

---
 x11-misc/picom/picom-8.2-r2.ebuild | 62 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 x11-misc/picom/picom-8.2-r2.ebuild

(limited to 'x11-misc/picom/picom-8.2-r2.ebuild')

diff --git a/x11-misc/picom/picom-8.2-r2.ebuild b/x11-misc/picom/picom-8.2-r2.ebuild
new file mode 100644
index 000000000000..705966851270
--- /dev/null
+++ b/x11-misc/picom/picom-8.2-r2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+inherit meson python-any-r1 virtualx xdg
+
+DESCRIPTION="A lightweight compositor for X11 (previously a compton fork)"
+HOMEPAGE="https://github.com/yshui/picom"
+SRC_URI="https://github.com/yshui/picom/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MPL-2.0 MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="+config-file dbus +doc +drm opengl pcre test"
+
+REQUIRED_USE="test? ( dbus )" # avoid "DBus support not compiled in!"
+RESTRICT="test" # but tests require dbus_next
+
+RDEPEND="
+	dev-libs/libev
+	dev-libs/uthash
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXext
+	x11-libs/pixman
+	x11-libs/xcb-util-image
+	x11-libs/xcb-util-renderutil
+	config-file? (
+		dev-libs/libconfig:=
+		dev-libs/libxdg-basedir
+	)
+	dbus? ( sys-apps/dbus )
+	drm? ( x11-libs/libdrm )
+	opengl? ( virtual/opengl )
+	pcre? ( dev-libs/libpcre )
+	!x11-misc/compton"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+BDEPEND="virtual/pkgconfig
+	doc? ( app-text/asciidoc )
+	test? ( $(python_gen_any_dep 'dev-python/xcffib[${PYTHON_USEDEP}]') )
+"
+
+DOCS=( README.md picom.sample.conf )
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use config-file config_file)
+		$(meson_use dbus)
+		$(meson_use doc with_docs)
+		$(meson_use opengl)
+		$(meson_use pcre regex)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx "${S}/tests/run_tests.sh" "${BUILD_DIR}/src/${PN}"
+}
-- 
cgit v1.2.3