From 71bc00c87bba1ce31de0dac6c3b7fd1aee6917fc Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 20:52:04 +0100
Subject: gentoo resync : 14.07.2018

---
 www-apps/wordpress/wordpress-4.9.7.ebuild | 55 +++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 www-apps/wordpress/wordpress-4.9.7.ebuild

(limited to 'www-apps/wordpress/wordpress-4.9.7.ebuild')

diff --git a/www-apps/wordpress/wordpress-4.9.7.ebuild b/www-apps/wordpress/wordpress-4.9.7.ebuild
new file mode 100644
index 000000000000..19231ee76d17
--- /dev/null
+++ b/www-apps/wordpress/wordpress-4.9.7.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit webapp
+
+DESCRIPTION="Wordpress PHP and MySQL based content management system (CMS)"
+HOMEPAGE="https://wordpress.org/"
+SRC_URI="https://wordpress.org/${P/_rc/-RC}.tar.gz"
+
+LICENSE="GPL-2+"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="virtual/httpd-php
+	|| ( dev-lang/php[mysql] dev-lang/php[mysqli] )"
+
+S=${WORKDIR}/${PN}
+
+need_httpd_cgi
+
+IUSE="+akismet examples +themes vhosts"
+
+src_install() {
+	webapp_src_preinst
+
+	dodoc readme.html
+	rm readme.html license.txt || die
+
+	if ! use akismet ; then
+		rm -R wp-content/plugins/akismet/ || die
+	fi
+	if ! use examples ; then
+		rm wp-content/plugins/hello.php || die
+	fi
+	if ! use themes ; then
+		rm -R wp-content/themes/*/ || die
+	fi
+
+	[[ -f wp-config.php ]] || cp wp-config-sample.php wp-config.php
+
+	insinto "${MY_HTDOCSDIR}"
+	doins -r .
+
+	webapp_serverowned "${MY_HTDOCSDIR}"/index.php
+	webapp_serverowned "${MY_HTDOCSDIR}"/wp-admin/menu.php
+	webapp_serverowned "${MY_HTDOCSDIR}"
+
+	webapp_configfile  "${MY_HTDOCSDIR}"/wp-config.php
+
+	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
+	webapp_postupgrade_txt en "${FILESDIR}"/postupgrade-en.txt
+
+	webapp_src_install
+}
-- 
cgit v1.2.3