From 22230e510e031a97cafc85353610e573b7508e98 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 1 Feb 2024 17:48:32 +0000
Subject: gentoo auto-resync : 01:02:2024 - 17:48:32

---
 www-apps/sonarr/sonarr-4.0.1.1047.ebuild | 65 ++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 www-apps/sonarr/sonarr-4.0.1.1047.ebuild

(limited to 'www-apps/sonarr/sonarr-4.0.1.1047.ebuild')

diff --git a/www-apps/sonarr/sonarr-4.0.1.1047.ebuild b/www-apps/sonarr/sonarr-4.0.1.1047.ebuild
new file mode 100644
index 000000000000..96ad64a73d0b
--- /dev/null
+++ b/www-apps/sonarr/sonarr-4.0.1.1047.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd
+
+SRC_URI="
+	amd64? (
+		elibc_glibc? ( https://github.com/Sonarr/Sonarr/releases/download/v${PV}/Sonarr.develop.${PV}.linux-x64.tar.gz )
+		elibc_musl? ( https://github.com/Sonarr/Sonarr/releases/download/v${PV}/Sonarr.develop.${PV}.linux-musl-x64.tar.gz )
+	)
+	arm? (
+		elibc_glibc? ( https://github.com/Sonarr/Sonarr/releases/download/v${PV}/Sonarr.develop.${PV}.linux-arm.tar.gz )
+	)
+	arm64? (
+		elibc_glibc? ( https://github.com/Sonarr/Sonarr/releases/download/v${PV}/Sonarr.develop.${PV}.linux-arm64.tar.gz )
+		elibc_musl? ( https://github.com/Sonarr/Sonarr/releases/download/v${PV}/Sonarr.develop.${PV}.linux-musl-arm64.tar.gz )
+	)
+"
+
+DESCRIPTION="Sonarr is a Smart PVR for newsgroup and bittorrent users"
+HOMEPAGE="https://www.sonarr.tv"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+RESTRICT="bindist strip test"
+
+RDEPEND="
+	acct-group/sonarr
+	acct-user/sonarr
+	media-video/mediainfo
+	dev-libs/icu
+	dev-util/lttng-ust:0
+	dev-db/sqlite
+"
+
+QA_PREBUILT="*"
+
+S="${WORKDIR}/Sonarr"
+
+src_prepare() {
+	default
+
+	# https://github.com/dotnet/runtime/issues/57784
+	rm libcoreclrtraceptprovider.so Sonarr.Update/libcoreclrtraceptprovider.so || die
+}
+
+src_install() {
+	newinitd "${FILESDIR}/${PN}.init-r2" ${PN}
+
+	keepdir /var/lib/${PN}
+	fowners -R ${PN}:${PN} /var/lib/${PN}
+
+	insinto /etc/logrotate.d
+	insopts -m0644 -o root -g root
+	newins "${FILESDIR}/${PN}.logrotate" ${PN}
+
+	dodir  "/opt/${PN}"
+	cp -R "${S}/." "${D}/opt/sonarr" || die "Install failed!"
+
+	systemd_newunit "${FILESDIR}/${PN}.service-r1" "${PN}.service"
+	systemd_newunit "${FILESDIR}/${PN}.service-r1" "${PN}@.service"
+}
-- 
cgit v1.2.3