From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 .../intel-hybrid-codec-driver-2.0.0.ebuild         | 53 ++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 x11-libs/intel-hybrid-codec-driver/intel-hybrid-codec-driver-2.0.0.ebuild

(limited to 'x11-libs/intel-hybrid-codec-driver/intel-hybrid-codec-driver-2.0.0.ebuild')

diff --git a/x11-libs/intel-hybrid-codec-driver/intel-hybrid-codec-driver-2.0.0.ebuild b/x11-libs/intel-hybrid-codec-driver/intel-hybrid-codec-driver-2.0.0.ebuild
new file mode 100644
index 000000000000..860feeb69f61
--- /dev/null
+++ b/x11-libs/intel-hybrid-codec-driver/intel-hybrid-codec-driver-2.0.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MULTILIB_COMPAT=( abi_x86_64 )
+EGIT_COMMIT="edead0c17e2818bc0fee0ea644f85ab81bbe6f7a"
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="Libva support for partially hardware accelerated encode and decode on Haswell and newer"
+HOMEPAGE="https://github.com/intel/intel-hybrid-driver"
+SRC_URI="https://github.com/intel/intel-hybrid-driver/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/intel-hybrid-driver-${EGIT_COMMIT}"
+
+KEYWORDS="~amd64 ~amd64-linux"
+LICENSE="MIT"
+SLOT="0"
+IUSE="wayland X"
+
+BDEPEND="virtual/pkgconfig"
+RDEPEND="
+	>=x11-libs/cmrt-1.0.6
+	>=x11-libs/libdrm-2.4.45
+	>=x11-libs/libva-1.0.16[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${P}-gcc10-fix.patch"
+	"${FILESDIR}/${P}-vadriverinit-fix.patch"
+	"${FILESDIR}/${P}-x11-fix.patch"
+	"${FILESDIR}/${P}-nullptr-fix.patch"
+	"${FILESDIR}/${P}-invalid-read-fix.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myconf=(
+		$(use_enable wayland)
+		$(use_enable X x11)
+	)
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
+}
+
+multilib_src_install() {
+	default
+	find "${D}" -name "*.la" -delete || die
+}
-- 
cgit v1.2.3