From 9ee6d97c2883d42f204a533a8bc1f4562df778fb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 16 Sep 2020 09:32:48 +0100
Subject: gentoo resync : 16.09.2020

---
 x11-misc/hsetroot/hsetroot-1.0.5.ebuild | 56 +++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 x11-misc/hsetroot/hsetroot-1.0.5.ebuild

(limited to 'x11-misc/hsetroot/hsetroot-1.0.5.ebuild')

diff --git a/x11-misc/hsetroot/hsetroot-1.0.5.ebuild b/x11-misc/hsetroot/hsetroot-1.0.5.ebuild
new file mode 100644
index 000000000000..cde4912ca941
--- /dev/null
+++ b/x11-misc/hsetroot/hsetroot-1.0.5.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs
+
+DESCRIPTION="Tool which allows you to compose wallpapers ('root pixmaps') for X"
+HOMEPAGE="https://github.com/himdel/hsetroot/"
+SRC_URI="
+	https://github.com/himdel/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+RDEPEND="
+	>=media-libs/imlib2-1.0.6.2003[X]
+	x11-libs/libX11
+	x11-libs/libXinerama
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+DOCS="AUTHORS ChangeLog NEWS README"
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.0.5-XOpenDisplay.patch
+)
+
+src_compile() {
+	# Avoid the Makefile that replaced autotools
+	tc-export CC PKG_CONFIG
+	local tgt hsr_comp_args
+	for tgt in ${PN} hsr-outputs; do
+		hsr_comp_args=(
+			${CFLAGS}
+			$("${PKG_CONFIG}" --cflags x11 imlib2 xinerama)
+			${LDFLAGS}
+			${tgt}.c
+			$("${PKG_CONFIG}" --libs x11 imlib2 xinerama)
+			-o ${tgt}
+		)
+		echo ${hsr_comp_args[@]}
+		"${CC}" ${hsr_comp_args[@]} || die
+	done
+
+}
+
+src_install() {
+	dobin ${PN} hsr-outputs
+	dodoc README.md
+}
-- 
cgit v1.2.3