From 7c59acba5699c9c58090a7a738669669a7307023 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 21 Aug 2021 23:14:26 +0100
Subject: gentoo resync : 21.08.2021

---
 x11-libs/pango/pango-1.48.9.ebuild | 75 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 75 insertions(+)
 create mode 100644 x11-libs/pango/pango-1.48.9.ebuild

(limited to 'x11-libs/pango/pango-1.48.9.ebuild')

diff --git a/x11-libs/pango/pango-1.48.9.ebuild b/x11-libs/pango/pango-1.48.9.ebuild
new file mode 100644
index 000000000000..31ec4a4021ca
--- /dev/null
+++ b/x11-libs/pango/pango-1.48.9.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic gnome2-utils meson-multilib toolchain-funcs xdg
+
+DESCRIPTION="Internationalized text layout and rendering library"
+HOMEPAGE="https://www.pango.org/ https://gitlab.gnome.org/GNOME/pango"
+SRC_URI="http://ftp.gnome.org/pub/GNOME/sources/pango/$(ver_cut 1-2)/${P}.tar.xz"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="debug +introspection sysprof X"
+
+RDEPEND="
+	>=dev-libs/glib-2.62.2:2[${MULTILIB_USEDEP}]
+	>=dev-libs/fribidi-1.0.6[${MULTILIB_USEDEP}]
+	>=media-libs/harfbuzz-2.2.0:=[glib(+),introspection?,truetype(+),${MULTILIB_USEDEP}]
+	>=media-libs/fontconfig-2.12.92:1.0=[${MULTILIB_USEDEP}]
+	>=x11-libs/cairo-1.12.10:=[X?,${MULTILIB_USEDEP}]
+	>=media-libs/freetype-2.5.0.1:2=[harfbuzz,png,${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXft-2.3.1-r1[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrender-0.9.8[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	sysprof? ( >=dev-util/sysprof-capture-3.40.1:4[${MULTILIB_USEDEP}] )
+	X? ( x11-base/xorg-proto )
+"
+BDEPEND="
+	dev-util/glib-utils
+	sys-apps/help2man
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	xdg_src_prepare
+	gnome2_environment_reset
+}
+
+multilib_src_configure() {
+	if use debug; then
+		append-cflags -DPANGO_ENABLE_DEBUG
+	else
+		append-cflags -DG_DISABLE_CAST_CHECKS
+	fi
+
+	local emesonargs=(
+		# Never use gi-docgen subproject
+		--wrap-mode nofallback
+
+		-Dgtk_doc=false # we ship pregenerated docs
+		$(meson_native_use_feature introspection)
+		-Dinstall-tests=false
+		-Dfontconfig=enabled
+		$(meson_feature sysprof)
+		-Dlibthai=disabled
+		-Dcairo=enabled
+		$(meson_feature X xft)
+		-Dfreetype=enabled
+	)
+	meson_src_configure
+}
+
+multilib_src_install_all() {
+	insinto /usr/share/gtk-doc/html
+	# This will install PangoXft API docs regardless of USE=-X, but this is intentional
+	doins -r "${S}"/docs/Pango*
+}
-- 
cgit v1.2.3