From 0fb71e0215ed52863e462cccef73c01aff44d43d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 18 Dec 2017 15:11:02 +0000
Subject: gentoo resync : 18.12.2017

---
 x11-libs/gtksourceview/gtksourceview-3.24.6.ebuild | 58 ++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 x11-libs/gtksourceview/gtksourceview-3.24.6.ebuild

(limited to 'x11-libs/gtksourceview/gtksourceview-3.24.6.ebuild')

diff --git a/x11-libs/gtksourceview/gtksourceview-3.24.6.ebuild b/x11-libs/gtksourceview/gtksourceview-3.24.6.ebuild
new file mode 100644
index 000000000000..1e25a7583c48
--- /dev/null
+++ b/x11-libs/gtksourceview/gtksourceview-3.24.6.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+VALA_MIN_API_VERSION="0.24"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala virtualx
+
+DESCRIPTION="A text widget implementing syntax highlighting and other features"
+HOMEPAGE="https://wiki.gnome.org/Projects/GtkSourceView"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="3.0/3"
+
+IUSE="glade +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+
+RDEPEND="
+	>=dev-libs/glib-2.48:2
+	>=dev-libs/libxml2-2.6:2
+	>=x11-libs/gtk+-3.20:3[introspection?]
+	glade? ( >=dev-util/glade-3.9:3.10 )
+	introspection? ( >=dev-libs/gobject-introspection-1.42:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.25
+	>=sys-devel/gettext-0.19.4
+	dev-util/itstool
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-deprecations \
+		$(use_enable glade glade-catalog) \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}
+
+src_test() {
+	virtx emake check
+}
+
+src_install() {
+	gnome2_src_install
+
+	insinto /usr/share/${PN}-3.0/language-specs
+	doins "${FILESDIR}"/2.0/gentoo.lang
+}
-- 
cgit v1.2.3