From 2719f73b6813d11d13a9650cdd2ab8ec6e69385d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 9 Jul 2022 15:43:36 +0100
Subject: gentoo resync : 09.07.2022

---
 x11-libs/libva/libva-2.15.0.ebuild | 69 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 x11-libs/libva/libva-2.15.0.ebuild

(limited to 'x11-libs/libva/libva-2.15.0.ebuild')

diff --git a/x11-libs/libva/libva-2.15.0.ebuild b/x11-libs/libva/libva-2.15.0.ebuild
new file mode 100644
index 000000000000..f2032b33b3ca
--- /dev/null
+++ b/x11-libs/libva/libva-2.15.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson-multilib optfeature
+
+DESCRIPTION="Video Acceleration (VA) API for Linux"
+HOMEPAGE="https://01.org/linuxmedia/vaapi"
+
+if [[ ${PV} = *9999 ]] ; then
+	inherit git-r3
+	EGIT_BRANCH=master
+	EGIT_REPO_URI="https://github.com/intel/libva"
+else
+	SRC_URI="https://github.com/intel/libva/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1)"
+IUSE="+drm opengl wayland X"
+REQUIRED_USE="opengl? ( X )"
+
+RDEPEND="
+	>=x11-libs/libdrm-2.4.60[${MULTILIB_USEDEP}]
+	wayland? (
+		>=dev-libs/wayland-1.11[${MULTILIB_USEDEP}]
+	)
+	X? (
+		>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXfixes-5.0.1[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	wayland? ( dev-util/wayland-scanner )
+	virtual/pkgconfig
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/va/va_backend_glx.h
+	/usr/include/va/va_x11.h
+	/usr/include/va/va_dri2.h
+	/usr/include/va/va_dricommon.h
+	/usr/include/va/va_glx.h
+)
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddriverdir="${EPREFIX}/usr/$(get_libdir)/va/drivers"
+		-Ddisable_drm=false
+		-Dwith_x11=$(usex X)
+		-Dwith_glx=$(usex X)
+		-Dwith_wayland=$(usex wayland)
+		-Denable_docs=false
+		-Denable_va_messaging=true
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	optfeature_header
+	optfeature "NVIDIA GPU support" x11-libs/libva-vdpau-driver
+	optfeature "Older Intel GPU support" x11-libs/libva-intel-driver
+	optfeature "Newer Intel GPU support" x11-libs/libva-intel-media-driver
+}
-- 
cgit v1.2.3