From f52562a45d967e193210737b55de5f0ff9018b76 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 24 Mar 2024 01:01:06 +0000
Subject: gentoo auto-resync : 24:03:2024 - 01:01:06

---
 www-apps/jellyfin-bin/jellyfin-bin-10.8.13.ebuild | 70 +++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 www-apps/jellyfin-bin/jellyfin-bin-10.8.13.ebuild

(limited to 'www-apps/jellyfin-bin/jellyfin-bin-10.8.13.ebuild')

diff --git a/www-apps/jellyfin-bin/jellyfin-bin-10.8.13.ebuild b/www-apps/jellyfin-bin/jellyfin-bin-10.8.13.ebuild
new file mode 100644
index 000000000000..ab927c16c0e6
--- /dev/null
+++ b/www-apps/jellyfin-bin/jellyfin-bin-10.8.13.ebuild
@@ -0,0 +1,70 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit pax-utils systemd tmpfiles
+
+DESCRIPTION="Jellyfin puts you in control of managing and streaming your media"
+HOMEPAGE="https://jellyfin.readthedocs.io/en/latest/
+	https://github.com/jellyfin/jellyfin/"
+
+SRC_URI="
+	arm64? (
+		https://repo.jellyfin.org/releases/server/linux/versions/stable/combined/${PV}/jellyfin_${PV}_arm64.tar.gz
+		https://repo.jellyfin.org/archive/linux/stable/${PV}/combined/jellyfin_${PV}_arm64.tar.gz
+	)
+	amd64? (
+		https://repo.jellyfin.org/releases/server/linux/versions/stable/combined/${PV}/jellyfin_${PV}_amd64.tar.gz
+		https://repo.jellyfin.org/archive/linux/stable/${PV}/combined/jellyfin_${PV}_amd64.tar.gz
+	)"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~arm64"
+RESTRICT="mirror test"
+REQUIRED_USE="elibc_glibc"
+
+DEPEND="acct-user/jellyfin
+	media-libs/fontconfig
+	sys-libs/zlib"
+RDEPEND="${DEPEND}
+	dev-libs/icu
+	media-video/ffmpeg[vpx,x264]"
+BDEPEND="acct-user/jellyfin"
+
+INST_DIR="/opt/jellyfin"
+QA_PREBUILT="${INST_DIR#/}/*.so ${INST_DIR#/}/jellyfin ${INST_DIR#/}/createdump"
+
+src_unpack() {
+	unpack ${A}
+	mv jellyfin_${PV} ${P} || die
+}
+
+src_prepare() {
+	default
+
+	# https://github.com/jellyfin/jellyfin/issues/7471
+	# https://github.com/dotnet/runtime/issues/57784
+	rm libcoreclrtraceptprovider.so || die
+}
+
+src_install() {
+	keepdir /var/log/jellyfin
+	fowners jellyfin:jellyfin /var/log/jellyfin
+	keepdir /etc/jellyfin
+	fowners jellyfin:jellyfin /etc/jellyfin
+	insinto ${INST_DIR}
+	dodir ${INST_DIR}
+	doins -r "${S}"/*
+	newtmpfiles - jellyfin.conf <<<"d /var/cache/jellyfin 0775 jellyfin jellyfin -"
+	chmod 755 "${D}${INST_DIR}/jellyfin"
+	newinitd "${FILESDIR}/jellyfin.init-r1" "jellyfin"
+	newconfd "${FILESDIR}"/jellyfin.confd "jellyfin"
+	systemd_dounit "${FILESDIR}/jellyfin.service"
+	pax-mark -m "${ED}${INST_DIR}/jellyfin"
+}
+
+pkg_postinst() {
+	tmpfiles_process jellyfin.conf
+}
-- 
cgit v1.2.3