From 4cbcc855382a06088e2f016f62cafdbcb7e40665 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 20 Mar 2022 00:40:44 +0000
Subject: gentoo resync : 20.03.2022

---
 www-apps/wordpress/wordpress-5.9.2.ebuild | 57 +++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 www-apps/wordpress/wordpress-5.9.2.ebuild

(limited to 'www-apps/wordpress/wordpress-5.9.2.ebuild')

diff --git a/www-apps/wordpress/wordpress-5.9.2.ebuild b/www-apps/wordpress/wordpress-5.9.2.ebuild
new file mode 100644
index 000000000000..6ea3e4bf16ad
--- /dev/null
+++ b/www-apps/wordpress/wordpress-5.9.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit webapp
+
+DESCRIPTION="Wordpress PHP and MySQL based content management system (CMS)"
+HOMEPAGE="https://wordpress.org/"
+SRC_URI="https://wordpress.org/${P/_rc/-RC}.tar.gz"
+
+LICENSE="GPL-2+"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="virtual/httpd-php
+	|| ( dev-lang/php[mysql] dev-lang/php[mysqli] )"
+
+S=${WORKDIR}/${PN}
+
+need_httpd_cgi
+
+IUSE="+akismet examples +themes vhosts"
+
+src_install() {
+	webapp_src_preinst
+
+	dodoc readme.html
+	rm readme.html license.txt || die
+
+	if use !akismet ; then
+		rm -R wp-content/plugins/akismet/ || die
+	fi
+	if use !examples ; then
+		rm wp-content/plugins/hello.php || die
+	fi
+	if use !themes ; then
+		rm -R wp-content/themes/*/ || die
+	fi
+
+	[[ -f wp-config.php ]] || cp wp-config-sample.php wp-config.php
+
+	insinto "${MY_HTDOCSDIR}"
+	doins -r .
+
+	webapp_serverowned "${MY_HTDOCSDIR}"/index.php
+	webapp_serverowned "${MY_HTDOCSDIR}"/wp-admin/menu.php
+	webapp_serverowned "${MY_HTDOCSDIR}"
+	# allows plugins update if allowed within WP
+	webapp_serverowned "${MY_HTDOCSDIR}"/wp-admin/includes/file.php
+
+	webapp_configfile  "${MY_HTDOCSDIR}"/wp-config.php
+
+	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
+	webapp_postupgrade_txt en "${FILESDIR}"/postupgrade-en.txt
+
+	webapp_src_install
+}
-- 
cgit v1.2.3