From 9ee6d97c2883d42f204a533a8bc1f4562df778fb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 16 Sep 2020 09:32:48 +0100
Subject: gentoo resync : 16.09.2020

---
 x11-misc/dmenu/dmenu-5.0.ebuild | 61 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 x11-misc/dmenu/dmenu-5.0.ebuild

(limited to 'x11-misc/dmenu/dmenu-5.0.ebuild')

diff --git a/x11-misc/dmenu/dmenu-5.0.ebuild b/x11-misc/dmenu/dmenu-5.0.ebuild
new file mode 100644
index 000000000000..49610645344e
--- /dev/null
+++ b/x11-misc/dmenu/dmenu-5.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit savedconfig toolchain-funcs
+
+DESCRIPTION="a generic, highly customizable, and efficient menu for the X Window System"
+HOMEPAGE="https://tools.suckless.org/dmenu/"
+SRC_URI="https://dl.suckless.org/tools/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+IUSE="xinerama"
+
+RDEPEND="
+	media-libs/fontconfig
+	x11-libs/libX11
+	x11-libs/libXft
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	x11-base/xorg-proto
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.9-gentoo.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's|^	@|	|g' \
+		-e '/^	echo/d' \
+		Makefile || die
+
+	restore_config config.h
+}
+
+src_compile() {
+	emake CC=$(tc-getCC) \
+		"FREETYPEINC=$( $(tc-getPKG_CONFIG) --cflags x11 fontconfig xft 2>/dev/null )" \
+		"FREETYPELIBS=$( $(tc-getPKG_CONFIG) --libs x11 fontconfig xft 2>/dev/null )" \
+		"X11INC=$( $(tc-getPKG_CONFIG) --cflags x11 2>/dev/null )" \
+		"X11LIB=$( $(tc-getPKG_CONFIG) --libs x11 2>/dev/null )" \
+		"XINERAMAFLAGS=$(
+			usex xinerama "-DXINERAMA $(
+				$(tc-getPKG_CONFIG) --cflags xinerama 2>/dev/null
+			)" ''
+		)" \
+		"XINERAMALIBS=$(
+			usex xinerama "$( $(tc-getPKG_CONFIG) --libs xinerama 2>/dev/null)" ''
+		)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+
+	save_config config.h
+}
-- 
cgit v1.2.3