From b7ebc951da8800f711142f69d9d958bde67a112d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 28 Apr 2019 09:54:45 +0100
Subject: gentoo resync : 28.04.2019

---
 www-servers/gunicorn/gunicorn-19.9.0.ebuild | 49 +++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 www-servers/gunicorn/gunicorn-19.9.0.ebuild

(limited to 'www-servers/gunicorn/gunicorn-19.9.0.ebuild')

diff --git a/www-servers/gunicorn/gunicorn-19.9.0.ebuild b/www-servers/gunicorn/gunicorn-19.9.0.ebuild
new file mode 100644
index 000000000000..a3e43945651e
--- /dev/null
+++ b/www-servers/gunicorn/gunicorn-19.9.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="A WSGI HTTP Server for UNIX"
+HOMEPAGE="https://gunicorn.org https://pypi.org/project/gunicorn https://github.com/benoitc/gunicorn"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT PSF-2 doc? ( BSD )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-python/setproctitle[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		dev-python/unittest2[${PYTHON_USEDEP}]
+	)"
+
+DOCS="README.rst"
+
+python_prepare_all() {
+	sed -ie "s/..\/bin/\/usr\/bin\//" docs/Makefile || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test -v || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3