From e2db47eaae00ec33f8971db44b68645c5d3b9590 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 17 Aug 2021 11:36:49 +0100
Subject: gentoo resync : 17.08.2021

---
 www-client/epiphany/epiphany-40.3.ebuild | 86 ++++++++++++++++++++++++++++++++
 1 file changed, 86 insertions(+)
 create mode 100644 www-client/epiphany/epiphany-40.3.ebuild

(limited to 'www-client/epiphany/epiphany-40.3.ebuild')

diff --git a/www-client/epiphany/epiphany-40.3.ebuild b/www-client/epiphany/epiphany-40.3.ebuild
new file mode 100644
index 000000000000..6e19aa0daada
--- /dev/null
+++ b/www-client/epiphany/epiphany-40.3.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg virtualx
+
+DESCRIPTION="GNOME webbrowser based on Webkit"
+HOMEPAGE="https://wiki.gnome.org/Apps/Web"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+
+DEPEND="
+	>=dev-libs/glib-2.64.0:2
+	>=x11-libs/gtk+-3.24.0:3
+	>=dev-libs/nettle-3.4:=
+	>=net-libs/webkit-gtk-2.31.1:4=
+	>=x11-libs/cairo-1.2
+	>=app-crypt/gcr-3.5.5:=[gtk]
+	>=x11-libs/gdk-pixbuf-2.36.5:2
+	gnome-base/gsettings-desktop-schemas
+	>=app-text/iso-codes-0.35
+	>=dev-libs/json-glib-1.2.4
+	app-arch/libarchive:=
+	>=dev-libs/libdazzle-3.37.1
+	>=gui-libs/libhandy-1.1.0:1=
+	>=x11-libs/libnotify-0.5.1
+	>=app-crypt/libsecret-0.19
+	>=net-libs/libsoup-2.48.0:2.4
+	>=dev-libs/libxml2-2.6.12:2
+	>=dev-db/sqlite-3.22:3
+	dev-libs/gmp:0=
+"
+RDEPEND="${DEPEND}
+	x11-themes/adwaita-icon-theme
+"
+# appstream-glib needed for appdata.xml gettext translation
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Allow /var/tmp prefixed recursive delete (due to package manager setting TMPDIR)
+	"${FILESDIR}"/var-tmp-tests.patch
+)
+
+src_configure() {
+	local emesonargs=(
+		-Ddeveloper_mode=false
+		-Dlibportal=disabled
+		# maybe enable later if network-sandbox is off, but in 3.32.4 the network test
+		# is commented out upstream anyway
+		-Dnetwork_tests=disabled
+		-Dtech_preview=false
+		$(meson_feature test unit_tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+
+	if ! has_version net-libs/webkit-gtk[jpeg2k]; then
+		ewarn "Your net-libs/webkit-gtk is built without USE=jpeg2k."
+		ewarn "Various image galleries/managers may be broken."
+	fi
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3