From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 www-client/epiphany/epiphany-3.22.7.ebuild | 72 ++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 www-client/epiphany/epiphany-3.22.7.ebuild

(limited to 'www-client/epiphany/epiphany-3.22.7.ebuild')

diff --git a/www-client/epiphany/epiphany-3.22.7.ebuild b/www-client/epiphany/epiphany-3.22.7.ebuild
new file mode 100644
index 000000000000..a7701018ee37
--- /dev/null
+++ b/www-client/epiphany/epiphany-3.22.7.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit flag-o-matic eutils gnome2 virtualx
+
+DESCRIPTION="GNOME webbrowser based on Webkit"
+HOMEPAGE="https://wiki.gnome.org/Apps/Web"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="test"
+KEYWORDS="amd64 ~arm ~ppc ~ppc64 ~sparc x86"
+
+COMMON_DEPEND="
+	>=app-crypt/gcr-3.5.5:=[gtk]
+	>=app-crypt/libsecret-0.14
+	>=app-text/iso-codes-0.35
+	>=dev-libs/glib-2.44.0:2[dbus]
+	>=dev-libs/libxml2-2.6.12:2
+	>=dev-libs/libxslt-1.1.7
+	>=gnome-base/gsettings-desktop-schemas-0.0.1
+	>=net-dns/avahi-0.6.22[dbus]
+	>=net-libs/webkit-gtk-2.14.2:4=
+	>=net-libs/libsoup-2.48:2.4
+	>=x11-libs/gtk+-3.19.1:3
+	>=x11-libs/libnotify-0.5.1:=
+	gnome-base/gnome-desktop:3=
+
+	dev-db/sqlite:3
+	x11-libs/libX11
+"
+# epiphany-extensions support was removed in 3.7; let's not pretend it still works
+RDEPEND="${COMMON_DEPEND}
+	x11-themes/adwaita-icon-theme
+	!www-client/epiphany-extensions
+"
+# paxctl needed for bug #407085
+DEPEND="${COMMON_DEPEND}
+	app-text/yelp-tools
+	dev-libs/appstream-glib
+	>=dev-util/intltool-0.50
+	sys-apps/paxctl
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# https://bugzilla.gnome.org/show_bug.cgi?id=751591
+	"${FILESDIR}"/${PN}-3.16.0-unittest-1.patch
+
+	# https://bugzilla.gnome.org/show_bug.cgi?id=751593
+	"${FILESDIR}"/${PN}-3.14.0-unittest-2.patch
+)
+
+src_configure() {
+	# https://bugzilla.gnome.org/show_bug.cgi?id=778495
+	append-cflags -std=gnu11
+
+	gnome2_src_configure \
+		--enable-shared \
+		--disable-static \
+		--with-distributor-name=Gentoo \
+		$(use_enable test tests)
+}
+
+src_test() {
+	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
+	GSETTINGS_SCHEMA_DIR="${S}/data" virtx emake check
+}
-- 
cgit v1.2.3