From 56330f065f2b903d9e1b2dffc63719fef5897a45 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 6 Jan 2024 12:54:39 +0000
Subject: gentoo auto-resync : 06:01:2024 - 12:54:38

---
 x11-misc/albert/albert-0.22.17.ebuild | 72 +++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 x11-misc/albert/albert-0.22.17.ebuild

(limited to 'x11-misc/albert/albert-0.22.17.ebuild')

diff --git a/x11-misc/albert/albert-0.22.17.ebuild b/x11-misc/albert/albert-0.22.17.ebuild
new file mode 100644
index 000000000000..188be790f708
--- /dev/null
+++ b/x11-misc/albert/albert-0.22.17.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10,11,12} )
+
+inherit cmake python-single-r1 xdg
+
+DESCRIPTION="A fast and flexible keyboard launcher"
+HOMEPAGE="https://albertlauncher.github.io/"
+
+PLUGINS_HASH="02755dfa0ef3f17c28a813355eb7db60642ee797"
+PYTHON_EXTENSIONS_COMMIT="2067bbb3d8fa5cfa5df2be9cada29a7e6715f07a"
+
+SRC_URI="
+	https://github.com/albertlauncher/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/albertlauncher/plugins/archive/${PLUGINS_HASH}.tar.gz -> ${PN}-plugins-${PLUGINS_HASH}.tar.gz
+	python-extensions? (
+		https://github.com/albertlauncher/python/archive/${PYTHON_EXTENSIONS_COMMIT}.tar.gz ->
+			${PN}-python-extensions-${PYTHON_EXTENSIONS_COMMIT}.tar.gz
+	)
+"
+
+LICENSE="Albert-1.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="debug +python +python-extensions"
+RESTRICT="mirror bindist"
+
+REQUIRED_USE="
+	python-extensions? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+RDEPEND="
+	app-arch/libarchive:=
+	dev-libs/qhotkey[qt6]
+	dev-qt/qt5compat:6[qml]
+	dev-qt/qtbase:6[concurrent,dbus,gui,network,sql,sqlite,widgets]
+	dev-qt/qtdeclarative:6
+	dev-qt/qtscxml:6[qml]
+	dev-qt/qtsvg:6
+	sci-libs/libqalculate:=
+	python? (
+		$(python_gen_cond_dep 'dev-python/urllib3[${PYTHON_USEDEP}]')
+		${PYTHON_DEPS}
+	)
+"
+DEPEND="${RDEPEND}
+	python? ( $(python_gen_cond_dep 'dev-python/pybind11[${PYTHON_USEDEP}]') )
+	x11-base/xorg-proto"
+
+PATCHES=("${FILESDIR}/${PN}-0.22.4-use-system-qhotkey-libraries-and-headers.patch")
+
+src_prepare() {
+	mv "${WORKDIR}"/plugins-${PLUGINS_HASH}/* "${S}"/plugins || die
+	if use python-extensions; then
+		mv "${WORKDIR}"/python-${PYTHON_EXTENSIONS_COMMIT}/* "${S}"/plugins/python/plugins || die
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DEBUG=$(usex debug)
+		-DBUILD_PYTHON=$(usex python)
+	)
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3